let R be Function of REAL,REAL; :: thesis: ( R is REST-like iff for r being Real st r > 0 holds
ex d being Real st
( d > 0 & ( for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r ) ) )

A2: now

assume A3: R is REST-like ; :: thesis: ( ex r being Real st
( r > 0 & ( for d being Real holds
( not d > 0 or ex z being Real st
( z <> 0 & abs z < d & not (abs (R . z)) / (abs z) < r ) ) ) ) implies for r being Real st r > 0 holds
ex d being Real st
( d > 0 & ( for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r ) ) )
assume ex r being Real st
( r > 0 & ( for d being Real holds
( not d > 0 or ex z being Real st
( z <> 0 & abs z < d & not (abs (R . z)) / (abs z) < r ) ) ) ) ; :: thesis: for r being Real st r > 0 holds
ex d being Real st
( d > 0 & ( for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r ) )
then consider r being Real such that
A4: r > 0 and
A5: for d being Real st d > 0 holds
ex z being Real st
( z <> 0 & abs z < d & not (abs (R . z)) / (abs z) < r ) ;
defpred S₁[ Element of NAT , Element of REAL ] means ( $2 <> 0 & abs $2 < 1 / ($1 + 1) & not (abs (R . $2)) / (abs $2) < r );

A6: now

let n be Element of NAT ; :: thesis: ex z being Element of REAL st S₁[n,z]
1 / (n + 1) is Real by XREAL_0:def 1;
hence ex z being Element of REAL st S₁[n,z] by A5; :: thesis: verum

end;

consider s being Real_Sequence such that
A7: for n being Element of NAT holds S₁[n,s . n] from FUNCT_2:sch 3(A6);

A8: now

let p be real number ; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((s . m) - 0) < p )
assume A9: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((s . m) - 0) < p
consider n being Element of NAT such that
A10: p " < n by SEQ_4:3;
(p ") + 0 < n + 1 by A10, XREAL_1:8;
then A11: 1 / (n + 1) < 1 / (p ") by A9, XREAL_1:76;
take n = n; :: thesis: for m being Element of NAT st n <= m holds
abs ((s . m) - 0) < p
let m be Element of NAT ; :: thesis: ( n <= m implies abs ((s . m) - 0) < p )
assume n <= m ; :: thesis: abs ((s . m) - 0) < p
then n + 1 <= m + 1 by XREAL_1:6;
then 1 / (m + 1) <= 1 / (n + 1) by XREAL_1:118;
then abs ((s . m) - 0) < 1 / (n + 1) by A7, XXREAL_0:2;
hence abs ((s . m) - 0) < p by A11, XXREAL_0:2; :: thesis: verum

end;

then A14: s is convergent by SEQ_2:def 6;
then A15: lim s = 0 by A8, SEQ_2:def 7;
s is non-empty by A7, SEQ_1:5;
then reconsider s = s as convergent_to_0 Real_Sequence by A14, A15, FDIFF_1:def 1;
( (s ") (#) (R /* s) is convergent & lim ((s ") (#) (R /* s)) = 0 ) by A3, FDIFF_1:def 2;
then consider n being Element of NAT such that
A16: for m being Element of NAT st n <= m holds
abs ((((s ") (#) (R /* s)) . m) - 0) < r by A4, SEQ_2:def 7;
A17: abs ((((s ") (#) (R /* s)) . n) - 0) < r by A16;
A19: abs (((s . n) ") * (R . (s . n))) = (abs ((s . n) ")) * (abs (R . (s . n))) by COMPLEX1:65
.= (abs (R . (s . n))) / (abs (s . n)) by COMPLEX1:66 ;
abs ((((s ") (#) (R /* s)) . n) - 0) = abs (((s ") . n) * ((R /* s) . n)) by SEQ_1:8
.= abs (((s . n) ") * ((R /* s) . n)) by VALUED_1:10
.= abs (((s . n) ") * (R . (s . n))) by FUNCT_2:115 ;
hence for r being Real st r > 0 holds
ex d being Real st
( d > 0 & ( for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r ) ) by A7, A17, A19; :: thesis: verum

end;

now

assume A21: for r being Real st r > 0 holds
ex d being Real st
( d > 0 & ( for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r ) ) ; :: thesis: R is REST-like

now

let s be convergent_to_0 Real_Sequence; :: thesis: ( (s ") (#) (R /* s) is convergent & lim ((s ") (#) (R /* s)) = 0 )
A22: s is non-empty by FDIFF_1:def 1;
A23: ( s is convergent & lim s = 0 ) by FDIFF_1:def 1;

A24: now

let r be real number ; :: thesis: ( r > 0 implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((((s ") (#) (R /* s)) . m) - 0) < r )
assume D1: r > 0 ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((((s ") (#) (R /* s)) . m) - 0) < r
r is Real by XREAL_0:def 1;
then consider d being Real such that
A25: d > 0 and
A26: for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r by D1, A21;
consider n being Element of NAT such that
A27: for m being Element of NAT st n <= m holds
abs ((s . m) - 0) < d by A23, A25, SEQ_2:def 7;
take n = n; :: thesis: for m being Element of NAT st n <= m holds
abs ((((s ") (#) (R /* s)) . m) - 0) < r

hereby :: thesis: verum

let m be Element of NAT ; :: thesis: ( n <= m implies abs ((((s ") (#) (R /* s)) . m) - 0) < r )
assume n <= m ; :: thesis: abs ((((s ") (#) (R /* s)) . m) - 0) < r
then A29: abs ((s . m) - 0) < d by A27;
A30: s . m <> 0 by A22, SEQ_1:5;
(abs (R . (s . m))) / (abs (s . m)) = (abs ((s . m) ")) * (abs (R . (s . m))) by COMPLEX1:66
.= abs (((s . m) ") * (R . (s . m))) by COMPLEX1:65
.= abs (((s . m) ") * ((R /* s) . m)) by FUNCT_2:115
.= abs (((s ") . m) * ((R /* s) . m)) by VALUED_1:10
.= abs ((((s ") (#) (R /* s)) . m) - 0) by SEQ_1:8 ;
hence abs ((((s ") (#) (R /* s)) . m) - 0) < r by A26, A29, A30; :: thesis: verum

end;

end;

hence (s ") (#) (R /* s) is convergent by SEQ_2:def 6; :: thesis: lim ((s ") (#) (R /* s)) = 0
hence lim ((s ") (#) (R /* s)) = 0 by A24, SEQ_2:def 7; :: thesis: verum

end;

hence R is REST-like by FDIFF_1:def 2; :: thesis: verum

end;

hence ( R is REST-like iff for r being Real st r > 0 holds
ex d being Real st
( d > 0 & ( for z being Real st z <> 0 & abs z < d holds
(abs (R . z)) / (abs z) < r ) ) ) by A2; :: thesis: verum