let s be State of SCM+FSA; :: thesis: for p being Instruction-Sequence of SCM+FSA
for I being InitClosed Program of SCM+FSA st p +* I halts_on Initialized s holds
for J being Program of SCM+FSA
for k being Element of NAT st k <= LifeSpan ((p +* I),(Initialized s)) holds
Comput ((p +* I),(Initialized s),k) = Comput ((p +* (I ';' J)),(Initialized s),k)
let p be Instruction-Sequence of SCM+FSA; :: thesis: for I being InitClosed Program of SCM+FSA st p +* I halts_on Initialized s holds
for J being Program of SCM+FSA
for k being Element of NAT st k <= LifeSpan ((p +* I),(Initialized s)) holds
Comput ((p +* I),(Initialized s),k) = Comput ((p +* (I ';' J)),(Initialized s),k)
let I be InitClosed Program of SCM+FSA; :: thesis: ( p +* I halts_on Initialized s implies for J being Program of SCM+FSA
for k being Element of NAT st k <= LifeSpan ((p +* I),(Initialized s)) holds
Comput ((p +* I),(Initialized s),k) = Comput ((p +* (I ';' J)),(Initialized s),k) )
assume A1: p +* I halts_on Initialized s ; :: thesis: for J being Program of SCM+FSA
for k being Element of NAT st k <= LifeSpan ((p +* I),(Initialized s)) holds
Comput ((p +* I),(Initialized s),k) = Comput ((p +* (I ';' J)),(Initialized s),k)
set s1 = Initialized s;
set p1 = p +* I;
A2: I c= p +* I by FUNCT_4:25;
let J be Program of SCM+FSA; :: thesis: for k being Element of NAT st k <= LifeSpan ((p +* I),(Initialized s)) holds
Comput ((p +* I),(Initialized s),k) = Comput ((p +* (I ';' J)),(Initialized s),k)
set s2 = Initialized s;
set p2 = p +* (I ';' J);
defpred S₁[ Nat] means ( $1 <= LifeSpan ((p +* I),(Initialized s)) implies Comput ((p +* I),(Initialized s),$1) = Comput ((p +* (I ';' J)),(Initialized s),$1) );
A3: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

dom (I ';' J) = (dom (Directed I)) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:def 1
.= (dom I) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:99 ;
then A4: dom I c= dom (I ';' J) by XBOOLE_1:7;
set sx = Initialized s;
set px = p +* (I ';' J);
A5: I ';' J c= p +* (I ';' J) by FUNCT_4:25;
let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A6: ( m <= LifeSpan ((p +* I),(Initialized s)) implies Comput ((p +* I),(Initialized s),m) = Comput ((p +* (I ';' J)),(Initialized s),m) ) ; :: thesis: S₁[m + 1]
assume A7: m + 1 <= LifeSpan ((p +* I),(Initialized s)) ; :: thesis: Comput ((p +* I),(Initialized s),(m + 1)) = Comput ((p +* (I ';' J)),(Initialized s),(m + 1))
A9: Comput ((p +* I),(Initialized s),(m + 1)) = Following ((p +* I),(Comput ((p +* I),(Initialized s),m))) by EXTPRO_1:3
.= Exec ((CurInstr ((p +* I),(Comput ((p +* I),(Initialized s),m)))),(Comput ((p +* I),(Initialized s),m))) ;
A10: Comput ((p +* (I ';' J)),(Initialized s),(m + 1)) = Following ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),(Initialized s),m))) by EXTPRO_1:3
.= Exec ((CurInstr ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),(Initialized s),m)))),(Comput ((p +* (I ';' J)),(Initialized s),m))) ;
Initialize ((intloc 0) .--> 1) c= Initialized s by FUNCT_4:25;
then A11: IC (Comput ((p +* I),(Initialized s),m)) in dom I by Def1, A2;
A12: (p +* I) /. (IC (Comput ((p +* I),(Initialized s),m))) = (p +* I) . (IC (Comput ((p +* I),(Initialized s),m))) by PBOOLE:143;
A13: CurInstr ((p +* I),(Comput ((p +* I),(Initialized s),m))) = I . (IC (Comput ((p +* I),(Initialized s),m))) by A11, A12, A2, GRFUNC_1:2;
A14: (p +* (I ';' J)) /. (IC (Comput ((p +* (I ';' J)),(Initialized s),m))) = (p +* (I ';' J)) . (IC (Comput ((p +* (I ';' J)),(Initialized s),m))) by PBOOLE:143;
m < LifeSpan ((p +* I),(Initialized s)) by A7, NAT_1:13;
then I . (IC (Comput ((p +* I),(Initialized s),m))) <> halt SCM+FSA by A1, A13, EXTPRO_1:def 15;
then CurInstr ((p +* I),(Comput ((p +* I),(Initialized s),m))) = (I ';' J) . (IC (Comput ((p +* I),(Initialized s),m))) by A11, A13, SCMFSA6A:15
.= CurInstr ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),(Initialized s),m))) by A14, A7, A11, A4, A5, A6, GRFUNC_1:2, NAT_1:13 ;
hence Comput ((p +* I),(Initialized s),(m + 1)) = Comput ((p +* (I ';' J)),(Initialized s),(m + 1)) by A6, A7, A9, A10, NAT_1:13; :: thesis: verum

end;

( Comput ((p +* I),(Initialized s),0) = Initialized s & Comput ((p +* (I ';' J)),(Initialized s),0) = Initialized s ) by EXTPRO_1:2;
then A18: S₁[ 0 ] ;
thus for k being Element of NAT holds S₁[k] from NAT_1:sch 1(A18, A3); :: thesis: verum