let P1, P2 be Instruction-Sequence of SCM+FSA; :: thesis: for s1, s2 being State of SCM+FSA
for I being Program of SCM+FSA st DataPart s1 = DataPart s2 & I is_closed_on s1,P1 & I is_halting_on s1,P1 holds
( I is_closed_on s2,P2 & I is_halting_on s2,P2 )
let s1, s2 be State of SCM+FSA; :: thesis: for I being Program of SCM+FSA st DataPart s1 = DataPart s2 & I is_closed_on s1,P1 & I is_halting_on s1,P1 holds
( I is_closed_on s2,P2 & I is_halting_on s2,P2 )
let I be Program of SCM+FSA; :: thesis: ( DataPart s1 = DataPart s2 & I is_closed_on s1,P1 & I is_halting_on s1,P1 implies ( I is_closed_on s2,P2 & I is_halting_on s2,P2 ) )
set S1 = Initialize s1;
set S2 = Initialize s2;
defpred S₁[ Nat] means ( IC (Comput ((P1 +* I),(Initialize s1),$1)) = IC (Comput ((P2 +* I),(Initialize s2),$1)) & CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),$1))) = CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),$1))) & DataPart (Comput ((P1 +* I),(Initialize s1),$1)) = DataPart (Comput ((P2 +* I),(Initialize s2),$1)) );
A1: IC in dom (Start-At (0,SCM+FSA)) by MEMSTR_0:15;
A2: IC (Comput ((P1 +* I),(Initialize s1),0)) = IC (Start-At (0,SCM+FSA)) by A1, FUNCT_4:13
.= 0 by FUNCOP_1:72 ;
A3: IC (Comput ((P2 +* I),(Initialize s2),0)) = IC (Start-At (0,SCM+FSA)) by A1, FUNCT_4:13
.= 0 by FUNCOP_1:72 ;
assume DataPart s1 = DataPart s2 ; :: thesis: ( not I is_closed_on s1,P1 or not I is_halting_on s1,P1 or ( I is_closed_on s2,P2 & I is_halting_on s2,P2 ) )
then A4: Comput ((P1 +* I),(Initialize s1),0) = Comput ((P2 +* I),(Initialize s2),0) by Th4;
assume A5: I is_closed_on s1,P1 ; :: thesis: ( not I is_halting_on s1,P1 or ( I is_closed_on s2,P2 & I is_halting_on s2,P2 ) )

A6: now :: thesis: for k being Element of NAT st S₁[k] holds
S₁[k + 1]

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
A7: Comput ((P2 +* I),(Initialize s2),(k + 1)) = Following ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),k))) by EXTPRO_1:3
.= Exec ((CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),k)))),(Comput ((P2 +* I),(Initialize s2),k))) ;
assume A8: S₁[k] ; :: thesis: S₁[k + 1]
then A9: for f being FinSeq-Location holds (Comput ((P1 +* I),(Initialize s1),k)) . f = (Comput ((P2 +* I),(Initialize s2),k)) . f by SCMFSA_M:2;
for a being Int-Location holds (Comput ((P1 +* I),(Initialize s1),k)) . a = (Comput ((P2 +* I),(Initialize s2),k)) . a by A8, SCMFSA_M:2;
then A10: Comput ((P1 +* I),(Initialize s1),k) = Comput ((P2 +* I),(Initialize s2),k) by A8, A9, SCMFSA_2:61;
A11: IC (Comput ((P1 +* I),(Initialize s1),(k + 1))) in dom I by A5, SCMFSA7B:def 6;
Comput ((P1 +* I),(Initialize s1),(k + 1)) = Following ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),k))) by EXTPRO_1:3
.= Exec ((CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),k)))),(Comput ((P1 +* I),(Initialize s1),k))) ;
then A12: Comput ((P1 +* I),(Initialize s1),(k + 1)) = Comput ((P2 +* I),(Initialize s2),(k + 1)) by A8, A10, A7;
A13: IC (Comput ((P1 +* I),(Initialize s1),(k + 1))) = IC (Comput ((P2 +* I),(Initialize s2),(k + 1))) by A12;
A14: (P1 +* I) /. (IC (Comput ((P1 +* I),(Initialize s1),(k + 1)))) = (P1 +* I) . (IC (Comput ((P1 +* I),(Initialize s1),(k + 1)))) by PBOOLE:143;
A15: (P2 +* I) /. (IC (Comput ((P2 +* I),(Initialize s2),(k + 1)))) = (P2 +* I) . (IC (Comput ((P2 +* I),(Initialize s2),(k + 1)))) by PBOOLE:143;
A16: I c= P1 +* I by FUNCT_4:25;
A17: I c= P2 +* I by FUNCT_4:25;
CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),(k + 1)))) = I . (IC (Comput ((P1 +* I),(Initialize s1),(k + 1)))) by A11, A14, A16, GRFUNC_1:2
.= CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),(k + 1)))) by A13, A11, A15, A17, GRFUNC_1:2 ;
hence S₁[k + 1] by A12; :: thesis: verum

end;

assume I is_halting_on s1,P1 ; :: thesis: ( I is_closed_on s2,P2 & I is_halting_on s2,P2 )
then P1 +* I halts_on Initialize s1 by SCMFSA7B:def 7;
then consider m being Element of NAT such that
A18: CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),m))) = halt SCM+FSA by EXTPRO_1:29;
A19: (P1 +* I) /. (IC (Comput ((P1 +* I),(Initialize s1),0))) = (P1 +* I) . (IC (Comput ((P1 +* I),(Initialize s1),0))) by PBOOLE:143;
A20: (P2 +* I) /. (IC (Comput ((P2 +* I),(Initialize s2),0))) = (P2 +* I) . (IC (Comput ((P2 +* I),(Initialize s2),0))) by PBOOLE:143;
A21: 0 in dom I by A5, Th1;
then CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),0))) = I . 0 by A2, A19, FUNCT_4:13
.= CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),0))) by A3, A21, A20, FUNCT_4:13 ;
then A22: S₁[ 0 ] by A4;

now :: thesis: for k being Element of NAT holds IC (Comput ((P2 +* I),(Initialize s2),k)) in dom I

let k be Element of NAT ; :: thesis: IC (Comput ((P2 +* I),(Initialize s2),k)) in dom I
A23: IC (Comput ((P1 +* I),(Initialize s1),k)) in dom I by A5, SCMFSA7B:def 6;
for k being Element of NAT holds S₁[k] from NAT_1:sch 1(A22, A6);
hence IC (Comput ((P2 +* I),(Initialize s2),k)) in dom I by A23; :: thesis: verum

end;

hence I is_closed_on s2,P2 by SCMFSA7B:def 6; :: thesis: I is_halting_on s2,P2
for k being Element of NAT holds S₁[k] from NAT_1:sch 1(A22, A6);
then CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),m))) = halt SCM+FSA by A18;
then P2 +* I halts_on Initialize s2 by EXTPRO_1:29;
hence I is_halting_on s2,P2 by SCMFSA7B:def 7; :: thesis: verum