let S be Language; :: thesis: R4 S is Correct

now

set f = R4 S;
set R = P4 S;
set Q = S -sequents ;
set E = TheEqSymbOf S;
set N = TheNorSymbOf S;
set FF = AllFormulasOf S;
set TT = AllTermsOf S;
set SS = AllSymbolsOf S;
set F = S -firstChar ;
let X be set ; :: thesis: ( X is S -correct implies (R4 S) . X is S -correct )
assume B0: X is S -correct ; :: thesis: (R4 S) . X is S -correct

now

let U be non empty set ; :: thesis: for I being Element of U -InterpretersOf S
for x being b₁ -satisfied set
for psi being wff string of S st [x,psi] in (R4 S) . X holds
I -TruthEval psi = 1
set II = U -InterpretersOf S;
let I be Element of U -InterpretersOf S; :: thesis: for x being I -satisfied set
for psi being wff string of S st [x,psi] in (R4 S) . X holds
I -TruthEval psi = 1
let x be I -satisfied set ; :: thesis: for psi being wff string of S st [x,psi] in (R4 S) . X holds
I -TruthEval psi = 1
let psi be wff string of S; :: thesis: ( [x,psi] in (R4 S) . X implies I -TruthEval psi = 1 )
set s = [x,psi];
CC0: ( ([x,psi] `1) \+\ x = {} & ([x,psi] `2) \+\ psi = {} ) ;
assume DD1: [x,psi] in (R4 S) . X ; :: thesis: I -TruthEval psi = 1
then D1: ( [x,psi] in S -sequents & [X,[x,psi]] in P4 S ) by Lm1e;
then X in dom (P4 S) by RELAT_1:def 4;
then reconsider Seqts = X as S -correct Subset of (S -sequents) by B0;
reconsider seqt = [x,psi] as Element of S -sequents by DD1, Lm1e;
seqt Rule4 Seqts by D1, DefP4;
then consider l being literal Element of S, phi being wff string of S, t being termal string of S such that
D2: ( seqt `1 = {((l,t) SubstIn phi)} & seqt `2 = <*l*> ^ phi ) by Def4;
reconsider tt = t as Element of AllTermsOf S by FOMODEL1:def 32;
reconsider phii = (l,tt) SubstIn phi as wff string of S ;
reconsider u = (I -TermEval) . tt as Element of U ;
reconsider I1 = (l,u) ReassignIn I as Element of U -InterpretersOf S ;
D3: ( x = {phii} & psi = <*l*> ^ phi ) by D2, CC0, FOMODEL0:29;
then 1 = I -TruthEval phii by FOMODEL2:27
.= I1 -TruthEval phi by FOMODEL3:10 ;
hence I -TruthEval psi = 1 by D3, FOMODEL2:19; :: thesis: verum

end;

hence (R4 S) . X is S -correct by FOMODEL2:def 44; :: thesis: verum

end;

hence R4 S is Correct by RuleCorr; :: thesis: verum