let X be set ; :: thesis: for S being SigmaField of X
for M being sigma_Measure of S
for F being Function of NAT,S st ( for n being Element of NAT holds F . n c= F . (n + 1) ) holds
M . (union (rng F)) = sup (rng (M * F))
let S be SigmaField of X; :: thesis: for M being sigma_Measure of S
for F being Function of NAT,S st ( for n being Element of NAT holds F . n c= F . (n + 1) ) holds
M . (union (rng F)) = sup (rng (M * F))
let M be sigma_Measure of S; :: thesis: for F being Function of NAT,S st ( for n being Element of NAT holds F . n c= F . (n + 1) ) holds
M . (union (rng F)) = sup (rng (M * F))
let F be Function of NAT,S; :: thesis: ( ( for n being Element of NAT holds F . n c= F . (n + 1) ) implies M . (union (rng F)) = sup (rng (M * F)) )
consider G being Function of NAT,S such that
A1: G . 0 = F . 0 and
A2: for n being Element of NAT holds G . (n + 1) = (F . (n + 1)) \ (F . n) by Th4;
assume A3: for n being Element of NAT holds F . n c= F . (n + 1) ; :: thesis: M . (union (rng F)) = sup (rng (M * F))
then A4: G is Sep_Sequence of S by A1, A2, Th25;
A5: for m being set st m in NAT holds
(Ser (M * G)) . m = (M * F) . m

proof

defpred S₁[ Element of NAT ] means (Ser (M * G)) . $1 = (M * F) . $1;
let m be set ; :: thesis: ( m in NAT implies (Ser (M * G)) . m = (M * F) . m )
assume A6: m in NAT ; :: thesis: (Ser (M * G)) . m = (M * F) . m
A7: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
A8: (M * G) . (m + 1) = M . (G . (m + 1)) by FUNCT_2:15;
A9: (M * F) . (m + 1) = M . (F . (m + 1)) by FUNCT_2:15;
A10: G . (m + 1) = (F . (m + 1)) \ (F . m) by A2;
assume (Ser (M * G)) . m = (M * F) . m ; :: thesis: S₁[m + 1]
then (Ser (M * G)) . (m + 1) = ((M * F) . m) + ((M * G) . (m + 1)) by SUPINF_2:44
.= (M . (F . m)) + (M . (G . (m + 1))) by A8, FUNCT_2:15
.= M . ((F . m) \/ (G . (m + 1))) by A10, MEASURE1:30, XBOOLE_1:79
.= (M * F) . (m + 1) by A3, A9, A10, XBOOLE_1:45 ;
hence S₁[m + 1] ; :: thesis: verum

end;

(Ser (M * G)) . 0 = (M * G) . 0 by SUPINF_2:44
.= M . (F . 0) by A1, FUNCT_2:15
.= (M * F) . 0 by FUNCT_2:15 ;
then A11: S₁[ 0 ] ;
for m being Element of NAT holds S₁[m] from NAT_1:sch 1(A11, A7);
hence (Ser (M * G)) . m = (M * F) . m by A6; :: thesis: verum

end;

A12: ( dom (Ser (M * G)) = NAT & dom (M * F) = NAT ) by FUNCT_2:def 1;
M . (union (rng F)) = M . (union (rng G)) by A3, A1, A2, Th24
.= SUM (M * G) by A4, MEASURE1:def 6
.= sup (rng (M * F)) by A12, A5, FUNCT_1:2 ;
hence M . (union (rng F)) = sup (rng (M * F)) ; :: thesis: verum