let S be Language; :: thesis: R3a S is Correct

now

set f = R3a S;
set R = P3a S;
set Q = S -sequents ;
set E = TheEqSymbOf S;
set N = TheNorSymbOf S;
set FF = AllFormulasOf S;
set TT = AllTermsOf S;
set SS = AllSymbolsOf S;
set F = S -firstChar ;
set C = S -multiCat ;
let X be set ; :: thesis: ( X is S -correct implies (R3a S) . X is S -correct )
assume B0: X is S -correct ; :: thesis: (R3a S) . X is S -correct

now

let U be non empty set ; :: thesis: for I being Element of U -InterpretersOf S
for x being b₁ -satisfied set
for psi being wff string of S st [x,psi] in (R3a S) . X holds
I -TruthEval psi = 1
set II = U -InterpretersOf S;
let I be Element of U -InterpretersOf S; :: thesis: for x being I -satisfied set
for psi being wff string of S st [x,psi] in (R3a S) . X holds
I -TruthEval psi = 1
let x be I -satisfied set ; :: thesis: for psi being wff string of S st [x,psi] in (R3a S) . X holds
I -TruthEval psi = 1
let psi be wff string of S; :: thesis: ( [x,psi] in (R3a S) . X implies I -TruthEval psi = 1 )
set s = [x,psi];
set TE = I -TermEval ;
set d = U -deltaInterpreter ;
CC0: ( ([x,psi] `1) \+\ x = {} & ([x,psi] `2) \+\ psi = {} ) ;
assume DD1: [x,psi] in (R3a S) . X ; :: thesis: I -TruthEval psi = 1
then D1: ( [x,psi] in S -sequents & [X,[x,psi]] in P3a S ) by Lm1e;
then X in dom (P3a S) by RELAT_1:def 4;
then reconsider Seqts = X as S -correct Subset of (S -sequents) by B0;
reconsider seqt = [x,psi] as Element of S -sequents by DD1, Lm1e;
seqt Rule3a Seqts by D1, DefP3a;
then consider t, t1, t2 being termal string of S, y being set such that
D2: ( y in Seqts & seqt `1 = (y `1) \/ {((<*(TheEqSymbOf S)*> ^ t1) ^ t2)} & y `2 = (<*(TheEqSymbOf S)*> ^ t) ^ t1 & seqt `2 = (<*(TheEqSymbOf S)*> ^ t) ^ t2 ) by Def3a;
reconsider phi1 = (<*(TheEqSymbOf S)*> ^ t) ^ t1, phi2 = (<*(TheEqSymbOf S)*> ^ t) ^ t2, phi = (<*(TheEqSymbOf S)*> ^ t1) ^ t2 as 0wff string of S ;
reconsider gamma = (y `1) null {phi}, z = {phi} null (y `1) as Subset of x by D2, CC0, FOMODEL0:29;
[gamma,phi1] in Seqts by D2, MCART_1:21;
then I -TruthEval phi1 = 1 by FOMODEL2:def 44;
then D3: ( phi2 = psi & (I -TermEval) . t = (I -TermEval) . t1 ) by Lm36, CC0, D2, FOMODEL0:29;
z = {phi} ;
then I -TruthEval phi = 1 by FOMODEL2:27;
then (I -TermEval) . t2 = (I -TermEval) . t by D3, Lm36;
then I -AtomicEval phi2 = 1 by Lm36;
hence I -TruthEval psi = 1 by CC0, D2, FOMODEL0:29; :: thesis: verum

end;

hence (R3a S) . X is S -correct by FOMODEL2:def 44; :: thesis: verum

end;

hence R3a S is Correct by RuleCorr; :: thesis: verum