let X be non empty set ; :: thesis: for S being SigmaField of X
for M being sigma_Measure of S
for f being PartFunc of X,ExtREAL
for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )
let S be SigmaField of X; :: thesis: for M being sigma_Measure of S
for f being PartFunc of X,ExtREAL
for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )
let M be sigma_Measure of S; :: thesis: for f being PartFunc of X,ExtREAL
for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )
let f be PartFunc of X,ExtREAL; :: thesis: for c being Real st f is_integrable_on M holds
( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )
let c be Real; :: thesis: ( f is_integrable_on M implies ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) ) )
assume A1: f is_integrable_on M ; :: thesis: ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )
A2: integral+ (M,(max+ f)) <> +infty by A1, Def17;
consider A being Element of S such that
A3: A = dom f and
A4: f is_measurable_on A by A1, Def17;
A5: c (#) f is_measurable_on A by A3, A4, Th55;
A6: dom (max- f) = A by A3, MESFUNC2:def 3;
A7: integral+ (M,(max- f)) <> +infty by A1, Def17;
0 <= integral+ (M,(max- f)) by A1, Th102;
then reconsider I2 = integral+ (M,(max- f)) as Real by A7, XXREAL_0:14;
A8: max- f is nonnegative by Lm1;
0 <= integral+ (M,(max+ f)) by A1, Th102;
then reconsider I1 = integral+ (M,(max+ f)) as Real by A2, XXREAL_0:14;
A9: max+ f is nonnegative by Lm1;
A10: dom (c (#) f) = A by A3, MESFUNC1:def 6;
A11: dom (max+ f) = A by A3, MESFUNC2:def 2;

per cases ( 0 <= c or c < 0 ) ;

suppose A12: 0 <= c ; :: thesis: ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )

c * I1 is Real ;
then A13: (R_EAL c) * (integral+ (M,(max+ f))) is Real by EXTREAL1:1;
A14: max+ (c (#) f) = c (#) (max+ f) by A12, Th32;
integral+ (M,(c (#) (max+ f))) = (R_EAL c) * (integral+ (M,(max+ f))) by A4, A9, A11, A12, Th92, MESFUNC2:25;
then A15: integral+ (M,(max+ (c (#) f))) < +infty by A14, A13, XXREAL_0:9;
c * I2 is Real ;
then (R_EAL c) * (integral+ (M,(max- f))) is Real by EXTREAL1:1;
then A16: (R_EAL c) * (integral+ (M,(max- f))) < +infty by XXREAL_0:9;
A17: max- (c (#) f) = c (#) (max- f) by A12, Th32;
integral+ (M,(c (#) (max- f))) = (R_EAL c) * (integral+ (M,(max- f))) by A3, A4, A8, A6, A12, Th92, MESFUNC2:26;
hence c (#) f is_integrable_on M by A5, A10, A17, A15, A16, Def17; :: thesis: Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f))
thus Integral (M,(c (#) f)) = (integral+ (M,(c (#) (max+ f)))) - (integral+ (M,(max- (c (#) f)))) by A12, Th32
.= (integral+ (M,(c (#) (max+ f)))) - (integral+ (M,(c (#) (max- f)))) by A12, Th32
.= ((R_EAL c) * (integral+ (M,(max+ f)))) - (integral+ (M,(c (#) (max- f)))) by A4, A9, A11, A12, Th92, MESFUNC2:25
.= ((R_EAL c) * (integral+ (M,(max+ f)))) - ((R_EAL c) * (integral+ (M,(max- f)))) by A3, A4, A8, A6, A12, Th92, MESFUNC2:26
.= (R_EAL c) * (Integral (M,f)) by XXREAL_3:100 ; :: thesis: verum

end;

suppose A18: c < 0 ; :: thesis: ( c (#) f is_integrable_on M & Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f)) )

- (- c) = c ;
then consider a being Real such that
A19: c = - a and
A20: a > 0 by A18;
A21: max+ (c (#) f) = a (#) (max- f) by A19, A20, Th33;
A22: max- (c (#) f) = a (#) (max+ f) by A19, A20, Th33;
a * I2 is Real ;
then A23: (R_EAL a) * (integral+ (M,(max- f))) is Real by EXTREAL1:1;
integral+ (M,(a (#) (max- f))) = (R_EAL a) * (integral+ (M,(max- f))) by A3, A4, A8, A6, A20, Th92, MESFUNC2:26;
then A24: integral+ (M,(max+ (c (#) f))) < +infty by A21, A23, XXREAL_0:9;
a * I1 is Real ;
then (R_EAL a) * (integral+ (M,(max+ f))) is Real by EXTREAL1:1;
then A25: (R_EAL a) * (integral+ (M,(max+ f))) < +infty by XXREAL_0:9;
integral+ (M,(a (#) (max+ f))) = (R_EAL a) * (integral+ (M,(max+ f))) by A4, A9, A11, A20, Th92, MESFUNC2:25;
hence c (#) f is_integrable_on M by A5, A10, A22, A24, A25, Def17; :: thesis: Integral (M,(c (#) f)) = (R_EAL c) * (Integral (M,f))
A26: - (R_EAL a) = - a by SUPINF_2:2;
thus Integral (M,(c (#) f)) = ((R_EAL a) * (integral+ (M,(max- f)))) - (integral+ (M,(a (#) (max+ f)))) by A3, A4, A8, A6, A20, A21, A22, Th92, MESFUNC2:26
.= ((R_EAL a) * (integral+ (M,(max- f)))) - ((R_EAL a) * (integral+ (M,(max+ f)))) by A4, A9, A11, A20, Th92, MESFUNC2:25
.= (R_EAL a) * ((integral+ (M,(max- f))) - (integral+ (M,(max+ f)))) by XXREAL_3:100
.= (R_EAL a) * (- ((integral+ (M,(max+ f))) - (integral+ (M,(max- f))))) by XXREAL_3:26
.= - ((R_EAL a) * ((integral+ (M,(max+ f))) - (integral+ (M,(max- f))))) by XXREAL_3:92
.= (R_EAL c) * (Integral (M,f)) by A19, A26, XXREAL_3:92 ; :: thesis: verum

end;

end;