let P1, P2 be Instruction-Sequence of SCM+FSA; :: thesis: for s1, s2 being State of SCM+FSA
for I being Program of SCM+FSA st DataPart s1 = DataPart s2 & I is_closed_on s1,P1 holds
I is_closed_on s2,P2
let s1, s2 be State of SCM+FSA; :: thesis: for I being Program of SCM+FSA st DataPart s1 = DataPart s2 & I is_closed_on s1,P1 holds
I is_closed_on s2,P2
let I be Program of SCM+FSA; :: thesis: ( DataPart s1 = DataPart s2 & I is_closed_on s1,P1 implies I is_closed_on s2,P2 )
set S1 = Initialize s1;
set S2 = Initialize s2;
assume A2: DataPart s1 = DataPart s2 ; :: thesis: ( not I is_closed_on s1,P1 or I is_closed_on s2,P2 )
A3: Comput ((P2 +* I),(Initialize s2),0) = Initialize s2 by EXTPRO_1:2;
A4: Comput ((P1 +* I),(Initialize s1),0) = Initialize s1 by EXTPRO_1:2;
then A5: DataPart (Comput ((P1 +* I),(Initialize s1),0)) = DataPart s1 by MEMSTR_0:79
.= DataPart (Comput ((P2 +* I),(Initialize s2),0)) by A2, A3, MEMSTR_0:79 ;
assume A6: I is_closed_on s1,P1 ; :: thesis: I is_closed_on s2,P2
then A7: 0 in dom I by Th3;
defpred S₁[ Nat] means ( IC (Comput ((P1 +* I),(Initialize s1),$1)) = IC (Comput ((P2 +* I),(Initialize s2),$1)) & CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),$1))) = CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),$1))) & DataPart (Comput ((P1 +* I),(Initialize s1),$1)) = DataPart (Comput ((P2 +* I),(Initialize s2),$1)) );

A8: now

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
A9: Comput ((P2 +* I),(Initialize s2),(k + 1)) = Following ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),k))) by EXTPRO_1:3
.= Exec ((CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),k)))),(Comput ((P2 +* I),(Initialize s2),k))) ;
assume A10: S₁[k] ; :: thesis: S₁[k + 1]
then A11: for f being FinSeq-Location holds (Comput ((P1 +* I),(Initialize s1),k)) . f = (Comput ((P2 +* I),(Initialize s2),k)) . f by SCMFSA6A:7;
for a being Int-Location holds (Comput ((P1 +* I),(Initialize s1),k)) . a = (Comput ((P2 +* I),(Initialize s2),k)) . a by A10, SCMFSA6A:7;
then A12: Comput ((P1 +* I),(Initialize s1),k) = Comput ((P2 +* I),(Initialize s2),k) by A10, A11, SCMFSA_2:61;
A13: IC (Comput ((P1 +* I),(Initialize s1),(k + 1))) in dom I by A6, SCMFSA7B:def 6;
Comput ((P1 +* I),(Initialize s1),(k + 1)) = Following ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),k))) by EXTPRO_1:3
.= Exec ((CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),k)))),(Comput ((P1 +* I),(Initialize s1),k))) ;
then A14: Comput ((P1 +* I),(Initialize s1),(k + 1)) = Comput ((P2 +* I),(Initialize s2),(k + 1)) by A10, A12, A9;
A15: IC (Comput ((P1 +* I),(Initialize s1),(k + 1))) = IC (Comput ((P2 +* I),(Initialize s2),(k + 1))) by A14;
A16: (P1 +* I) /. (IC (Comput ((P1 +* I),(Initialize s1),(k + 1)))) = (P1 +* I) . (IC (Comput ((P1 +* I),(Initialize s1),(k + 1)))) by PBOOLE:143;
A17: (P2 +* I) /. (IC (Comput ((P2 +* I),(Initialize s2),(k + 1)))) = (P2 +* I) . (IC (Comput ((P2 +* I),(Initialize s2),(k + 1)))) by PBOOLE:143;
A18: I c= P1 +* I by FUNCT_4:25;
A19: I c= P2 +* I by FUNCT_4:25;
CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),(k + 1)))) = I . (IC (Comput ((P1 +* I),(Initialize s1),(k + 1)))) by A13, A16, A18, GRFUNC_1:2
.= CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),(k + 1)))) by A15, A13, A17, A19, GRFUNC_1:2 ;
hence S₁[k + 1] by A14; :: thesis: verum

end;

A20: (P1 +* I) /. (IC (Comput ((P1 +* I),(Initialize s1),0))) = (P1 +* I) . (IC (Comput ((P1 +* I),(Initialize s1),0))) by PBOOLE:143;
A21: (P2 +* I) /. (IC (Comput ((P2 +* I),(Initialize s2),0))) = (P2 +* I) . (IC (Comput ((P2 +* I),(Initialize s2),0))) by PBOOLE:143;
B22: IC in dom (Start-At (0,SCM+FSA)) by MEMSTR_0:15;
then A23: IC (Comput ((P2 +* I),(Initialize s2),0)) = IC (Start-At (0,SCM+FSA)) by A3, FUNCT_4:13
.= 0 by FUNCOP_1:72 ;
A24: IC (Comput ((P1 +* I),(Initialize s1),0)) = IC (Start-At (0,SCM+FSA)) by A4, B22, FUNCT_4:13
.= 0 by FUNCOP_1:72 ;
then CurInstr ((P1 +* I),(Comput ((P1 +* I),(Initialize s1),0))) = I . 0 by A7, A20, FUNCT_4:13
.= CurInstr ((P2 +* I),(Comput ((P2 +* I),(Initialize s2),0))) by A23, A7, A21, FUNCT_4:13 ;
then A25: S₁[ 0 ] by A24, A23, A5;

now

let k be Element of NAT ; :: thesis: IC (Comput ((P2 +* I),(Initialize s2),k)) in dom I
A26: IC (Comput ((P1 +* I),(Initialize s1),k)) in dom I by A6, SCMFSA7B:def 6;
for k being Element of NAT holds S₁[k] from NAT_1:sch 1(A25, A8);
hence IC (Comput ((P2 +* I),(Initialize s2),k)) in dom I by A26; :: thesis: verum

end;

hence I is_closed_on s2,P2 by SCMFSA7B:def 6; :: thesis: verum