let p be Instruction-Sequence of SCM+FSA; :: thesis: for s being State of SCM+FSA
for I being InitClosed Program of SCM+FSA st Initialize ((intloc 0) .--> 1) c= s & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (loop I)),s,m)
let s be State of SCM+FSA; :: thesis: for I being InitClosed Program of SCM+FSA st Initialize ((intloc 0) .--> 1) c= s & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (loop I)),s,m)
let I be InitClosed Program of SCM+FSA; :: thesis: ( Initialize ((intloc 0) .--> 1) c= s & I c= p & p halts_on s implies for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (loop I)),s,m) )
assume that
A1: Initialize ((intloc 0) .--> 1) c= s and
A2: I c= p ; :: thesis: ( not p halts_on s or for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (loop I)),s,m) )
defpred S₁[ Nat] means ( $1 <= LifeSpan (p,s) implies Comput (p,s,$1) = Comput ((p +* (loop I)),s,$1) );
assume A3: p halts_on s ; :: thesis: for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m) = Comput ((p +* (loop I)),s,m)
A4: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

set sx = s;
set px = p +* (loop I);
A5: loop I c= p +* (loop I) by FUNCT_4:25;
let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A6: ( m <= LifeSpan (p,s) implies Comput (p,s,m) = Comput ((p +* (loop I)),s,m) ) ; :: thesis: S₁[m + 1]
A7: Comput ((p +* (loop I)),s,(m + 1)) = Following ((p +* (loop I)),(Comput ((p +* (loop I)),s,m))) by EXTPRO_1:3
.= Exec ((CurInstr ((p +* (loop I)),(Comput ((p +* (loop I)),s,m)))),(Comput ((p +* (loop I)),s,m))) ;
A8: Comput (p,s,(m + 1)) = Following (p,(Comput (p,s,m))) by EXTPRO_1:3
.= Exec ((CurInstr (p,(Comput (p,s,m)))),(Comput (p,s,m))) ;
A9: IC (Comput (p,s,m)) in dom I by A1, Def1, A2;
then A10: IC (Comput (p,s,m)) in dom (loop I) by FUNCT_4:99;
A11: p /. (IC (Comput (p,s,m))) = p . (IC (Comput (p,s,m))) by PBOOLE:143;
A12: CurInstr (p,(Comput (p,s,m))) = I . (IC (Comput (p,s,m))) by A9, A11, A2, GRFUNC_1:2;
assume A13: m + 1 <= LifeSpan (p,s) ; :: thesis: Comput (p,s,(m + 1)) = Comput ((p +* (loop I)),s,(m + 1))
A15: (p +* (loop I)) /. (IC (Comput ((p +* (loop I)),s,m))) = (p +* (loop I)) . (IC (Comput ((p +* (loop I)),s,m))) by PBOOLE:143;
m < LifeSpan (p,s) by A13, NAT_1:13;
then I . (IC (Comput (p,s,m))) <> halt SCM+FSA by A3, A12, EXTPRO_1:def 15;
then CurInstr (p,(Comput (p,s,m))) = (loop I) . (IC (Comput (p,s,m))) by A12, FUNCT_4:105
.= CurInstr ((p +* (loop I)),(Comput ((p +* (loop I)),s,m))) by A13, A10, A15, A5, A6, GRFUNC_1:2, NAT_1:13 ;
hence Comput (p,s,(m + 1)) = Comput ((p +* (loop I)),s,(m + 1)) by A6, A13, A8, A7, NAT_1:13; :: thesis: verum

end;

( Comput (p,s,0) = s & Comput ((p +* (loop I)),s,0) = s ) by EXTPRO_1:2;
then A16: S₁[ 0 ] ;
thus for m being Element of NAT holds S₁[m] from NAT_1:sch 1(A16, A4); :: thesis: verum