let s be 0 -started State of SCM+FSA; :: thesis: for I being paraclosed Program of
for J being Program of
for P being Instruction-Sequence of SCM+FSA st I c= P & P halts_on s holds
for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m)
let I be paraclosed Program of ; :: thesis: for J being Program of
for P being Instruction-Sequence of SCM+FSA st I c= P & P halts_on s holds
for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m)
let J be Program of ; :: thesis: for P being Instruction-Sequence of SCM+FSA st I c= P & P halts_on s holds
for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m)
let P be Instruction-Sequence of SCM+FSA; :: thesis: ( I c= P & P halts_on s implies for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m) )
assume A1: I c= P ; :: thesis: ( not P halts_on s or for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m) )
assume A3: P halts_on s ; :: thesis: for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m)
defpred S₁[ Nat] means ( $1 <= LifeSpan (P,s) implies Comput (P,s,$1) = Comput ((P +* (I ';' J)),s,$1) );
A6: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A7: ( m <= LifeSpan (P,s) implies Comput (P,s,m) = Comput ((P +* (I ';' J)),s,m) ) ; :: thesis: S₁[m + 1]
xx: dom (I ';' J) = (dom (Directed I)) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:def 1
.= (dom I) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:99 ;
A8: ( {} c= Comput ((P +* (I ';' J)),s,m) & dom I c= dom (I ';' J) ) by xx, XBOOLE_1:2, XBOOLE_1:7;
A9: Comput (P,s,(m + 1)) = Following (P,(Comput (P,s,m))) by EXTPRO_1:3;
A10: Comput ((P +* (I ';' J)),s,(m + 1)) = Following ((P +* (I ';' J)),(Comput ((P +* (I ';' J)),s,m))) by EXTPRO_1:3;
A11: IC (Comput (P,s,m)) in dom I by A1, AMISTD_1:def 10;
dom P = NAT by PARTFUN1:def 2;
then A12: CurInstr (P,(Comput (P,s,m))) = P . (IC (Comput (P,s,m))) by PARTFUN1:def 6
.= I . (IC (Comput (P,s,m))) by A11, A1, GRFUNC_1:2 ;
assume A13: m + 1 <= LifeSpan (P,s) ; :: thesis: Comput (P,s,(m + 1)) = Comput ((P +* (I ';' J)),s,(m + 1))
A14: I ';' J c= P +* (I ';' J) by FUNCT_4:25;
A15: dom (P +* (I ';' J)) = NAT by PARTFUN1:def 2;
m < LifeSpan (P,s) by A13, NAT_1:13;
then I . (IC (Comput (P,s,m))) <> halt SCM+FSA by A3, A12, EXTPRO_1:def 15;
then CurInstr (P,(Comput (P,s,m))) = (I ';' J) . (IC (Comput (P,s,m))) by A11, A12, SCMFSA6A:15
.= (P +* (I ';' J)) . (IC (Comput (P,s,m))) by A11, A8, A14, GRFUNC_1:2
.= CurInstr ((P +* (I ';' J)),(Comput ((P +* (I ';' J)),s,m))) by A15, A13, A7, NAT_1:13, PARTFUN1:def 6 ;
hence Comput (P,s,(m + 1)) = Comput ((P +* (I ';' J)),s,(m + 1)) by A9, A10, A7, A13, NAT_1:13; :: thesis: verum

end;

( Comput (P,s,0) = s & Comput ((P +* (I ';' J)),s,0) = s ) by EXTPRO_1:2;
then A16: S₁[ 0 ] ;
thus for m being Element of NAT holds S₁[m] from NAT_1:sch 1(A16, A6); :: thesis: verum