let f1, f2 be PartFunc of REAL,REAL; :: thesis: ( f1 is divergent_in+infty_to+infty & ( for r being Real ex g being Real st
( r < g & g in dom (f1 (#) f2) ) ) & ex r, r1 being Real st
( 0 < r & ( for g being Real st g in (dom f2) /\ (right_open_halfline r1) holds
r <= f2 . g ) ) implies f1 (#) f2 is divergent_in+infty_to+infty )
assume that
A1: f1 is divergent_in+infty_to+infty and
A2: for r being Real ex g being Real st
( r < g & g in dom (f1 (#) f2) ) ; :: thesis: ( for r, r1 being Real holds
( not 0 < r or ex g being Real st
( g in (dom f2) /\ (right_open_halfline r1) & not r <= f2 . g ) ) or f1 (#) f2 is divergent_in+infty_to+infty )
given r2, r1 being Real such that A3: 0 < r2 and
A4: for g being Real st g in (dom f2) /\ (right_open_halfline r1) holds
r2 <= f2 . g ; :: thesis: f1 (#) f2 is divergent_in+infty_to+infty

now

let seq be Real_Sequence; :: thesis: ( seq is divergent_to+infty & rng seq c= dom (f1 (#) f2) implies (f1 (#) f2) /* seq is divergent_to+infty )
assume that
A5: seq is divergent_to+infty and
A6: rng seq c= dom (f1 (#) f2) ; :: thesis: (f1 (#) f2) /* seq is divergent_to+infty
consider k being Element of NAT such that
A7: for n being Element of NAT st k <= n holds
r1 < seq . n by A5, Def4;
A8: rng (seq ^\ k) c= rng seq by VALUED_0:21;
A9: rng seq c= dom f2 by A6, Lm3;
then A10: rng (seq ^\ k) c= dom f2 by A8, XBOOLE_1:1;

A11: now

thus 0 < r2 by A3; :: thesis: for n being Element of NAT holds r2 <= (f2 /* (seq ^\ k)) . n
let n be Element of NAT ; :: thesis: r2 <= (f2 /* (seq ^\ k)) . n
r1 < seq . (n + k) by A7, NAT_1:12;
then r1 < (seq ^\ k) . n by NAT_1:def 3;
then (seq ^\ k) . n in { g2 where g2 is Real : r1 < g2 } ;
then ( (seq ^\ k) . n in rng (seq ^\ k) & (seq ^\ k) . n in right_open_halfline r1 ) by VALUED_0:28, XXREAL_1:230;
then (seq ^\ k) . n in (dom f2) /\ (right_open_halfline r1) by A10, XBOOLE_0:def 4;
then r2 <= f2 . ((seq ^\ k) . n) by A4;
hence r2 <= (f2 /* (seq ^\ k)) . n by A9, A8, FUNCT_2:108, XBOOLE_1:1; :: thesis: verum

end;

dom (f1 (#) f2) = (dom f1) /\ (dom f2) by A6, Lm3;
then rng (seq ^\ k) c= (dom f1) /\ (dom f2) by A6, A8, XBOOLE_1:1;
then A12: (f1 /* (seq ^\ k)) (#) (f2 /* (seq ^\ k)) = (f1 (#) f2) /* (seq ^\ k) by RFUNCT_2:8
.= ((f1 (#) f2) /* seq) ^\ k by A6, VALUED_0:27 ;
rng seq c= dom f1 by A6, Lm3;
then A13: rng (seq ^\ k) c= dom f1 by A8, XBOOLE_1:1;
seq ^\ k is divergent_to+infty by A5, Th53;
then f1 /* (seq ^\ k) is divergent_to+infty by A1, A13, Def7;
then (f1 /* (seq ^\ k)) (#) (f2 /* (seq ^\ k)) is divergent_to+infty by A11, Th49;
hence (f1 (#) f2) /* seq is divergent_to+infty by A12, Th34; :: thesis: verum

end;

hence f1 (#) f2 is divergent_in+infty_to+infty by A2, Def7; :: thesis: verum