let p be Instruction-Sequence of SCM+FSA; :: thesis: for I, J being Program of SCM+FSA
for s being 0 -started State of SCM+FSA st I is_closed_on s,p & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (I ';' J)),s,m)
let I, J be Program of SCM+FSA; :: thesis: for s being 0 -started State of SCM+FSA st I is_closed_on s,p & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (I ';' J)),s,m)
let s be 0 -started State of SCM+FSA; :: thesis: ( I is_closed_on s,p & I c= p & p halts_on s implies for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (I ';' J)),s,m) )
assume that
A1: I is_closed_on s,p and
A3: I c= p and
A4: p halts_on s ; :: thesis: for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (I ';' J)),s,m)
A2: Start-At (0,SCM+FSA) c= s by MEMSTR_0:29;
A5: p +* I = p by A3, FUNCT_4:98;
defpred S₁[ Element of NAT ] means ( $1 <= LifeSpan (p,s) implies Comput (p,s,$1) = Comput ((p +* (I ';' J)),s,$1) );
A7: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

dom (I ';' J) = (dom (Directed I)) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:def 1
.= (dom I) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:99 ;
then A8: dom I c= dom (I ';' J) by XBOOLE_1:7;
set sIJ = s;
set pIJ = p +* (I ';' J);
A9: I ';' J c= p +* (I ';' J) by FUNCT_4:25;
let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A10: ( m <= LifeSpan (p,s) implies Comput (p,s,m) = Comput ((p +* (I ';' J)),s,m) ) ; :: thesis: S₁[m + 1]
A11: Comput ((p +* (I ';' J)),s,(m + 1)) = Following ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),s,m))) by EXTPRO_1:3;
A12: Comput (p,s,(m + 1)) = Following (p,(Comput (p,s,m))) by EXTPRO_1:3;
A13: p /. (IC (Comput (p,s,m))) = p . (IC (Comput (p,s,m))) by PBOOLE:143;
assume A14: m + 1 <= LifeSpan (p,s) ; :: thesis: Comput (p,s,(m + 1)) = Comput ((p +* (I ';' J)),s,(m + 1))
then A15: IC (Comput (p,s,m)) = IC (Comput ((p +* (I ';' J)),s,m)) by A10, NAT_1:13;
s = Initialize s by A2, FUNCT_4:98;
then A16: IC (Comput (p,s,m)) in dom I by A1, A5, SCMFSA7B:def 6;
A17: CurInstr (p,(Comput (p,s,m))) = I . (IC (Comput (p,s,m))) by A16, A13, A3, GRFUNC_1:2;
A18: (p +* (I ';' J)) /. (IC (Comput ((p +* (I ';' J)),s,m))) = (p +* (I ';' J)) . (IC (Comput ((p +* (I ';' J)),s,m))) by PBOOLE:143;
m < LifeSpan (p,s) by A14, NAT_1:13;
then I . (IC (Comput (p,s,m))) <> halt SCM+FSA by A4, A17, EXTPRO_1:def 15;
then CurInstr (p,(Comput (p,s,m))) = (I ';' J) . (IC (Comput (p,s,m))) by A16, A17, SCMFSA6A:15
.= CurInstr ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),s,m))) by A15, A16, A8, A18, A9, GRFUNC_1:2 ;
hence Comput (p,s,(m + 1)) = Comput ((p +* (I ';' J)),s,(m + 1)) by A10, A14, A12, A11, NAT_1:13; :: thesis: verum

end;

A19: Comput ((p +* (I ';' J)),s,0) = s by EXTPRO_1:2;
Comput (p,s,0) = s by EXTPRO_1:2;
then A20: S₁[ 0 ] by A19;
thus for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A20, A7); :: thesis: verum