let T, T1 be non empty TopSpace; :: thesis: for f being continuous Function of T,T1 st T1 is T_1 holds
ex h being continuous Function of (T_1-reflex T),T1 st f = h * (T_1-reflect T)
let f be continuous Function of T,T1; :: thesis: ( T1 is T_1 implies ex h being continuous Function of (T_1-reflex T),T1 st f = h * (T_1-reflect T) )
set g = T_1-reflect T;
A1: dom (T_1-reflect T) = the carrier of T by FUNCT_2:def 1;
defpred S1[ set , set ] means for z being Element of T1 st z in rng f & $1 c= f " {z} holds
$2 = f " {z};
assume A2: T1 is T_1 ; :: thesis: ex h being continuous Function of (T_1-reflex T),T1 st f = h * (T_1-reflect T)
then reconsider fx = { (f " {x}) where x is Element of T1 : x in rng f } as a_partition of the carrier of T by Th13;
A3: dom f = the carrier of T by FUNCT_2:def 1;
A4: for y being set st y in the carrier of (T_1-reflex T) holds
ex w being set st S1[y,w]
proof
let y be set ; :: thesis: ( y in the carrier of (T_1-reflex T) implies ex w being set st S1[y,w] )
assume y in the carrier of (T_1-reflex T) ; :: thesis: ex w being set st S1[y,w]
then y in Intersection (Closed_Partitions T) by BORSUK_1:def 7;
then consider x being Element of T such that
A5: y = EqClass (x,(Intersection (Closed_Partitions T))) by EQREL_1:42;
reconsider x = x as Element of T ;
set w = f " {(f . x)};
take f " {(f . x)} ; :: thesis: S1[y,f " {(f . x)}]
let z be Element of T1; :: thesis: ( z in rng f & y c= f " {z} implies f " {(f . x)} = f " {z} )
assume that
A6: z in rng f and
A7: y c= f " {z} ; :: thesis: f " {(f . x)} = f " {z}
reconsider fix = f . x as Element of T1 ;
f . x in rng f by A3, FUNCT_1:def 3;
then A8: f " {fix} in fx ;
not y is empty by A5, EQREL_1:def 6;
then A9: ex z1 being set st z1 in y by XBOOLE_0:def 1;
f " {z} in fx by A6;
then A10: ( f " {(f . x)} misses f " {z} or f " {(f . x)} = f " {z} ) by A8, EQREL_1:def 4;
y c= f " {(f . x)} by A2, A5, Th14;
hence f " {(f . x)} = f " {z} by A7, A10, A9, XBOOLE_0:3; :: thesis: verum
end;
consider h1 being Function such that
A11: ( dom h1 = the carrier of (T_1-reflex T) & ( for y being set st y in the carrier of (T_1-reflex T) holds
S1[y,h1 . y] ) ) from CLASSES1:sch 1(A4);
 defpred S2[ set , set ] means for z being Element of T1 st z in rng f & $1 = f " {z} holds
$2 = z;
A12: for y being set st y in fx holds
ex w being set st S2[y,w]
proof
let y be set ; :: thesis: ( y in fx implies ex w being set st S2[y,w] )
assume y in fx ; :: thesis: ex w being set st S2[y,w]
then consider w being Element of T1 such that
A13: y = f " {w} and
w in rng f ;
take w ; :: thesis: S2[y,w]
let z be Element of T1; :: thesis: ( z in rng f & y = f " {z} implies w = z )
assume that
A14: z in rng f and
A15: y = f " {z} ; :: thesis: w = z
now
assume A16: z <> w ; :: thesis: contradiction
consider v being set such that
A17: v in dom f and
A18: z = f . v by A14, FUNCT_1:def 3;
z in {z} by TARSKI:def 1;
then v in f " {w} by A13, A15, A17, A18, FUNCT_1:def 7;
then f . v in {w} by FUNCT_1:def 7;
hence contradiction by A16, A18, TARSKI:def 1; :: thesis: verum
end;
hence w = z ; :: thesis: verum
end;
consider h2 being Function such that
A19: ( dom h2 = fx & ( for y being set st y in fx holds
S2[y,h2 . y] ) ) from CLASSES1:sch 1(A12);
 set h = h2 * h1;
A20: dom (h2 * h1) = the carrier of (T_1-reflex T)
proof
thus dom (h2 * h1) c= the carrier of (T_1-reflex T) by A11, RELAT_1:25; :: according to XBOOLE_0:def 10 :: thesis: the carrier of (T_1-reflex T) c= dom (h2 * h1)
let z be set ; :: according to TARSKI:def 3 :: thesis: ( not z in the carrier of (T_1-reflex T) or z in dom (h2 * h1) )
assume A21: z in the carrier of (T_1-reflex T) ; :: thesis: z in dom (h2 * h1)
then consider w being Element of T1 such that
A22: w in rng f and
A23: z c= f " {w} by A2, Th15;
h1 . z = f " {w} by A11, A21, A22, A23;
then h1 . z in dom h2 by A19, A22;
hence z in dom (h2 * h1) by A11, A21, FUNCT_1:11; :: thesis: verum
end;
A24: dom ((h2 * h1) * (T_1-reflect T)) = the carrier of T
proof
thus dom ((h2 * h1) * (T_1-reflect T)) c= the carrier of T by A1, RELAT_1:25; :: according to XBOOLE_0:def 10 :: thesis: the carrier of T c= dom ((h2 * h1) * (T_1-reflect T))
let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in the carrier of T or y in dom ((h2 * h1) * (T_1-reflect T)) )
assume A25: y in the carrier of T ; :: thesis: y in dom ((h2 * h1) * (T_1-reflect T))
then (T_1-reflect T) . y in rng (T_1-reflect T) by A1, FUNCT_1:def 3;
hence y in dom ((h2 * h1) * (T_1-reflect T)) by A1, A20, A25, FUNCT_1:11; :: thesis: verum
end;
A26: for x being set st x in dom f holds
f . x = ((h2 * h1) * (T_1-reflect T)) . x
proof
let x be set ; :: thesis: ( x in dom f implies f . x = ((h2 * h1) * (T_1-reflect T)) . x )
assume A27: x in dom f ; :: thesis: f . x = ((h2 * h1) * (T_1-reflect T)) . x
then (T_1-reflect T) . x in rng (T_1-reflect T) by A1, FUNCT_1:def 3;
then (T_1-reflect T) . x in the carrier of (T_1-reflex T) ;
then (T_1-reflect T) . x in Intersection (Closed_Partitions T) by BORSUK_1:def 7;
then consider y being Element of T such that
A28: (T_1-reflect T) . x = EqClass (y,(Intersection (Closed_Partitions T))) by EQREL_1:42;
reconsider x = x as Element of T by A27;
reconsider fix = f . x as Element of T1 ;
A29: x in EqClass (x,(Intersection (Closed_Partitions T))) by EQREL_1:def 6;
T_1-reflect T = proj (Intersection (Closed_Partitions T)) by BORSUK_1:def 8;
then x in (T_1-reflect T) . x by EQREL_1:def 9;
then EqClass (x,(Intersection (Closed_Partitions T))) meets EqClass (y,(Intersection (Closed_Partitions T))) by A28, A29, XBOOLE_0:3;
then A30: (T_1-reflect T) . x c= f " {fix} by A2, A28, Th14, EQREL_1:41;
A31: fix in rng f by A27, FUNCT_1:def 3;
then A32: f " {fix} in fx ;
((h2 * h1) * (T_1-reflect T)) . x = (h2 * h1) . ((T_1-reflect T) . x) by A24, FUNCT_1:12
.= h2 . (h1 . ((T_1-reflect T) . x)) by A11, FUNCT_1:13
.= h2 . (f " {fix}) by A11, A31, A30
.= f . x by A19, A31, A32 ;
hence f . x = ((h2 * h1) * (T_1-reflect T)) . x ; :: thesis: verum
end;
then A33: f = (h2 * h1) * (T_1-reflect T) by A3, A24, FUNCT_1:2;
A34: rng h2 c= the carrier of T1
proof
let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng h2 or y in the carrier of T1 )
assume y in rng h2 ; :: thesis: y in the carrier of T1
then consider w being set such that
A35: w in dom h2 and
A36: y = h2 . w by FUNCT_1:def 3;
consider x being Element of T1 such that
A37: ( w = f " {x} & x in rng f ) by A19, A35;
h2 . w = x by A19, A35, A37;
hence y in the carrier of T1 by A36; :: thesis: verum
end;
rng (h2 * h1) c= rng h2
proof
let z be set ; :: according to TARSKI:def 3 :: thesis: ( not z in rng (h2 * h1) or z in rng h2 )
thus ( not z in rng (h2 * h1) or z in rng h2 ) by FUNCT_1:14; :: thesis: verum
end;
then rng (h2 * h1) c= the carrier of T1 by A34, XBOOLE_1:1;
then reconsider h = h2 * h1 as Function of the carrier of (T_1-reflex T), the carrier of T1 by A20, FUNCT_2:def 1, RELSET_1:4;
reconsider h = h as Function of (T_1-reflex T),T1 ;
h is continuous
proof
let y be Subset of T1; :: according to PRE_TOPC:def 6 :: thesis: ( not y is closed or h " y is closed )
reconsider hy = h " y as Subset of (space (Intersection (Closed_Partitions T))) ;
union hy c= the carrier of T
proof
let z1 be set ; :: according to TARSKI:def 3 :: thesis: ( not z1 in union hy or z1 in the carrier of T )
assume z1 in union hy ; :: thesis: z1 in the carrier of T
then consider z2 being set such that
A38: z1 in z2 and
A39: z2 in hy by TARSKI:def 4;
z2 in the carrier of (space (Intersection (Closed_Partitions T))) by A39;
then z2 in Intersection (Closed_Partitions T) by BORSUK_1:def 7;
hence z1 in the carrier of T by A38; :: thesis: verum
end;
then reconsider uhy = union hy as Subset of T ;
assume y is closed ; :: thesis: h " y is closed
then (h * (T_1-reflect T)) " y is closed by A33, PRE_TOPC:def 6;
then (T_1-reflect T) " (h " y) is closed by RELAT_1:146;
then uhy is closed by Th2;
hence h " y is closed by Th5; :: thesis: verum
end;
then reconsider h = h as continuous Function of (T_1-reflex T),T1 ;
take h ; :: thesis: f = h * (T_1-reflect T)
thus f = h * (T_1-reflect T) by A3, A24, A26, FUNCT_1:2; :: thesis: verum