let I be Function of REAL,(REAL 1); :: thesis:
let J be Function of (REAL 1),REAL; :: thesis:
assume that
A1: I = (proj (1,1)) " and
A2: J = proj (1,1) ; :: thesis:
thus for R being REST holds (I * R) * J is REST of (REAL-NS 1),(REAL-NS 1) :: thesis:

proof

let R be REST; :: thesis:
R is total by FDIFF_1:def 2;
then reconsider R0 = R as Function of REAL,REAL ;
A3: the carrier of (REAL-NS 1) = REAL 1 by REAL_NS1:def 4;
then reconsider R1 = (I * R0) * J as PartFunc of (REAL-NS 1),(REAL-NS 1) ;
for h being convergent_to_0 sequence of (REAL-NS 1) holds
( (||.h.|| ") (#) (R1 /* h) is convergent & lim ((||.h.|| ") (#) (R1 /* h)) = 0. (REAL-NS 1) )

proof

let h be convergent_to_0 sequence of (REAL-NS 1); :: thesis:
A4: lim h = 0. (REAL-NS 1) by NDIFF_1:def 4;
deffunc H₁( Element of NAT ) -> Element of REAL = J . (h . $1);
consider s being Real_Sequence such that
A5: for n being Element of NAT holds s . n = H₁(n) from SEQ_1:sch 1();
A6: h is convergent by NDIFF_1:def 4;

A7: now

let p be real number ; :: thesis:
A8: p is Real by XREAL_0:def 1;
assume 0 < p ; :: thesis:
then consider m being Element of NAT such that
A9: for n being Element of NAT st m <= n holds
||.((h . n) - (0. (REAL-NS 1))).|| < p by A6, A4, A8, NORMSP_1:def 7;
take m = m; :: thesis:

now

let n be Element of NAT ; :: thesis:
assume m <= n ; :: thesis:
then ||.((h . n) - (0. (REAL-NS 1))).|| < p by A9;
then A10: ||.(h . n).|| < p by RLVECT_1:13;
s . n = J . (h . n) by A5;
hence abs ((s . n) - 0) < p by A2, A10, Th4; :: thesis:

end;

hence for n being Element of NAT st m <= n holds
abs ((s . n) - 0) < p ; :: thesis:

end;

then A11: s is convergent by SEQ_2:def 6;
then A12: lim s = 0 by A7, SEQ_2:def 7;
A13: h is non-zero by NDIFF_1:def 4;

now

let x be set ; :: thesis:
assume x in NAT ; :: thesis:
then reconsider n = x as Element of NAT ;
A14: 0 <= abs (s . n) by COMPLEX1:46;
h . n <> 0. (REAL-NS 1) by A13, NDIFF_1:6;
then A15: ||.(h . n).|| <> 0 by NORMSP_0:def 5;
s . n = J . (h . n) by A5;
then abs (s . n) <> 0 by A2, A15, Th4;
hence s . x <> 0 by A14, COMPLEX1:47; :: thesis:

end;

then s is non-empty by SEQ_1:4;
then reconsider s = s as convergent_to_0 Real_Sequence by A11, A12, FDIFF_1:def 1;
A16: J * I = id REAL by A1, A2, Lm1, FUNCT_1:39;

now

reconsider f1 = R1 as Function ;
let n be Element of NAT ; :: thesis:
A17: rng h c= the carrier of (REAL-NS 1) ;
h . n in the carrier of (REAL-NS 1) ;
then A18: h . n in REAL 1 by REAL_NS1:def 4;
R1 is total by A3;
then (R /* s) . n = R . (s . n) by FUNCT_2:115;
then (R /* s) . n = R . (J . (h . n)) by A5;
then (R /* s) . n = (J * I) . (R0 . (J . (h . n))) by A16, FUNCT_1:18;
then (R /* s) . n = (J * I) . ((R0 * J) . (h . n)) by A18, FUNCT_2:15;
then (R /* s) . n = J . (I . ((R0 * J) . (h . n))) by FUNCT_2:15;
then A19: (R /* s) . n = J . ((I * (R0 * J)) . (h . n)) by A18, FUNCT_2:15;
NAT = dom h by FUNCT_2:def 1;
then A20: R1 . (h . n) = (f1 * h) . n by FUNCT_1:13;
dom R1 = REAL 1 by FUNCT_2:def 1;
then rng h c= dom R1 by A17, REAL_NS1:def 4;
then R1 . (h . n) = (R1 /* h) . n by A20, FUNCT_2:def 11;
then A21: (R /* s) . n = J . ((R1 /* h) . n) by A19, RELAT_1:36;
A22: ||.(h . n).|| >= 0 by NORMSP_1:4;
A23: s . n = J . (h . n) by A5;
||.((||.h.|| ") (#) (R1 /* h)).|| . n = ||.(((||.h.|| ") (#) (R1 /* h)) . n).|| by NORMSP_0:def 4
.= ||.(((||.h.|| ") . n) * ((R1 /* h) . n)).|| by NDIFF_1:def 2
.= (abs ((||.h.|| ") . n)) * ||.((R1 /* h) . n).|| by NORMSP_1:def 1
.= (abs ((||.h.|| . n) ")) * ||.((R1 /* h) . n).|| by VALUED_1:10
.= (abs (||.(h . n).|| ")) * ||.((R1 /* h) . n).|| by NORMSP_0:def 4
.= (||.(h . n).|| ") * ||.((R1 /* h) . n).|| by A22, ABSVALUE:def 1
.= ((abs (s . n)) ") * ||.((R1 /* h) . n).|| by A2, A23, Th4
.= ((abs (s . n)) ") * (abs ((R /* s) . n)) by A2, A21, Th4
.= ((abs (s . n)) ") * ((abs (R /* s)) . n) by SEQ_1:12
.= (((abs s) . n) ") * ((abs (R /* s)) . n) by SEQ_1:12
.= (((abs s) ") . n) * ((abs (R /* s)) . n) by VALUED_1:10
.= (((abs s) ") (#) (abs (R /* s))) . n by SEQ_1:8
.= ((abs (s ")) (#) (abs (R /* s))) . n by SEQ_1:54 ;
hence ||.((||.h.|| ") (#) (R1 /* h)).|| . n = (abs ((s ") (#) (R /* s))) . n by SEQ_1:52; :: thesis:

end;

then A24: ||.((||.h.|| ") (#) (R1 /* h)).|| = abs ((s ") (#) (R /* s)) by FUNCT_2:63;
A25: lim ((s ") (#) (R /* s)) = 0 by FDIFF_1:def 2;
A26: (s ") (#) (R /* s) is convergent by FDIFF_1:def 2;
then lim (abs ((s ") (#) (R /* s))) = abs (lim ((s ") (#) (R /* s))) by SEQ_4:14;
then A27: lim (abs ((s ") (#) (R /* s))) = 0 by A25, ABSVALUE:2;
A28: abs ((s ") (#) (R /* s)) is convergent by A26, SEQ_4:13;

A29: now

let p be Real; :: thesis:
assume 0 < p ; :: thesis:
then consider m being Element of NAT such that
A30: for n being Element of NAT st m <= n holds
abs ((||.((||.h.|| ") (#) (R1 /* h)).|| . n) - 0) < p by A24, A28, A27, SEQ_2:def 7;
take m = m; :: thesis:

hereby :: thesis:

let n be Element of NAT ; :: thesis:
assume m <= n ; :: thesis:
then abs ((||.((||.h.|| ") (#) (R1 /* h)).|| . n) - 0) < p by A30;
then A31: abs ||.(((||.h.|| ") (#) (R1 /* h)) . n).|| < p by NORMSP_0:def 4;
0 <= ||.(((||.h.|| ") (#) (R1 /* h)) . n).|| by NORMSP_1:4;
then ||.(((||.h.|| ") (#) (R1 /* h)) . n).|| < p by A31, ABSVALUE:def 1;
hence ||.((((||.h.|| ") (#) (R1 /* h)) . n) - (0. (REAL-NS 1))).|| < p by RLVECT_1:13; :: thesis:

end;

then (||.h.|| ") (#) (R1 /* h) is convergent by NORMSP_1:def 6;
hence ( (||.h.|| ") (#) (R1 /* h) is convergent & lim ((||.h.|| ") (#) (R1 /* h)) = 0. (REAL-NS 1) ) by A29, NORMSP_1:def 7; :: thesis:

end;

hence (I * R) * J is REST of (REAL-NS 1),(REAL-NS 1) by A3, NDIFF_1:def 5; :: thesis:

end;

thus for L being LINEAR holds (I * L) * J is bounded LinearOperator of (REAL-NS 1),(REAL-NS 1) :: thesis:

proof

let L be LINEAR; :: thesis:
consider r being Real such that
A32: for p being Real holds L . p = r * p by FDIFF_1:def 3;
L is total by FDIFF_1:def 3;
then reconsider L0 = L as Function of REAL,REAL ;
set K = abs r;
A33: the carrier of (REAL-NS 1) = REAL 1 by REAL_NS1:def 4;
(I * L0) * J is Function of (REAL 1),(REAL 1) ;
then reconsider L1 = (I * L) * J as Function of (REAL-NS 1),(REAL-NS 1) by A33;
A34: dom L1 = REAL 1 by A33, FUNCT_2:def 1;
A35: dom L0 = REAL by FUNCT_2:def 1;

A36: now

let x, y be VECTOR of (REAL-NS 1); :: thesis:
I . (L . (J . y)) = (I * L) . (J . y) by A35, FUNCT_1:13;
then A37: I . (L . (J . y)) = L1 . y by A33, A34, FUNCT_1:12;
L1 . (x + y) = (I * L) . (J . (x + y)) by A33, A34, FUNCT_1:12;
then L1 . (x + y) = (I * L) . ((J . x) + (J . y)) by A2, Th4;
then L1 . (x + y) = I . (L . ((J . x) + (J . y))) by A35, FUNCT_1:13;
then L1 . (x + y) = I . (r * ((J . x) + (J . y))) by A32;
then L1 . (x + y) = I . ((r * (J . x)) + (r * (J . y))) ;
then L1 . (x + y) = I . ((L . (J . x)) + (r * (J . y))) by A32;
then A38: L1 . (x + y) = I . ((L . (J . x)) + (L . (J . y))) by A32;
I . (L . (J . x)) = (I * L) . (J . x) by A35, FUNCT_1:13;
then I . (L . (J . x)) = L1 . x by A33, A34, FUNCT_1:12;
hence L1 . (x + y) = (L1 . x) + (L1 . y) by A1, A37, A38, Th3; :: thesis:

end;

now

let x be VECTOR of (REAL-NS 1); :: thesis:
let a be Real; :: thesis:
L1 . (a * x) = (I * L) . (J . (a * x)) by A33, A34, FUNCT_1:12;
then L1 . (a * x) = (I * L) . (a * (J . x)) by A2, Th4;
then L1 . (a * x) = I . (L . (a * (J . x))) by A35, FUNCT_1:13;
then L1 . (a * x) = I . (r * (a * (J . x))) by A32;
then L1 . (a * x) = I . (a * (r * (J . x))) ;
then A39: L1 . (a * x) = I . (a * (L . (J . x))) by A32;
I . (L . (J . x)) = (I * L) . (J . x) by A35, FUNCT_1:13;
then I . (L . (J . x)) = L1 . x by A33, A34, FUNCT_1:12;
hence L1 . (a * x) = a * (L1 . x) by A1, A39, Th3; :: thesis:

end;

then reconsider L1 = L1 as LinearOperator of (REAL-NS 1),(REAL-NS 1) by A36, GRCAT_1:def 8, LOPBAN_1:def 5;

A40: now

let x be VECTOR of (REAL-NS 1); :: thesis:
I . (L . (J . x)) = (I * L) . (J . x) by A35, FUNCT_1:13;
then I . (L . (J . x)) = L1 . x by A33, A34, FUNCT_1:12;
then ||.(L1 . x).|| = abs (L . (J . x)) by A1, Th3;
then ||.(L1 . x).|| = abs (r * (J . x)) by A32;
then ||.(L1 . x).|| = (abs r) * (abs (J . x)) by COMPLEX1:65;
hence ||.(L1 . x).|| <= (abs r) * ||.x.|| by A2, Th4; :: thesis:

end;

0 <= abs r by COMPLEX1:46;
hence (I * L) * J is bounded LinearOperator of (REAL-NS 1),(REAL-NS 1) by A40, LOPBAN_1:def 8; :: thesis:

end;