let F be non trivial RealNormSpace; :: thesis: for x0 being Real
for f being PartFunc of REAL, the carrier of F
for r being Real st f is_differentiable_in x0 holds
( r (#) f is_differentiable_in x0 & diff ((r (#) f),x0) = r * (diff (f,x0)) )
let x0 be Real; :: thesis: for f being PartFunc of REAL, the carrier of F
for r being Real st f is_differentiable_in x0 holds
( r (#) f is_differentiable_in x0 & diff ((r (#) f),x0) = r * (diff (f,x0)) )
let f be PartFunc of REAL, the carrier of F; :: thesis: for r being Real st f is_differentiable_in x0 holds
( r (#) f is_differentiable_in x0 & diff ((r (#) f),x0) = r * (diff (f,x0)) )
let r be Real; :: thesis: ( f is_differentiable_in x0 implies ( r (#) f is_differentiable_in x0 & diff ((r (#) f),x0) = r * (diff (f,x0)) ) )
assume A1: f is_differentiable_in x0 ; :: thesis: ( r (#) f is_differentiable_in x0 & diff ((r (#) f),x0) = r * (diff (f,x0)) )
then consider N1 being Neighbourhood of x0 such that
A2: N1 c= dom f and
A3: ex L being LINEAR of F ex R being REST of F st
for x being Real st x in N1 holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) by Def3;
consider L1 being LINEAR of F, R1 being REST of F such that
A4: for x being Real st x in N1 holds
(f /. x) - (f /. x0) = (L1 . (x - x0)) + (R1 /. (x - x0)) by A3;
reconsider R = r (#) R1 as REST of F by Th8;
reconsider L = r (#) L1 as LINEAR of F by Th4;
A5: dom L1 = REAL by FUNCT_2:def 1;
A6: N1 c= dom (r (#) f) by A2, VFUNCT_1:def 4;
R1 is total by Def1;
then r (#) R1 is total by VFUNCT_1:34;
then A7: dom (r (#) R1) = REAL by FUNCT_2:def 1;
r (#) L1 is total by VFUNCT_1:34;
then A8: dom (r (#) L1) = REAL by FUNCT_2:def 1;

A9: now

let x be Real; :: thesis: ( x in N1 implies ((r (#) f) /. x) - ((r (#) f) /. x0) = (L . (x - x0)) + (R /. (x - x0)) )
A10: x0 in N1 by RCOMP_1:16;
assume A11: x in N1 ; :: thesis: ((r (#) f) /. x) - ((r (#) f) /. x0) = (L . (x - x0)) + (R /. (x - x0))
hence ((r (#) f) /. x) - ((r (#) f) /. x0) = (r * (f /. x)) - ((r (#) f) /. x0) by A6, VFUNCT_1:def 4
.= (r * (f /. x)) - (r * (f /. x0)) by A6, A10, VFUNCT_1:def 4
.= r * ((f /. x) - (f /. x0)) by RLVECT_1:34
.= r * ((L1 . (x - x0)) + (R1 /. (x - x0))) by A4, A11
.= (r * (L1 /. (x - x0))) + (r * (R1 /. (x - x0))) by RLVECT_1:def 5
.= (L /. (x - x0)) + (r * (R1 /. (x - x0))) by A8, VFUNCT_1:def 4
.= (L . (x - x0)) + (R /. (x - x0)) by A7, VFUNCT_1:def 4 ;
:: thesis: verum

end;

hence r (#) f is_differentiable_in x0 by A6, Def3; :: thesis: diff ((r (#) f),x0) = r * (diff (f,x0))
hence diff ((r (#) f),x0) = L . 1 by A6, A9, Def4
.= L /. 1 by A8, PARTFUN1:def 6
.= r * (L1 /. 1) by A8, VFUNCT_1:def 4
.= r * (L1 . 1) by A5, PARTFUN1:def 6
.= r * (diff (f,x0)) by A1, A2, A4, Def4 ;
:: thesis: verum