let f be PartFunc of REAL,REAL; :: thesis: for g being Real st f is convergent_in-infty holds
( lim_in-infty f = g iff for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 )
let g be Real; :: thesis: ( f is convergent_in-infty implies ( lim_in-infty f = g iff for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 ) )
assume A1: f is convergent_in-infty ; :: thesis: ( lim_in-infty f = g iff for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 )
thus ( lim_in-infty f = g implies for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 ) :: thesis: ( ( for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 ) implies lim_in-infty f = g )

proof

deffunc H₁( Element of NAT ) -> Element of REAL = - $1;
assume A2: lim_in-infty f = g ; :: thesis: for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1
consider s1 being Real_Sequence such that
A3: for n being Element of NAT holds s1 . n = H₁(n) from SEQ_1:sch 1();
given g1 being Real such that A4: 0 < g1 and
A5: for r being Real ex r1 being Real st
( r1 < r & r1 in dom f & abs ((f . r1) - g) >= g1 ) ; :: thesis: contradiction
defpred S₁[ Element of NAT , real number ] means ( $2 < - $1 & $2 in dom f & abs ((f . $2) - g) >= g1 );
A6: for n being Element of NAT ex r being Real st S₁[n,r] by A5;
consider s being Real_Sequence such that
A7: for n being Element of NAT holds S₁[n,s . n] from FUNCT_2:sch 3(A6);

now

let x be set ; :: thesis: ( x in rng s implies x in dom f )
assume x in rng s ; :: thesis: x in dom f
then ex n being Element of NAT st s . n = x by FUNCT_2:113;
hence x in dom f by A7; :: thesis: verum

end;

then A8: rng s c= dom f by TARSKI:def 3;

now

let n be Element of NAT ; :: thesis: s . n <= s1 . n
s . n < - n by A7;
hence s . n <= s1 . n by A3; :: thesis: verum

end;

then s is divergent_to-infty by A3, Th48, Th70;
then ( f /* s is convergent & lim (f /* s) = g ) by A1, A2, A8, Def13;
then consider n being Element of NAT such that
A9: for m being Element of NAT st n <= m holds
abs (((f /* s) . m) - g) < g1 by A4, SEQ_2:def 7;
abs (((f /* s) . n) - g) < g1 by A9;
then abs ((f . (s . n)) - g) < g1 by A8, FUNCT_2:108;
hence contradiction by A7; :: thesis: verum

end;

assume A10: for g1 being Real st 0 < g1 holds
ex r being Real st
for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 ; :: thesis: lim_in-infty f = g

now

let s be Real_Sequence; :: thesis: ( s is divergent_to-infty & rng s c= dom f implies ( f /* s is convergent & lim (f /* s) = g ) )
assume that
A11: s is divergent_to-infty and
A12: rng s c= dom f ; :: thesis: ( f /* s is convergent & lim (f /* s) = g )

A13: now

let g1 be real number ; :: thesis: ( 0 < g1 implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f /* s) . m) - g) < g1 )
assume A14: 0 < g1 ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f /* s) . m) - g) < g1
g1 is Real by XREAL_0:def 1;
then consider r being Real such that
A15: for r1 being Real st r1 < r & r1 in dom f holds
abs ((f . r1) - g) < g1 by A10, A14;
consider n being Element of NAT such that
A16: for m being Element of NAT st n <= m holds
s . m < r by A11, Def5;
take n = n; :: thesis: for m being Element of NAT st n <= m holds
abs (((f /* s) . m) - g) < g1
let m be Element of NAT ; :: thesis: ( n <= m implies abs (((f /* s) . m) - g) < g1 )
A17: s . m in rng s by VALUED_0:28;
assume n <= m ; :: thesis: abs (((f /* s) . m) - g) < g1
then abs ((f . (s . m)) - g) < g1 by A12, A15, A16, A17;
hence abs (((f /* s) . m) - g) < g1 by A12, FUNCT_2:108; :: thesis: verum

end;

hence f /* s is convergent by SEQ_2:def 6; :: thesis: lim (f /* s) = g
hence lim (f /* s) = g by A13, SEQ_2:def 7; :: thesis: verum

end;

hence lim_in-infty f = g by A1, Def13; :: thesis: verum