let p be real number ; :: thesis: for s being Real_Sequence st p <= 1 & ( for n being Element of NAT st n >= 1 holds
s . n = 1 / (n to_power p) ) holds
not s is summable
let s be Real_Sequence; :: thesis: ( p <= 1 & ( for n being Element of NAT st n >= 1 holds
s . n = 1 / (n to_power p) ) implies not s is summable )
assume that
A1: p <= 1 and
A2: for n being Element of NAT st n >= 1 holds
s . n = 1 / (n to_power p) ; :: thesis: not s is summable

now

per cases ( p < 0 or p >= 0 ) ;

suppose A3: p < 0 ; :: thesis: not s is summable

now

assume ( s is convergent & lim s = 0 ) ; :: thesis: contradiction
then consider m being Element of NAT such that
A4: for n being Element of NAT st n >= m holds
abs ((s . n) - 0) < 1 by SEQ_2:def 7;
consider k being Element of NAT such that
A5: k > m by SEQ_4:3;

now

let n be Element of NAT ; :: thesis: not n >= k
assume A6: n >= k ; :: thesis: contradiction
A7: n > 0 by A5, A6;
then A8: n >= 0 + 1 by NAT_1:13;
n >= m by A5, A6, XXREAL_0:2;
then abs ((s . n) - 0) < 1 by A4;
then abs (1 / (n to_power p)) < 1 by A2, A8;
then abs (n to_power (- p)) < 1 by A7, POWER:28;
then A9: n to_power (- p) < 1 by ABSVALUE:def 1;
n #R (- p) >= 1 by A3, A8, PREPOWER:85;
hence contradiction by A7, A9, POWER:def 2; :: thesis: verum

end;

hence contradiction ; :: thesis: verum

end;

hence not s is summable by Th7; :: thesis: verum

end;

suppose A10: p >= 0 ; :: thesis: not s is summable

defpred S₁[ Element of NAT , real number ] means ( ( $1 = 0 & $2 = 1 ) or ( $1 >= 1 & $2 = 1 / ($1 to_power p) ) );
A11: for n being Element of NAT ex r being Real st S₁[n,r]

proof

let n be Element of NAT ; :: thesis: ex r being Real st S₁[n,r]
( n = 0 or n >= 1 )

proof

assume that
A12: n <> 0 and
A13: n < 1 ; :: thesis: contradiction
n >= 0 + 1 by A12, NAT_1:13;
hence contradiction by A13; :: thesis: verum

end;

hence ex r being Real st S₁[n,r] ; :: thesis: verum

end;

consider s1 being Real_Sequence such that
A14: for n being Element of NAT holds S₁[n,s1 . n] from FUNCT_2:sch 3(A11);
A15: s1 . 0 = 1 by A14;

now

let n be Element of NAT ; :: thesis: s1 . (n + 1) <= s1 . n

now

per cases ( n = 0 or ex m being Nat st n = m + 1 ) by NAT_1:6;

suppose A16: n = 0 ; :: thesis: s1 . (n + 1) <= s1 . n

then (n + 1) #R p >= 1 by A10, PREPOWER:85;
then A17: (n + 1) to_power p >= 1 by POWER:def 2;
s1 . (n + 1) = 1 / ((n + 1) to_power p) by A14;
hence s1 . (n + 1) <= s1 . n by A15, A16, A17, XREAL_1:211; :: thesis: verum

end;

suppose A18: ex m being Nat st n = m + 1 ; :: thesis: s1 . (n + 1) <= s1 . n

then n to_power p > 0 by POWER:34;
then 1 / (n to_power p) > 0 ;
then A19: s1 . n > 0 by A14;
A20: n / (n + 1) <= 1 by NAT_1:11, XREAL_1:183;
A21: n / (n + 1) > 0 by A18;
(s1 . (n + 1)) / (s1 . n) = (1 / ((n + 1) to_power p)) / (s1 . n) by A14
.= (1 / ((n + 1) to_power p)) / (1 / (n to_power p)) by A14, A18
.= (1 / ((n + 1) to_power p)) * (n to_power p)
.= (n to_power p) / ((n + 1) to_power p)
.= (n / (n + 1)) to_power p by A18, POWER:31
.= (n / (n + 1)) #R p by A21, POWER:def 2 ;
then (s1 . (n + 1)) / (s1 . n) <= (n / (n + 1)) #R 0 by A10, A21, A20, PREPOWER:84;
then (s1 . (n + 1)) / (s1 . n) <= 1 by A18, PREPOWER:71;
hence s1 . (n + 1) <= s1 . n by A19, XREAL_1:187; :: thesis: verum

end;

end;

end;

hence s1 . (n + 1) <= s1 . n ; :: thesis: verum

end;

then A22: s1 is non-increasing by SEQM_3:def 9;

A23: now

let n be Element of NAT ; :: thesis: ( n >= 1 implies s . n >= s1 . n )
assume A24: n >= 1 ; :: thesis: s . n >= s1 . n
then s . n = 1 / (n to_power p) by A2
.= s1 . n by A14, A24 ;
hence s . n >= s1 . n ; :: thesis: verum

end;

deffunc H₁( Element of NAT ) -> Element of REAL = (2 to_power $1) * (s1 . (2 to_power $1));
consider s2 being Real_Sequence such that
A25: for n being Element of NAT holds s2 . n = H₁(n) from SEQ_1:sch 1();

A26: now

let n be Element of NAT ; :: thesis: ( s1 . n >= 0 & s2 . n = (2 to_power n) * (s1 . (2 to_power n)) )

now

per cases ( n = 0 or ex m being Nat st n = m + 1 ) by NAT_1:6;

suppose n = 0 ; :: thesis: s1 . n >= 0

hence s1 . n >= 0 by A14; :: thesis: verum

end;

suppose ex m being Nat st n = m + 1 ; :: thesis: s1 . n >= 0

then n to_power p > 0 by POWER:34;
then 1 / (n to_power p) >= 0 ;
hence s1 . n >= 0 by A14; :: thesis: verum

end;

end;

end;

hence ( s1 . n >= 0 & s2 . n = (2 to_power n) * (s1 . (2 to_power n)) ) by A25; :: thesis: verum

end;

now

assume ( s2 is convergent & lim s2 = 0 ) ; :: thesis: contradiction
then consider m being Element of NAT such that
A27: for n being Element of NAT st n >= m holds
abs ((s2 . n) - 0) < 1 / 2 by SEQ_2:def 7;

now

let n be Element of NAT ; :: thesis: not n >= m
assume n >= m ; :: thesis: contradiction
then abs ((s2 . n) - 0) < 1 / 2 by A27;
then A28: abs ((2 to_power n) * (s1 . (2 to_power n))) < 1 / 2 by A25;
2 to_power n >= 1 by PREPOWER:11;
then abs ((2 to_power n) * (1 / ((2 to_power n) to_power p))) < 1 / 2 by A14, A28;
then abs ((2 to_power n) * (1 / (2 to_power (n * p)))) < 1 / 2 by POWER:33;
then abs ((2 to_power n) * (2 to_power (- (n * p)))) < 1 / 2 by POWER:28;
then abs (2 to_power (n + (- (n * p)))) < 1 / 2 by POWER:27;
then 2 to_power (n - (n * p)) < 1 / 2 by ABSVALUE:def 1;
then (2 to_power (n - (n * p))) * 2 < (1 / 2) * 2 by XREAL_1:68;
then (2 to_power (n - (n * p))) * (2 to_power 1) < 1 by POWER:25;
then A29: 2 to_power ((n - (n * p)) + 1) < 1 by POWER:27;
1 - p >= 0 by A1, XREAL_1:48;
then n * (1 - p) >= 0 ;
then 2 #R ((n - (n * p)) + 1) >= 1 by PREPOWER:85;
hence contradiction by A29, POWER:def 2; :: thesis: verum

end;

hence contradiction ; :: thesis: verum

end;

then not s2 is summable by Th7;
then not s1 is summable by A22, A26, Th35;
hence not s is summable by A26, A23, Th22; :: thesis: verum

end;

end;

end;

hence not s is summable ; :: thesis: verum