let s be Rational_Sequence; :: thesis: for a being real number st s is convergent & a >= 1 holds
a #Q s is convergent
let a be real number ; :: thesis: ( s is convergent & a >= 1 implies a #Q s is convergent )
assume that
A1: s is convergent and
A2: a >= 1 ; :: thesis: a #Q s is convergent
s is bounded by A1, SEQ_2:13;
then consider d being real number such that
0 < d and
A3: for n being Element of NAT holds abs (s . n) < d by SEQ_2:3;
consider m2 being Element of NAT such that
A4: d < m2 by SEQ_4:3;
reconsider m2 = m2 as Rational ;

now

A5: a #Q m2 >= 0 by A2, Th63;
let c be real number ; :: thesis: ( c > 0 implies ex n being Element of NAT st
for m being Element of NAT st m >= n holds
abs (((a #Q s) . m) - ((a #Q s) . n)) < c )
assume A6: c > 0 ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st m >= n holds
abs (((a #Q s) . m) - ((a #Q s) . n)) < c
consider m1 being Element of NAT such that
A7: ((a #Q m2) * (a - 1)) / c < m1 by SEQ_4:3;
m1 + 1 >= m1 by XREAL_1:29;
then ((a #Q m2) * (a - 1)) / c < m1 + 1 by A7, XXREAL_0:2;
then (((a #Q m2) * (a - 1)) / c) * c < c * (m1 + 1) by A6, XREAL_1:68;
then (a #Q m2) * (a - 1) < c * (m1 + 1) by A6, XCMPLX_1:87;
then ((a #Q m2) * (a - 1)) / (m1 + 1) < ((m1 + 1) * c) / (m1 + 1) by XREAL_1:74;
then ((a #Q m2) * (a - 1)) / (m1 + 1) < (c / (m1 + 1)) * (m1 + 1) ;
then A8: ((a #Q m2) * (a - 1)) / (m1 + 1) < c by XCMPLX_1:87;
consider n being Element of NAT such that
A9: for m being Element of NAT st n <= m holds
abs ((s . m) - (s . n)) < (m1 + 1) " by A1, SEQ_4:41;
take n = n; :: thesis: for m being Element of NAT st m >= n holds
abs (((a #Q s) . m) - ((a #Q s) . n)) < c
let m be Element of NAT ; :: thesis: ( m >= n implies abs (((a #Q s) . m) - ((a #Q s) . n)) < c )
assume m >= n ; :: thesis: abs (((a #Q s) . m) - ((a #Q s) . n)) < c
then A10: abs ((s . m) - (s . n)) <= (m1 + 1) " by A9;
A11: m1 + 1 >= 0 + 1 by NAT_1:13;
then ((m1 + 1) -Root a) - 1 <= (a - 1) / (m1 + 1) by A2, Th40;
then A12: (a #Q m2) * (((m1 + 1) -Root a) - 1) <= (a #Q m2) * ((a - 1) / (m1 + 1)) by A5, XREAL_1:64;
A13: a #Q (s . n) <> 0 by A2, Th63;
A14: abs ((a #Q (s . m)) - (a #Q (s . n))) = abs (((a #Q (s . m)) - (a #Q (s . n))) * 1)
.= abs (((a #Q (s . m)) - (a #Q (s . n))) * ((a #Q (s . n)) / (a #Q (s . n)))) by A13, XCMPLX_1:60
.= abs (((a #Q (s . n)) * ((a #Q (s . m)) - (a #Q (s . n)))) / (a #Q (s . n)))
.= abs ((a #Q (s . n)) * (((a #Q (s . m)) - (a #Q (s . n))) / (a #Q (s . n))))
.= (abs (a #Q (s . n))) * (abs (((a #Q (s . m)) - (a #Q (s . n))) / (a #Q (s . n)))) by COMPLEX1:65
.= (abs (a #Q (s . n))) * (abs (((a #Q (s . m)) / (a #Q (s . n))) - ((a #Q (s . n)) / (a #Q (s . n)))))
.= (abs (a #Q (s . n))) * (abs (((a #Q (s . m)) / (a #Q (s . n))) - 1)) by A13, XCMPLX_1:60
.= (abs (a #Q (s . n))) * (abs ((a #Q ((s . m) - (s . n))) - 1)) by A2, Th66 ;
A15: s . n <= abs (s . n) by ABSVALUE:4;
reconsider m3 = (m1 + 1) " as Rational ;
A16: abs ((a #Q ((s . m) - (s . n))) - 1) >= 0 by COMPLEX1:46;
A17: a #Q ((s . m) - (s . n)) <> 0 by A2, Th63;
(s . m) - (s . n) <= abs ((s . m) - (s . n)) by ABSVALUE:4;
then (s . m) - (s . n) <= (m1 + 1) " by A10, XXREAL_0:2;
then a #Q ((s . m) - (s . n)) <= a #Q m3 by A2, Th74;
then a #Q ((s . m) - (s . n)) <= (m1 + 1) -Root a by A11, Th61;
then A18: (a #Q ((s . m) - (s . n))) - 1 <= ((m1 + 1) -Root a) - 1 by XREAL_1:9;
A19: a #Q ((s . m) - (s . n)) > 0 by A2, Th63;

A20: now

per cases ( (s . m) - (s . n) >= 0 or (s . m) - (s . n) < 0 ) ;

suppose (s . m) - (s . n) >= 0 ; :: thesis: abs ((a #Q ((s . m) - (s . n))) - 1) <= ((m1 + 1) -Root a) - 1

then a #Q ((s . m) - (s . n)) >= 1 by A2, Th71;
then (a #Q ((s . m) - (s . n))) - 1 >= 0 by XREAL_1:48;
hence abs ((a #Q ((s . m) - (s . n))) - 1) <= ((m1 + 1) -Root a) - 1 by A18, ABSVALUE:def 1; :: thesis: verum

end;

suppose A21: (s . m) - (s . n) < 0 ; :: thesis: abs ((a #Q ((s . m) - (s . n))) - 1) <= ((m1 + 1) -Root a) - 1

A22: - ((s . m) - (s . n)) <= abs (- ((s . m) - (s . n))) by ABSVALUE:4;
abs ((s . m) - (s . n)) = abs (- ((s . m) - (s . n))) by COMPLEX1:52;
then - ((s . m) - (s . n)) <= m3 by A10, A22, XXREAL_0:2;
then a #Q (- ((s . m) - (s . n))) <= a #Q m3 by A2, Th74;
then a #Q (- ((s . m) - (s . n))) <= (m1 + 1) -Root a by A11, Th61;
then A23: (a #Q (- ((s . m) - (s . n)))) - 1 <= ((m1 + 1) -Root a) - 1 by XREAL_1:9;
a #Q (- ((s . m) - (s . n))) >= 1 by A2, A21, Th71;
then (a #Q (- ((s . m) - (s . n)))) - 1 >= 0 by XREAL_1:48;
then A24: abs ((a #Q (- ((s . m) - (s . n)))) - 1) <= ((m1 + 1) -Root a) - 1 by A23, ABSVALUE:def 1;
a #Q ((s . m) - (s . n)) <= 1 by A2, A21, Th72;
then A25: abs (a #Q ((s . m) - (s . n))) <= 1 by A19, ABSVALUE:def 1;
abs ((a #Q (- ((s . m) - (s . n)))) - 1) >= 0 by COMPLEX1:46;
then A26: (abs (a #Q ((s . m) - (s . n)))) * (abs ((a #Q (- ((s . m) - (s . n)))) - 1)) <= 1 * (abs ((a #Q (- ((s . m) - (s . n)))) - 1)) by A25, XREAL_1:64;
abs ((a #Q ((s . m) - (s . n))) - 1) = abs (((a #Q ((s . m) - (s . n))) - 1) * 1)
.= abs (((a #Q ((s . m) - (s . n))) - 1) * ((a #Q ((s . m) - (s . n))) / (a #Q ((s . m) - (s . n))))) by A17, XCMPLX_1:60
.= abs (((a #Q ((s . m) - (s . n))) * ((a #Q ((s . m) - (s . n))) - 1)) / (a #Q ((s . m) - (s . n))))
.= abs ((a #Q ((s . m) - (s . n))) * (((a #Q ((s . m) - (s . n))) - 1) / (a #Q ((s . m) - (s . n)))))
.= (abs (a #Q ((s . m) - (s . n)))) * (abs (((a #Q ((s . m) - (s . n))) - 1) / (a #Q ((s . m) - (s . n))))) by COMPLEX1:65
.= (abs (a #Q ((s . m) - (s . n)))) * (abs (((a #Q ((s . m) - (s . n))) / (a #Q ((s . m) - (s . n)))) - (1 / (a #Q ((s . m) - (s . n))))))
.= (abs (a #Q ((s . m) - (s . n)))) * (abs (1 - (1 / (a #Q ((s . m) - (s . n)))))) by A17, XCMPLX_1:60
.= (abs (a #Q ((s . m) - (s . n)))) * (abs (1 - (a #Q (- ((s . m) - (s . n)))))) by A2, Th65
.= (abs (a #Q ((s . m) - (s . n)))) * (abs (- (1 - (a #Q (- ((s . m) - (s . n))))))) by COMPLEX1:52
.= (abs (a #Q ((s . m) - (s . n)))) * (abs ((a #Q (- ((s . m) - (s . n)))) - 1)) ;
hence abs ((a #Q ((s . m) - (s . n))) - 1) <= ((m1 + 1) -Root a) - 1 by A24, A26, XXREAL_0:2; :: thesis: verum

end;

end;

end;

A27: a #Q (s . n) > 0 by A2, Th63;
abs (s . n) <= m2 by A3, A4, XXREAL_0:2;
then s . n <= m2 by A15, XXREAL_0:2;
then a #Q (s . n) <= a #Q m2 by A2, Th74;
then A28: abs (a #Q (s . n)) <= a #Q m2 by A27, ABSVALUE:def 1;
abs (a #Q (s . n)) >= 0 by A27, ABSVALUE:def 1;
then (abs (a #Q (s . n))) * (abs ((a #Q ((s . m) - (s . n))) - 1)) <= (a #Q m2) * (((m1 + 1) -Root a) - 1) by A20, A16, A28, XREAL_1:66;
then abs ((a #Q (s . m)) - (a #Q (s . n))) <= ((a #Q m2) * (a - 1)) / (m1 + 1) by A14, A12, XXREAL_0:2;
then abs ((a #Q (s . m)) - (a #Q (s . n))) < c by A8, XXREAL_0:2;
then abs (((a #Q s) . m) - (a #Q (s . n))) < c by Def7;
hence abs (((a #Q s) . m) - ((a #Q s) . n)) < c by Def7; :: thesis: verum

end;

hence a #Q s is convergent by SEQ_4:41; :: thesis: verum