let x0 be Real; :: thesis: for f being PartFunc of REAL,REAL holds
( f is_divergent_to-infty_in x0 iff ( ( for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom f & g2 < r2 & x0 < g2 & g2 in dom f ) ) & ( for g1 being Real ex g2 being Real st
( 0 < g2 & ( for r1 being Real st 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f holds
f . r1 < g1 ) ) ) ) )
let f be PartFunc of REAL,REAL; :: thesis: ( f is_divergent_to-infty_in x0 iff ( ( for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom f & g2 < r2 & x0 < g2 & g2 in dom f ) ) & ( for g1 being Real ex g2 being Real st
( 0 < g2 & ( for r1 being Real st 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f holds
f . r1 < g1 ) ) ) ) )
thus ( f is_divergent_to-infty_in x0 implies ( ( for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom f & g2 < r2 & x0 < g2 & g2 in dom f ) ) & ( for g1 being Real ex g2 being Real st
( 0 < g2 & ( for r1 being Real st 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f holds
f . r1 < g1 ) ) ) ) ) :: thesis: ( ( for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom f & g2 < r2 & x0 < g2 & g2 in dom f ) ) & ( for g1 being Real ex g2 being Real st
( 0 < g2 & ( for r1 being Real st 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f holds
f . r1 < g1 ) ) ) implies f is_divergent_to-infty_in x0 )

proof

assume that
A1: f is_divergent_to-infty_in x0 and
A2: ( ex r1, r2 being Real st
( r1 < x0 & x0 < r2 & ( for g1, g2 being Real holds
( not r1 < g1 or not g1 < x0 or not g1 in dom f or not g2 < r2 or not x0 < g2 or not g2 in dom f ) ) ) or ex g1 being Real st
for g2 being Real st 0 < g2 holds
ex r1 being Real st
( 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f & g1 <= f . r1 ) ) ; :: thesis: contradiction
consider g1 being Real such that
A3: for g2 being Real st 0 < g2 holds
ex r1 being Real st
( 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f & g1 <= f . r1 ) by A1, A2, Def3;
defpred S₁[ Element of NAT , real number ] means ( 0 < abs (x0 - $2) & abs (x0 - $2) < 1 / ($1 + 1) & $2 in dom f & g1 <= f . $2 );
A4: for n being Element of NAT ex r1 being Real st S₁[n,r1] by A3, XREAL_1:139;
consider s being Real_Sequence such that
A5: for n being Element of NAT holds S₁[n,s . n] from FUNCT_2:sch 3(A4);
A6: rng s c= (dom f) \ {x0} by A5, Th2;
A7: lim s = x0 by A5, Th2;
s is convergent by A5, Th2;
then f /* s is divergent_to-infty by A1, A7, A6, Def3;
then consider n being Element of NAT such that
A8: for k being Element of NAT st n <= k holds
(f /* s) . k < g1 by LIMFUNC1:def 5;
A9: (f /* s) . n < g1 by A8;
rng s c= dom f by A5, Th2;
then f . (s . n) < g1 by A9, FUNCT_2:108;
hence contradiction by A5; :: thesis: verum

end;

assume that
A10: for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom f & g2 < r2 & x0 < g2 & g2 in dom f ) and
A11: for g1 being Real ex g2 being Real st
( 0 < g2 & ( for r1 being Real st 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f holds
f . r1 < g1 ) ) ; :: thesis: f is_divergent_to-infty_in x0

now

let s be Real_Sequence; :: thesis: ( s is convergent & lim s = x0 & rng s c= (dom f) \ {x0} implies f /* s is divergent_to-infty )
assume that
A12: s is convergent and
A13: lim s = x0 and
A14: rng s c= (dom f) \ {x0} ; :: thesis: f /* s is divergent_to-infty

now

let g1 be Real; :: thesis: ex n being Element of NAT st
for k being Element of NAT st n <= k holds
(f /* s) . k < g1
consider g2 being Real such that
A15: 0 < g2 and
A16: for r1 being Real st 0 < abs (x0 - r1) & abs (x0 - r1) < g2 & r1 in dom f holds
f . r1 < g1 by A11;
consider n being Element of NAT such that
A17: for k being Element of NAT st n <= k holds
( 0 < abs (x0 - (s . k)) & abs (x0 - (s . k)) < g2 & s . k in dom f ) by A12, A13, A14, A15, Th3;
take n = n; :: thesis: for k being Element of NAT st n <= k holds
(f /* s) . k < g1
let k be Element of NAT ; :: thesis: ( n <= k implies (f /* s) . k < g1 )
assume A18: n <= k ; :: thesis: (f /* s) . k < g1
then A19: abs (x0 - (s . k)) < g2 by A17;
A20: s . k in dom f by A17, A18;
0 < abs (x0 - (s . k)) by A17, A18;
then f . (s . k) < g1 by A16, A19, A20;
hence (f /* s) . k < g1 by A14, FUNCT_2:108, XBOOLE_1:1; :: thesis: verum

end;

hence f /* s is divergent_to-infty by LIMFUNC1:def 5; :: thesis: verum

end;

hence f is_divergent_to-infty_in x0 by A10, Def3; :: thesis: verum