let z be Complex; :: thesis: for CNS being ComplexNormSpace
for RNS being RealNormSpace
for X being set
for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let CNS be ComplexNormSpace; :: thesis: for RNS being RealNormSpace
for X being set
for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let RNS be RealNormSpace; :: thesis: for X being set
for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let X be set ; :: thesis: for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let f be PartFunc of RNS,CNS; :: thesis: ( f is_Lipschitzian_on X implies z (#) f is_Lipschitzian_on X )
assume A1: f is_Lipschitzian_on X ; :: thesis: z (#) f is_Lipschitzian_on X
then consider s being Real such that
A2: 0 < s and
A3: for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.((f /. x1) - (f /. x2)).|| <= s * ||.(x1 - x2).|| by Def29;
X c= dom f by A1, Def29;
hence A4: X c= dom (z (#) f) by VFUNCT_2:def 2; :: according to NCFCONT1:def 19 :: thesis: ex r being Real st
( 0 < r & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= r * ||.(x1 - x2).|| ) )

now

per cases ( z = 0 or z <> 0 ) ;

suppose A5: z = 0 ; :: thesis: ex s being Real st
( 0 < s & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| ) )

take s = s; :: thesis: ( 0 < s & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| ) )
thus 0 < s by A2; :: thesis: for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).||
let x1, x2 be Point of RNS; :: thesis: ( x1 in X & x2 in X implies ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| )
assume that
A6: x1 in X and
A7: x2 in X ; :: thesis: ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).||
0 <= ||.(x1 - x2).|| by NORMSP_1:4;
then A8: s * 0 <= s * ||.(x1 - x2).|| by A2, XREAL_1:64;
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| = ||.((z * (f /. x1)) - ((z (#) f) /. x2)).|| by A4, A6, VFUNCT_2:def 2
.= ||.((0. CNS) - ((z (#) f) /. x2)).|| by A5, CLVECT_1:1
.= ||.((0. CNS) - (z * (f /. x2))).|| by A4, A7, VFUNCT_2:def 2
.= ||.((0. CNS) - (0. CNS)).|| by A5, CLVECT_1:1
.= ||.(0. CNS).|| by RLVECT_1:13
.= 0 by CLVECT_1:102 ;
hence ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| by A8; :: thesis: verum

end;

suppose A9: z <> 0 ; :: thesis: ex g being Element of REAL st
( 0 < g & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| ) )

take g = |.z.| * s; :: thesis: ( 0 < g & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| ) )
0 < |.z.| by A9, COMPLEX1:47;
then 0 * s < |.z.| * s by A2, XREAL_1:68;
hence 0 < g ; :: thesis: for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).||
let x1, x2 be Point of RNS; :: thesis: ( x1 in X & x2 in X implies ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| )
assume that
A10: x1 in X and
A11: x2 in X ; :: thesis: ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).||
0 <= |.z.| by COMPLEX1:46;
then A12: |.z.| * ||.((f /. x1) - (f /. x2)).|| <= |.z.| * (s * ||.(x1 - x2).||) by A3, A10, A11, XREAL_1:64;
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| = ||.((z * (f /. x1)) - ((z (#) f) /. x2)).|| by A4, A10, VFUNCT_2:def 2
.= ||.((z * (f /. x1)) - (z * (f /. x2))).|| by A4, A11, VFUNCT_2:def 2
.= ||.(z * ((f /. x1) - (f /. x2))).|| by CLVECT_1:9
.= |.z.| * ||.((f /. x1) - (f /. x2)).|| by CLVECT_1:def 13 ;
hence ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| by A12; :: thesis: verum

end;

end;

end;

hence ex r being Real st
( 0 < r & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= r * ||.(x1 - x2).|| ) ) ; :: thesis: verum