let Z be open Subset of REAL; :: thesis: ( Z c= dom (ln * cos) & ( for x being Real st x in Z holds
cos . x > 0 ) implies ( ln * cos is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cos) `| Z) . x = - (tan x) ) ) )
assume that
A1: Z c= dom (ln * cos) and
A2: for x being Real st x in Z holds
cos . x > 0 ; :: thesis: ( ln * cos is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cos) `| Z) . x = - (tan x) ) )
A3: cos is_differentiable_on Z by FDIFF_1:26, SIN_COS:67;
A4: for x being Real st x in Z holds
ln * cos is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * cos is_differentiable_in x )
assume x in Z ; :: thesis: ln * cos is_differentiable_in x
then ( cos is_differentiable_in x & cos . x > 0 ) by A2, A3, FDIFF_1:9;
hence ln * cos is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A5: ln * cos is_differentiable_on Z by A1, FDIFF_1:9;
for x being Real st x in Z holds
((ln * cos) `| Z) . x = - (tan x)

proof

let x be Real; :: thesis: ( x in Z implies ((ln * cos) `| Z) . x = - (tan x) )
assume A6: x in Z ; :: thesis: ((ln * cos) `| Z) . x = - (tan x)
then ( cos is_differentiable_in x & cos . x > 0 ) by A2, A3, FDIFF_1:9;
then diff ((ln * cos),x) = (diff (cos,x)) / (cos . x) by TAYLOR_1:20
.= (- (sin . x)) / (cos . x) by SIN_COS:63
.= - ((sin . x) / (cos . x)) by XCMPLX_1:187
.= - ((sin x) / (cos . x)) by SIN_COS:def 17
.= - ((sin x) / (cos x)) by SIN_COS:def 19
.= - (tan x) by SIN_COS4:def 1 ;
hence ((ln * cos) `| Z) . x = - (tan x) by A5, A6, FDIFF_1:def 7; :: thesis: verum

end;

hence ( ln * cos is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * cos) `| Z) . x = - (tan x) ) ) by A1, A4, FDIFF_1:9; :: thesis: verum