let r, s be Real; :: thesis: ( ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of x0 st
( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) ) ) & ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of x0 st
( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) ) ) implies r = s )
assume that
A6: ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of x0 st
( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) ) ) and
A7: ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of x0 st
( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) ) ) ; :: thesis: r = s
consider x0, y0, z0 being Real such that
A8: ( u = <*x0,y0,z0*> & ex N being Neighbourhood of x0 st
( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) ) ) by A6;
consider N being Neighbourhood of x0 such that
A9: ( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) ) by A8;
consider L being LINEAR, R being REST such that
A10: ( r = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) ) ) by A9;
consider x1, y1, z1 being Real such that
A11: ( u = <*x1,y1,z1*> & ex N being Neighbourhood of x1 st
( N c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for x being Real st x in N holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x1) = (L . (x - x1)) + (R . (x - x1)) ) ) ) ) by A7;
consider N1 being Neighbourhood of x1 such that
A12: ( N1 c= dom (SVF1 (1,(pdiff1 (f,1)),u)) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for x being Real st x in N1 holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x1) = (L . (x - x1)) + (R . (x - x1)) ) ) ) by A11;
consider L1 being LINEAR, R1 being REST such that
A13: ( s = L1 . 1 & ( for x being Real st x in N1 holds
((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x1) = (L1 . (x - x1)) + (R1 . (x - x1)) ) ) by A12;
consider r1 being Real such that
A14: for p being Real holds L . p = r1 * p by FDIFF_1:def 3;
consider p1 being Real such that
A15: for p being Real holds L1 . p = p1 * p by FDIFF_1:def 3;
A16: r = r1 * 1 by A10, A14;
A17: s = p1 * 1 by A13, A15;
A18: ( x0 = x1 & y0 = y1 & z0 = z1 ) by A8, A11, FINSEQ_1:78;
A19: now
let x be Real; :: thesis: ( x in N & x in N1 implies (r * (x - x0)) + (R . (x - x0)) = (s * (x - x0)) + (R1 . (x - x0)) )
assume A20: ( x in N & x in N1 ) ; :: thesis: (r * (x - x0)) + (R . (x - x0)) = (s * (x - x0)) + (R1 . (x - x0))
then ((SVF1 (1,(pdiff1 (f,1)),u)) . x) - ((SVF1 (1,(pdiff1 (f,1)),u)) . x0) = (L . (x - x0)) + (R . (x - x0)) by A10;
then (L . (x - x0)) + (R . (x - x0)) = (L1 . (x - x0)) + (R1 . (x - x0)) by A13, A18, A20;
then (r1 * (x - x0)) + (R . (x - x0)) = (L1 . (x - x0)) + (R1 . (x - x0)) by A14;
hence (r * (x - x0)) + (R . (x - x0)) = (s * (x - x0)) + (R1 . (x - x0)) by A15, A16, A17; :: thesis: verum
end;
consider N0 being Neighbourhood of x0 such that
A21: ( N0 c= N & N0 c= N1 ) by A18, RCOMP_1:17;
consider g being real number such that
A22: ( 0 < g & N0 = ].(x0 - g),(x0 + g).[ ) by RCOMP_1:def 6;
deffunc H1( Element of NAT ) -> Element of REAL = g / ($1 + 2);
consider s1 being Real_Sequence such that
A23: for n being Element of NAT holds s1 . n = H1(n) from SEQ_1:sch 1();
now
let n be Element of NAT ; :: thesis: s1 . n <> 0
g / (n + 2) <> 0 by A22, XREAL_1:139;
hence s1 . n <> 0 by A23; :: thesis: verum
end;
then A24: s1 is non-zero by SEQ_1:5;
( s1 is convergent & lim s1 = 0 ) by A23, SEQ_4:31;
then reconsider h = s1 as convergent_to_0 Real_Sequence by A24, FDIFF_1:def 1;
A25: for n being Element of NAT ex x being Real st
( x in N & x in N1 & h . n = x - x0 )
proof
let n be Element of NAT ; :: thesis: ex x being Real st
( x in N & x in N1 & h . n = x - x0 )
A26: g / (n + 2) > 0 by A22, XREAL_1:139;
0 + 1 < (n + 1) + 1 by XREAL_1:6;
then g / (n + 2) < g / 1 by A22, XREAL_1:76;
then A27: x0 + (g / (n + 2)) < x0 + g by XREAL_1:6;
x0 + (- g) < x0 + (g / (n + 2)) by A22, A26, XREAL_1:6;
then A28: x0 + (g / (n + 2)) in ].(x0 - g),(x0 + g).[ by A27;
take x0 + (g / (n + 2)) ; :: thesis: ( x0 + (g / (n + 2)) in N & x0 + (g / (n + 2)) in N1 & h . n = (x0 + (g / (n + 2))) - x0 )
thus ( x0 + (g / (n + 2)) in N & x0 + (g / (n + 2)) in N1 & h . n = (x0 + (g / (n + 2))) - x0 ) by A21, A22, A23, A28; :: thesis: verum
end;
A29: for n being Nat holds r - s = (((h ") (#) (R1 /* h)) - ((h ") (#) (R /* h))) . n
proof
let n be Nat; :: thesis: r - s = (((h ") (#) (R1 /* h)) - ((h ") (#) (R /* h))) . n
A30: n in NAT by ORDINAL1:def 12;
then ex x being Real st
( x in N & x in N1 & h . n = x - x0 ) by A25;
then A31: (r * (h . n)) + (R . (h . n)) = (s * (h . n)) + (R1 . (h . n)) by A19;
h is non-zero by FDIFF_1:def 1;
then A32: h . n <> 0 by A30, SEQ_1:5;
A33: ((r * (h . n)) / (h . n)) + ((R . (h . n)) / (h . n)) = ((s * (h . n)) + (R1 . (h . n))) / (h . n) by A31, XCMPLX_1:62;
A34: (r * (h . n)) / (h . n) = r * ((h . n) / (h . n)) by XCMPLX_1:74
.= r * 1 by A32, XCMPLX_1:60
.= r ;
(s * (h . n)) / (h . n) = s * ((h . n) / (h . n)) by XCMPLX_1:74
.= s * 1 by A32, XCMPLX_1:60
.= s ;
then A35: r + ((R . (h . n)) / (h . n)) = s + ((R1 . (h . n)) / (h . n)) by A33, A34, XCMPLX_1:62;
dom R = REAL by PARTFUN1:def 2;
then A36: rng h c= dom R ;
dom R1 = REAL by PARTFUN1:def 2;
then A37: rng h c= dom R1 ;
A38: (R . (h . n)) / (h . n) = (R . (h . n)) * ((h . n) ") by XCMPLX_0:def 9
.= (R . (h . n)) * ((h ") . n) by VALUED_1:10
.= ((R /* h) . n) * ((h ") . n) by A36, A30, FUNCT_2:108
.= ((h ") (#) (R /* h)) . n by VALUED_1:5 ;
(R1 . (h . n)) / (h . n) = (R1 . (h . n)) * ((h . n) ") by XCMPLX_0:def 9
.= (R1 . (h . n)) * ((h ") . n) by VALUED_1:10
.= ((R1 /* h) . n) * ((h ") . n) by A37, A30, FUNCT_2:108
.= ((h ") (#) (R1 /* h)) . n by VALUED_1:5 ;
then r = s + ((((h ") (#) (R1 /* h)) . n) - (((h ") (#) (R /* h)) . n)) by A35, A38;
hence r - s = (((h ") (#) (R1 /* h)) - ((h ") (#) (R /* h))) . n by A30, RFUNCT_2:1; :: thesis: verum
end;
then A39: ((h ") (#) (R1 /* h)) - ((h ") (#) (R /* h)) is constant by VALUED_0:def 18;
(((h ") (#) (R1 /* h)) - ((h ") (#) (R /* h))) . 1 = r - s by A29;
then A40: lim (((h ") (#) (R1 /* h)) - ((h ") (#) (R /* h))) = r - s by A39, SEQ_4:25;
A41: ( (h ") (#) (R /* h) is convergent & lim ((h ") (#) (R /* h)) = 0 ) by FDIFF_1:def 2;
( (h ") (#) (R1 /* h) is convergent & lim ((h ") (#) (R1 /* h)) = 0 ) by FDIFF_1:def 2;
then r - s = 0 - 0 by A40, A41, SEQ_2:12;
hence r = s ; :: thesis: verum