let X be Subset of COMPLEX; :: thesis: ( X is open implies for z0 being Complex st z0 in X holds
ex N being Neighbourhood of z0 st N c= X )
assume X is open ; :: thesis: for z0 being Complex st z0 in X holds
ex N being Neighbourhood of z0 st N c= X
then A1: X ` is closed by Def11;
let z0 be Complex; :: thesis: ( z0 in X implies ex N being Neighbourhood of z0 st N c= X )
assume that
A2: z0 in X and
A3: for N being Neighbourhood of z0 holds not N c= X ; :: thesis: contradiction
defpred S<sub>1</sub>[ Element of NAT , Complex] means ( $2 in { y where y is Complex : |.(y - z0).| < 1 / ($1 + 1) } & $2 in X ` );
A4: z0 in COMPLEX by XCMPLX_0:def 2;

now :: thesis: for g being Real st 0 < g holds
ex s being Element of COMPLEX st
( s in { y where y is Complex : |.(y - z0).| < g } & s in X ` )

let g be Real; :: thesis: ( 0 < g implies ex s being Element of COMPLEX st
( s in { y where y is Complex : |.(y - z0).| < g } & s in X ` ) )
assume A5: 0 < g ; :: thesis: ex s being Element of COMPLEX st
( s in { y where y is Complex : |.(y - z0).| < g } & s in X ` )
set N = { y where y is Complex : |.(y - z0).| < g } ;
{ y where y is Complex : |.(y - z0).| < g } is Neighbourhood of z0 by A4, A5, Th6;
then not { y where y is Complex : |.(y - z0).| < g } c= X by A3;
then consider x being set such that
A6: x in { y where y is Complex : |.(y - z0).| < g } and
A7: not x in X by TARSKI:def 3;
consider s being Complex such that
A8: x = s and
A9: |.(s - z0).| < g by A6;
reconsider s = s as Element of COMPLEX by XCMPLX_0:def 2;
take s = s; :: thesis: ( s in { y where y is Complex : |.(y - z0).| < g } & s in X ` )
thus s in { y where y is Complex : |.(y - z0).| < g } by A9; :: thesis: s in X `
thus s in X ` by A7, A8, XBOOLE_0:def 5; :: thesis: verum

end;

then A10: for n being Element of NAT ex s being Element of COMPLEX st S₁[n,s] ;
consider s1 being Function of NAT,COMPLEX such that
A11: for n being Element of NAT holds S₁[n,s1 . n] from FUNCT_2:sch 3(A10);
A12: rng s1 c= X `

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng s1 or y in X ` )
assume y in rng s1 ; :: thesis: y in X `
then consider y1 being set such that
A13: y1 in dom s1 and
A14: s1 . y1 = y by FUNCT_1:def 3;
reconsider y1 = y1 as Element of NAT by A13;
s1 . y1 in X ` by A11;
hence y in X ` by A14; :: thesis: verum

end;

A15: now :: thesis: for p being Real st 0 < p holds
ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.((s1 . m) - z0).| < p

let p be Real; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.((s1 . m) - z0).| < p )
assume A16: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.((s1 . m) - z0).| < p
consider n being Element of NAT such that
A17: p " < n by SEQ_4:3;
take n = n; :: thesis: for m being Element of NAT st n <= m holds
|.((s1 . m) - z0).| < p
let m be Element of NAT ; :: thesis: ( n <= m implies |.((s1 . m) - z0).| < p )
assume n <= m ; :: thesis: |.((s1 . m) - z0).| < p
then n + 1 <= m + 1 by XREAL_1:6;
then A18: 1 / (m + 1) <= 1 / (n + 1) by XREAL_1:118;
s1 . m in { y where y is Complex : |.(y - z0).| < 1 / (m + 1) } by A11;
then ex y being Complex st
( s1 . m = y & |.(y - z0).| < 1 / (m + 1) ) ;
then A19: |.((s1 . m) - z0).| < 1 / (n + 1) by A18, XXREAL_0:2;
(p ") + 0 < n + 1 by A17, XREAL_1:8;
then 1 / (n + 1) < 1 / (p ") by A16, XREAL_1:76;
hence |.((s1 . m) - z0).| < p by A19, XXREAL_0:2; :: thesis: verum

end;

then A20: s1 is convergent by A4, COMSEQ_2:def 5;
then lim s1 = z0 by A4, A15, COMSEQ_2:def 6;
then z0 in COMPLEX \ X by A20, A12, A1, Def10;
hence contradiction by A2, XBOOLE_0:def 5; :: thesis: verum