let X be set ; :: thesis: for p being Real
for S, T being RealNormSpace
for f being PartFunc of S,T st f is_Lipschitzian_on X holds
p (#) f is_Lipschitzian_on X
let p be Real; :: thesis: for S, T being RealNormSpace
for f being PartFunc of S,T st f is_Lipschitzian_on X holds
p (#) f is_Lipschitzian_on X
let S, T be RealNormSpace; :: thesis: for f being PartFunc of S,T st f is_Lipschitzian_on X holds
p (#) f is_Lipschitzian_on X
let f be PartFunc of S,T; :: thesis: ( f is_Lipschitzian_on X implies p (#) f is_Lipschitzian_on X )
assume A1: f is_Lipschitzian_on X ; :: thesis: p (#) f is_Lipschitzian_on X
then consider s being Real such that
A2: 0 < s and
A3: for x1, x2 being Point of S st x1 in X & x2 in X holds
||.((f /. x1) - (f /. x2)).|| <= s * ||.(x1 - x2).|| by Def13;
X c= dom f by A1, Def13;
hence A4: X c= dom (p (#) f) by VFUNCT_1:def 4; :: according to NFCONT_1:def 9 :: thesis: ex r being Real st
( 0 < r & ( for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= r * ||.(x1 - x2).|| ) )

now

per cases ( p = 0 or p <> 0 ) ;

suppose A5: p = 0 ; :: thesis: ex s being Real st
( 0 < s & ( for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| ) )

take s = s; :: thesis: ( 0 < s & ( for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| ) )
thus 0 < s by A2; :: thesis: for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= s * ||.(x1 - x2).||
let x1, x2 be Point of S; :: thesis: ( x1 in X & x2 in X implies ||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| )
assume that
A6: x1 in X and
A7: x2 in X ; :: thesis: ||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= s * ||.(x1 - x2).||
0 <= ||.(x1 - x2).|| by NORMSP_1:4;
then A8: s * 0 <= s * ||.(x1 - x2).|| by A2, XREAL_1:64;
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| = ||.((p * (f /. x1)) - ((p (#) f) /. x2)).|| by A4, A6, VFUNCT_1:def 4
.= ||.((0. T) - ((p (#) f) /. x2)).|| by A5, RLVECT_1:10
.= ||.((0. T) - (p * (f /. x2))).|| by A4, A7, VFUNCT_1:def 4
.= ||.((0. T) - (0. T)).|| by A5, RLVECT_1:10
.= ||.(0. T).|| by RLVECT_1:13
.= 0 by NORMSP_1:1 ;
hence ||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| by A8; :: thesis: verum

end;

suppose A9: p <> 0 ; :: thesis: ex g being Element of REAL st
( 0 < g & ( for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| ) )

take g = (abs p) * s; :: thesis: ( 0 < g & ( for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| ) )
0 < abs p by A9, COMPLEX1:47;
then 0 * s < (abs p) * s by A2, XREAL_1:68;
hence 0 < g ; :: thesis: for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= g * ||.(x1 - x2).||
let x1, x2 be Point of S; :: thesis: ( x1 in X & x2 in X implies ||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| )
assume that
A10: x1 in X and
A11: x2 in X ; :: thesis: ||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= g * ||.(x1 - x2).||
0 <= abs p by COMPLEX1:46;
then A12: (abs p) * ||.((f /. x1) - (f /. x2)).|| <= (abs p) * (s * ||.(x1 - x2).||) by A3, A10, A11, XREAL_1:64;
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| = ||.((p * (f /. x1)) - ((p (#) f) /. x2)).|| by A4, A10, VFUNCT_1:def 4
.= ||.((p * (f /. x1)) - (p * (f /. x2))).|| by A4, A11, VFUNCT_1:def 4
.= ||.(p * ((f /. x1) - (f /. x2))).|| by RLVECT_1:34
.= (abs p) * ||.((f /. x1) - (f /. x2)).|| by NORMSP_1:def 1 ;
hence ||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| by A12; :: thesis: verum

end;

end;

end;

hence ex r being Real st
( 0 < r & ( for x1, x2 being Point of S st x1 in X & x2 in X holds
||.(((p (#) f) /. x1) - ((p (#) f) /. x2)).|| <= r * ||.(x1 - x2).|| ) ) ; :: thesis: verum