let S, T be non trivial RealNormSpace; :: thesis: for R1 being REST of S st R1 /. 0 = 0. S holds
for R2 being REST of S,T st R2 /. (0. S) = 0. T holds
for L being LINEAR of S holds R2 * (L + R1) is REST of T
let R1 be REST of S; :: thesis: ( R1 /. 0 = 0. S implies for R2 being REST of S,T st R2 /. (0. S) = 0. T holds
for L being LINEAR of S holds R2 * (L + R1) is REST of T )
assume R1 /. 0 = 0. S ; :: thesis: for R2 being REST of S,T st R2 /. (0. S) = 0. T holds
for L being LINEAR of S holds R2 * (L + R1) is REST of T
then consider d0 being Real such that
A1: 0 < d0 and
A2: for h being Real st |.h.| < d0 holds
||.(R1 /. h).|| <= 1 * |.h.| by NDIFF27;
let R2 be REST of S,T; :: thesis: ( R2 /. (0. S) = 0. T implies for L being LINEAR of S holds R2 * (L + R1) is REST of T )
assume A3: R2 /. (0. S) = 0. T ; :: thesis: for L being LINEAR of S holds R2 * (L + R1) is REST of T
let L be LINEAR of S; :: thesis: R2 * (L + R1) is REST of T
consider r being Point of S such that
A4: for h being Real holds L . h = h * r by NDIFF_3:def 2;
reconsider K = ||.r.|| as Real ;
R2 is total by NDIFF_1:def 5;
then dom R2 = the carrier of S by PARTFUN1:def 2;
then A6: rng (L + R1) c= dom R2 ;
R1 is total by NDIFF_3:def 1;
then L + R1 is total by VFUNCT_1:32;
then A8: dom (L + R1) = REAL by PARTFUN1:def 2;
then dom (R2 * (L + R1)) = REAL by A6, RELAT_1:27;
then A9: R2 * (L + R1) is total by PARTFUN1:def 2;

now

let e be Real; :: thesis: ( e > 0 implies ex dd1 being Real st
( dd1 > 0 & ( for h being Real st h <> 0 & |.h.| < dd1 holds
(|.h.| ") * ||.((R2 * (L + R1)) /. h).|| < e ) ) )
assume A10: e > 0 ; :: thesis: ex dd1 being Real st
( dd1 > 0 & ( for h being Real st h <> 0 & |.h.| < dd1 holds
(|.h.| ") * ||.((R2 * (L + R1)) /. h).|| < e ) )
A11: e / 2 < e by A10, XREAL_1:216;
set e1 = (e / 2) / (1 + K);
consider d being Real such that
A12: 0 < d and
A13: for z being Point of S st ||.z.|| < d holds
||.(R2 /. z).|| <= ((e / 2) / (1 + K)) * ||.z.|| by A3, A10, NDIFF_2:7;
set d1 = d / (1 + K);
set dd1 = min (d0,(d / (1 + K)));
A14: ( min (d0,(d / (1 + K))) <= d / (1 + K) & min (d0,(d / (1 + K))) <= d0 ) by XXREAL_0:17;

A16: now

let h be Real; :: thesis: ( h <> 0 & |.h.| < min (d0,(d / (1 + K))) implies (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| < e )
assume that
A17: h <> 0 and
A18: |.h.| < min (d0,(d / (1 + K))) ; :: thesis: (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| < e
|.h.| < d0 by A14, A18, XXREAL_0:2;
then A19: ||.(R1 /. h).|| <= 1 * |.h.| by A2;
reconsider p0 = 0 as Real ;
L . h = h * r by A4;
then (||.(L . h).|| - (K * |.h.|)) + (K * |.h.|) <= p0 + (K * |.h.|) by NORMSP_1:def 1;
then ( ||.((L . h) + (R1 /. h)).|| <= ||.(L . h).|| + ||.(R1 /. h).|| & ||.(L . h).|| + ||.(R1 /. h).|| <= (K * |.h.|) + (1 * |.h.|) ) by A19, NORMSP_1:def 1, XREAL_1:7;
then A20: ||.((L . h) + (R1 /. h)).|| <= (K + 1) * |.h.| by XXREAL_0:2;
then A21: ((e / 2) / (1 + K)) * ||.((L . h) + (R1 /. h)).|| <= ((e / 2) / (1 + K)) * ((K + 1) * |.h.|) by A10, XREAL_1:64;
|.h.| < d / (1 + K) by A14, A18, XXREAL_0:2;
then (K + 1) * |.h.| < (K + 1) * (d / (1 + K)) by XREAL_1:68;
then ||.((L . h) + (R1 /. h)).|| < (K + 1) * (d / (1 + K)) by A20, XXREAL_0:2;
then ||.((L . h) + (R1 /. h)).|| < d by XCMPLX_1:87;
then ||.(R2 /. ((L . h) + (R1 /. h))).|| <= ((e / 2) / (1 + K)) * ||.((L . h) + (R1 /. h)).|| by A13;
then A22: ||.(R2 /. ((L . h) + (R1 /. h))).|| <= ((e / 2) / (1 + K)) * ((K + 1) * |.h.|) by A21, XXREAL_0:2;
A23: R2 /. ((L . h) + (R1 /. h)) = R2 /. ((L /. h) + (R1 /. h))
.= R2 /. ((L + R1) /. h) by A8, VFUNCT_1:def 1
.= (R2 * (L + R1)) /. h by A8, A6, PARTFUN2:5 ;
A24: |.h.| <> 0 by A17, COMPLEX1:45;
then |.h.| > 0 by COMPLEX1:46;
then (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| <= (|.h.| ") * ((((e / 2) / (1 + K)) * (K + 1)) * |.h.|) by A23, A22, XREAL_1:64;
then (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| <= ((|.h.| * (|.h.| ")) * ((e / 2) / (1 + K))) * (K + 1) ;
then (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| <= (1 * ((e / 2) / (1 + K))) * (K + 1) by A24, XCMPLX_0:def 7;
then (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| <= e / 2 by XCMPLX_1:87;
hence (|.h.| ") * ||.((R2 * (L + R1)) /. h).|| < e by A11, XXREAL_0:2; :: thesis: verum

end;

0 < min (d0,(d / (1 + K))) by A1, A12, XXREAL_0:15;
hence ex dd1 being Real st
( dd1 > 0 & ( for h being Real st h <> 0 & |.h.| < dd1 holds
(|.h.| ") * ||.((R2 * (L + R1)) /. h).|| < e ) ) by A16; :: thesis: verum

end;

hence R2 * (L + R1) is REST of T by A9, NDIFF126; :: thesis: verum