let X be non empty set ; :: thesis: for Y being RealNormSpace
for f, g being Point of (R_NormSpace_of_BoundedFunctions (X,Y))
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let Y be RealNormSpace; :: thesis: for f, g being Point of (R_NormSpace_of_BoundedFunctions (X,Y))
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (R_NormSpace_of_BoundedFunctions (X,Y)); :: thesis: for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let a be Real; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
A1: now
assume A2: f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum
proof
reconsider g = f as bounded Function of X, the carrier of Y by Def5;
set z = X --> (0. Y);
reconsider z = X --> (0. Y) as Function of X, the carrier of Y ;
consider r0 being set such that
A3: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A3;
A4: ( ( for s being real number st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
A5: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th13;
A6: z = g by A2, Th18;
A7: now
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being Element of X such that
A8: r = ||.(g . t).|| ;
||.(g . t).|| = ||.(0. Y).|| by A6, FUNCOP_1:7
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A8; :: thesis: verum
end;
then 0 <= r0 by A3;
then upper_bound (PreNorms g) = 0 by A7, A5, A3, A4, SEQ_4:def 1;
hence ||.f.|| = 0 by Th17; :: thesis: verum
end;
end;
A9: ||.(f + g).|| <= ||.f.|| + ||.g.||
proof
reconsider f1 = f, g1 = g, h1 = f + g as bounded Function of X, the carrier of Y by Def5;
A10: now
let t be Element of X; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
( ||.(f1 . t).|| <= ||.f.|| & ||.(g1 . t).|| <= ||.g.|| ) by Th19;
then A11: ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by XREAL_1:7;
( ||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| & ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| ) by Th22, NORMSP_1:def 1;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A11, XXREAL_0:2; :: thesis: verum
end;
A12: now
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= ||.f.|| + ||.g.|| by A10; :: thesis: verum
end;
( ( for s being real number st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies upper_bound (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:45;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A12, Th17; :: thesis: verum
end;
A13: ||.(a * f).|| = (abs a) * ||.f.||
proof
reconsider f1 = f, h1 = a * f as bounded Function of X, the carrier of Y by Def5;
A14: ( ( for s being real number st s in PreNorms h1 holds
s <= (abs a) * ||.f.|| ) implies upper_bound (PreNorms h1) <= (abs a) * ||.f.|| ) by SEQ_4:45;
A15: now
let t be Element of X; :: thesis: ||.(h1 . t).|| <= (abs a) * ||.f.||
A16: 0 <= abs a by COMPLEX1:46;
( ||.(h1 . t).|| = ||.(a * (f1 . t)).|| & ||.(a * (f1 . t)).|| = (abs a) * ||.(f1 . t).|| ) by Th23, NORMSP_1:def 1;
hence ||.(h1 . t).|| <= (abs a) * ||.f.|| by A16, Th19, XREAL_1:64; :: thesis: verum
end;
A17: now
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= (abs a) * ||.f.|| )
assume r in PreNorms h1 ; :: thesis: r <= (abs a) * ||.f.||
then ex t being Element of X st r = ||.(h1 . t).|| ;
hence r <= (abs a) * ||.f.|| by A15; :: thesis: verum
end;
A18: now
per cases ( a <> 0 or a = 0 ) ;
case A19: a <> 0 ; :: thesis: (abs a) * ||.f.|| <= ||.(a * f).||
A20: now
let t be Element of X; :: thesis: ||.(f1 . t).|| <= ((abs a) ") * ||.(a * f).||
A21: abs (a ") = abs (1 * (a "))
.= abs (1 / a) by XCMPLX_0:def 9
.= 1 / (abs a) by ABSVALUE:7
.= 1 * ((abs a) ") by XCMPLX_0:def 9
.= (abs a) " ;
h1 . t = a * (f1 . t) by Th23;
then A22: (a ") * (h1 . t) = ((a ") * a) * (f1 . t) by RLVECT_1:def 7
.= 1 * (f1 . t) by A19, XCMPLX_0:def 7
.= f1 . t by RLVECT_1:def 8 ;
( ||.((a ") * (h1 . t)).|| = (abs (a ")) * ||.(h1 . t).|| & 0 <= abs (a ") ) by COMPLEX1:46, NORMSP_1:def 1;
hence ||.(f1 . t).|| <= ((abs a) ") * ||.(a * f).|| by A22, A21, Th19, XREAL_1:64; :: thesis: verum
end;
A23: now
let r be Real; :: thesis: ( r in PreNorms f1 implies r <= ((abs a) ") * ||.(a * f).|| )
assume r in PreNorms f1 ; :: thesis: r <= ((abs a) ") * ||.(a * f).||
then ex t being Element of X st r = ||.(f1 . t).|| ;
hence r <= ((abs a) ") * ||.(a * f).|| by A20; :: thesis: verum
end;
A24: ( ( for s being real number st s in PreNorms f1 holds
s <= ((abs a) ") * ||.(a * f).|| ) implies upper_bound (PreNorms f1) <= ((abs a) ") * ||.(a * f).|| ) by SEQ_4:45;
( (BoundedFunctionsNorm (X,Y)) . f = upper_bound (PreNorms f1) & 0 <= abs a ) by Th17, COMPLEX1:46;
then (abs a) * ||.f.|| <= (abs a) * (((abs a) ") * ||.(a * f).||) by A23, A24, XREAL_1:64;
then A25: (abs a) * ||.f.|| <= ((abs a) * ((abs a) ")) * ||.(a * f).|| ;
abs a <> 0 by A19, COMPLEX1:47;
then (abs a) * ||.f.|| <= 1 * ||.(a * f).|| by A25, XCMPLX_0:def 7;
hence (abs a) * ||.f.|| <= ||.(a * f).|| ; :: thesis: verum
end;
case A26: a = 0 ; :: thesis: (abs a) * ||.f.|| = ||.(a * f).||
reconsider fz = f as VECTOR of (R_VectorSpace_of_BoundedFunctions (X,Y)) ;
A27: a * f = a * fz
.= 0. (R_VectorSpace_of_BoundedFunctions (X,Y)) by A26, RLVECT_1:10
.= 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ;
thus (abs a) * ||.f.|| = 0 * ||.f.|| by A26, ABSVALUE:2
.= ||.(a * f).|| by A27, Th21 ; :: thesis: verum
end;
end;
end;
(BoundedFunctionsNorm (X,Y)) . (a * f) = upper_bound (PreNorms h1) by Th17;
hence ||.(a * f).|| = (abs a) * ||.f.|| by A17, A14, A18, XXREAL_0:1; :: thesis: verum
end;
now
reconsider g = f as bounded Function of X, the carrier of Y by Def5;
set z = X --> (0. Y);
reconsider z = X --> (0. Y) as Function of X, the carrier of Y ;
assume A28: ||.f.|| = 0 ; :: thesis: f = 0. (R_NormSpace_of_BoundedFunctions (X,Y))
now
let t be Element of X; :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| by Th19;
then ||.(g . t).|| = 0 by A28;
hence g . t = 0. Y by NORMSP_0:def 5
.= z . t by FUNCOP_1:7 ;
:: thesis: verum
end;
then g = z by FUNCT_2:63;
hence f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) by Th18; :: thesis: verum
end;
hence ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) ) & ( f = 0. (R_NormSpace_of_BoundedFunctions (X,Y)) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A1, A13, A9; :: thesis: verum