let a be ordinal number ; :: thesis: for U being Universe st omega in U & a in U holds
(U -Veblen) . a is normal Ordinal-Sequence of U
let U be Universe; :: thesis: ( omega in U & a in U implies (U -Veblen) . a is normal Ordinal-Sequence of U )
assume A1: omega in U ; :: thesis: ( not a in U or (U -Veblen) . a is normal Ordinal-Sequence of U )
defpred S₁[ Ordinal] means ( $1 in U implies (U -Veblen) . $1 is normal Ordinal-Sequence of U );
A2: S₁[ 0 ] by A1, Lm2;
A3: for b being ordinal number st S₁[b] holds
S₁[ succ b]

proof

let b be ordinal number ; :: thesis: ( S₁[b] implies S₁[ succ b] )
b in succ b by ORDINAL1:6;
then ( succ b in U implies b in U ) by ORDINAL1:10;
hence ( S₁[b] implies S₁[ succ b] ) by A1, Lm3; :: thesis: verum

end;

A4: for b being ordinal number st b <> {} & b is limit_ordinal & ( for c being ordinal number st c in b holds
S₁[c] ) holds
S₁[b]

proof

let b be ordinal number ; :: thesis: ( b <> {} & b is limit_ordinal & ( for c being ordinal number st c in b holds
S₁[c] ) implies S₁[b] )
assume that
A5: ( b <> {} & b is limit_ordinal ) and
A6: for c being ordinal number st c in b holds
S₁[c] and
A7: b in U ; :: thesis: (U -Veblen) . b is normal Ordinal-Sequence of U

now :: thesis: for a being ordinal number st a in b holds
(U -Veblen) . a is normal Ordinal-Sequence of U

let a be ordinal number ; :: thesis: ( a in b implies (U -Veblen) . a is normal Ordinal-Sequence of U )
assume A8: a in b ; :: thesis: (U -Veblen) . a is normal Ordinal-Sequence of U
then a in U by A7, ORDINAL1:10;
hence (U -Veblen) . a is normal Ordinal-Sequence of U by A6, A8; :: thesis: verum

end;

hence (U -Veblen) . b is normal Ordinal-Sequence of U by A5, A7, Lm4; :: thesis: verum

end;

for b being ordinal number holds S₁[b] from ORDINAL2:sch 1(A2, A3, A4);
hence ( not a in U or (U -Veblen) . a is normal Ordinal-Sequence of U ) ; :: thesis: verum