let C be non empty compact non horizontal non vertical Subset of (TOP-REAL 2); :: thesis: for i, n being Nat st i <= len (Gauge (C,n)) holds
cell ((Gauge (C,n)),i,0) misses C
let i, n be Nat; :: thesis: ( i <= len (Gauge (C,n)) implies cell ((Gauge (C,n)),i,0) misses C )
set G = Gauge (C,n);
A1: i in NAT by ORDINAL1:def 12;
assume A2: i <= len (Gauge (C,n)) ; :: thesis: cell ((Gauge (C,n)),i,0) misses C
A3: len (Gauge (C,n)) = width (Gauge (C,n)) by Def1;
assume (cell ((Gauge (C,n)),i,0)) /\ C <> {} ; :: according to XBOOLE_0:def 7 :: thesis: contradiction
then consider p being Point of (TOP-REAL 2) such that
A4: p in (cell ((Gauge (C,n)),i,0)) /\ C by SUBSET_1:4;
A5: p in cell ((Gauge (C,n)),i,0) by A4, XBOOLE_0:def 4;
A6: p in C by A4, XBOOLE_0:def 4;
4 <= len (Gauge (C,n)) by Th13;
then A7: 1 <= len (Gauge (C,n)) by XXREAL_0:2;
set W = W-bound C;
set S = S-bound C;
set E = E-bound C;
set N = N-bound C;
set NS = ((N-bound C) - (S-bound C)) / (2 |^ n);
[1,1] in Indices (Gauge (C,n)) by A3, A7, MATRIX_1:36;
then (Gauge (C,n)) * (1,1) = |[((W-bound C) + ((((E-bound C) - (W-bound C)) / (2 |^ n)) * (1 - 2))),((S-bound C) + ((((N-bound C) - (S-bound C)) / (2 |^ n)) * (1 - 2)))]| by Def1;
then A8: ((Gauge (C,n)) * (1,1)) `2 = (S-bound C) + ((((N-bound C) - (S-bound C)) / (2 |^ n)) * (- 1)) by EUCLID:52;
A9: 2 |^ n > 0 by NEWTON:83;
N-bound C > S-bound C by Th12;
then (N-bound C) - (S-bound C) > 0 by XREAL_1:50;
then ((N-bound C) - (S-bound C)) / (2 |^ n) > 0 by A9, XREAL_1:139;
then (((N-bound C) - (S-bound C)) / (2 |^ n)) * (- 1) < 0 * (- 1) by XREAL_1:69;
then A10: ((Gauge (C,n)) * (1,1)) `2 < (S-bound C) + 0 by A8, XREAL_1:6;
( i = 0 or i > 0 ) by NAT_1:3;
then A11: ( i = 0 or i >= 1 + 0 ) by NAT_1:9;

per cases ( i = 0 or i = len (Gauge (C,n)) or ( 1 <= i & i < len (Gauge (C,n)) ) ) by A2, A11, XXREAL_0:1;

suppose i = 0 ; :: thesis: contradiction

then cell ((Gauge (C,n)),i,0) = { |[r,s]| where r, s is Real : ( r <= ((Gauge (C,n)) * (1,1)) `1 & s <= ((Gauge (C,n)) * (1,1)) `2 ) } by GOBRD11:24;
then consider r, s being Real such that
A12: p = |[r,s]| and
r <= ((Gauge (C,n)) * (1,1)) `1 and
A13: s <= ((Gauge (C,n)) * (1,1)) `2 by A5;
p `2 = s by A12, EUCLID:52;
then S-bound C > p `2 by A10, A13, XXREAL_0:2;
hence contradiction by A6, PSCOMP_1:24; :: thesis: verum

end;

suppose i = len (Gauge (C,n)) ; :: thesis: contradiction

then cell ((Gauge (C,n)),i,0) = { |[r,s]| where r, s is Real : ( ((Gauge (C,n)) * ((len (Gauge (C,n))),1)) `1 <= r & s <= ((Gauge (C,n)) * (1,1)) `2 ) } by GOBRD11:27;
then consider r, s being Real such that
A14: p = |[r,s]| and
((Gauge (C,n)) * ((len (Gauge (C,n))),1)) `1 <= r and
A15: s <= ((Gauge (C,n)) * (1,1)) `2 by A5;
p `2 = s by A14, EUCLID:52;
then S-bound C > p `2 by A10, A15, XXREAL_0:2;
hence contradiction by A6, PSCOMP_1:24; :: thesis: verum

end;

suppose ( 1 <= i & i < len (Gauge (C,n)) ) ; :: thesis: contradiction

then cell ((Gauge (C,n)),i,0) = { |[r,s]| where r, s is Real : ( ((Gauge (C,n)) * (i,1)) `1 <= r & r <= ((Gauge (C,n)) * ((i + 1),1)) `1 & s <= ((Gauge (C,n)) * (1,1)) `2 ) } by A1, GOBRD11:30;
then consider r, s being Real such that
A16: p = |[r,s]| and
((Gauge (C,n)) * (i,1)) `1 <= r and
r <= ((Gauge (C,n)) * ((i + 1),1)) `1 and
A17: s <= ((Gauge (C,n)) * (1,1)) `2 by A5;
p `2 = s by A16, EUCLID:52;
then S-bound C > p `2 by A10, A17, XXREAL_0:2;
hence contradiction by A6, PSCOMP_1:24; :: thesis: verum

end;

end;