let s be Real_Sequence; :: thesis: ( ( for n being Element of NAT st n >= 1 holds
( s . n = 1 / (((2 * n) - 1) * ((2 * n) + 1)) & s . 0 = 0 ) ) implies for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = n / ((2 * n) + 1) )
defpred S₁[ Nat] means (Partial_Sums s) . $1 = $1 / ((2 * $1) + 1);
assume A1: for n being Element of NAT st n >= 1 holds
( s . n = 1 / (((2 * n) - 1) * ((2 * n) + 1)) & s . 0 = 0 ) ; :: thesis: for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = n / ((2 * n) + 1)
A2: for n being Nat st n >= 1 & S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( n >= 1 & S₁[n] implies S₁[n + 1] )
assume that
n >= 1 and
A3: (Partial_Sums s) . n = n / ((2 * n) + 1) ; :: thesis: S₁[n + 1]
A4: n + 1 >= 1 by NAT_1:11;
(2 * n) + 1 >= 1 by NAT_1:11;
then A5: (2 * n) + 1 > 0 by XXREAL_0:2;
(2 * n) + 3 >= 3 by NAT_1:11;
then A6: (2 * n) + 3 > 0 by XXREAL_0:2;
n in NAT by ORDINAL1:def 12;
then (Partial_Sums s) . (n + 1) = (n / ((2 * n) + 1)) + (s . (n + 1)) by A3, SERIES_1:def 1
.= (n / ((2 * n) + 1)) + (1 / (((2 * (n + 1)) - 1) * ((2 * (n + 1)) + 1))) by A1, A4
.= (n / ((2 * n) + 1)) + ((1 / ((2 * n) + 1)) * (1 / ((2 * n) + 3))) by XCMPLX_1:102
.= (n * (1 / ((2 * n) + 1))) + ((1 / ((2 * n) + 1)) * (1 / ((2 * n) + 3))) by XCMPLX_1:99
.= (n + (1 / ((2 * n) + 3))) * (1 / ((2 * n) + 1))
.= (((n * ((2 * n) + 3)) + 1) / ((2 * n) + 3)) * (1 / ((2 * n) + 1)) by A6, XCMPLX_1:113
.= (((n + 1) * ((2 * n) + 1)) / ((2 * n) + 3)) * (1 / ((2 * n) + 1))
.= (((2 * n) + 1) * ((n + 1) / ((2 * n) + 3))) * (1 / ((2 * n) + 1)) by XCMPLX_1:74
.= (n + 1) / ((2 * (n + 1)) + 1) by A5, XCMPLX_1:107 ;
hence S₁[n + 1] ; :: thesis: verum

end;

(Partial_Sums s) . (1 + 0) = ((Partial_Sums s) . 0) + (s . (1 + 0)) by SERIES_1:def 1
.= (s . 0) + (s . 1) by SERIES_1:def 1
.= 0 + (s . 1) by A1
.= 1 / (((2 * 1) - 1) * ((2 * 1) + 1)) by A1
.= 1 / ((2 * 1) + 1) ;
then A7: S₁[1] ;
for n being Nat st n >= 1 holds
S₁[n] from NAT_1:sch 8(A7, A2);
hence for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = n / ((2 * n) + 1) ; :: thesis: verum