let r, p be Real; :: thesis: for Z being open Subset of REAL
for f being PartFunc of REAL,REAL st Z c= dom f & ( for x being Real st x in Z holds
f . x = (r * x) + p ) holds
( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = r ) )
let Z be open Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL st Z c= dom f & ( for x being Real st x in Z holds
f . x = (r * x) + p ) holds
( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = r ) )
let f be PartFunc of REAL,REAL; :: thesis: ( Z c= dom f & ( for x being Real st x in Z holds
f . x = (r * x) + p ) implies ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = r ) ) )
set R = cf;
defpred S₁[ set ] means $1 in REAL ;
A1: dom cf = REAL by FUNCOP_1:13;

now

let h be convergent_to_0 Real_Sequence; :: thesis: ( (h ") (#) (cf /* h) is convergent & lim ((h ") (#) (cf /* h)) = 0 )

A2: now

let n be Nat; :: thesis: ((h ") (#) (cf /* h)) . n = 0
A3: rng h c= dom cf by A1;
A4: n in NAT by ORDINAL1:def 12;
hence ((h ") (#) (cf /* h)) . n = ((h ") . n) * ((cf /* h) . n) by SEQ_1:8
.= ((h ") . n) * (cf . (h . n)) by A4, A3, FUNCT_2:108
.= ((h ") . n) * 0 by FUNCOP_1:7
.= 0 ;
:: thesis: verum

end;

then A5: (h ") (#) (cf /* h) is constant by VALUED_0:def 18;
hence (h ") (#) (cf /* h) is convergent ; :: thesis: lim ((h ") (#) (cf /* h)) = 0
((h ") (#) (cf /* h)) . 0 = 0 by A2;
hence lim ((h ") (#) (cf /* h)) = 0 by A5, SEQ_4:25; :: thesis: verum

end;

then reconsider R = cf as REST by Def3;
assume that
A6: Z c= dom f and
A7: for x being Real st x in Z holds
f . x = (r * x) + p ; :: thesis: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = r ) )
deffunc H₁( Real) -> Element of REAL = r * $1;
consider L being PartFunc of REAL,REAL such that
A8: ( ( for x being Real holds
( x in dom L iff S₁[x] ) ) & ( for x being Real st x in dom L holds
L . x = H₁(x) ) ) from SEQ_1:sch 3();
dom L = REAL by A8, Th1;
then A9: L is total by PARTFUN1:def 2;

A10: now

let x be Real; :: thesis: L . x = r * x
x in dom L by A8;
hence L . x = r * x by A8; :: thesis: verum

end;

then reconsider L = L as LINEAR by A9, Def4;

A11: now

let x0 be Real; :: thesis: ( x0 in Z implies f is_differentiable_in x0 )
assume A12: x0 in Z ; :: thesis: f is_differentiable_in x0
then consider N being Neighbourhood of x0 such that
A13: N c= Z by RCOMP_1:18;
A14: for x being Real st x in N holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))

proof

let x be Real; :: thesis: ( x in N implies (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) )
assume x in N ; :: thesis: (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))
hence (f . x) - (f . x0) = ((r * x) + p) - (f . x0) by A7, A13
.= ((r * x) + p) - ((r * x0) + p) by A7, A12
.= (r * (x - x0)) + 0
.= (L . (x - x0)) + 0 by A10
.= (L . (x - x0)) + (R . (x - x0)) by FUNCOP_1:7 ;
:: thesis: verum

end;

N c= dom f by A6, A13, XBOOLE_1:1;
hence f is_differentiable_in x0 by A14, Def5; :: thesis: verum

end;

hence A15: f is_differentiable_on Z by A6, Th16; :: thesis: for x being Real st x in Z holds
(f `| Z) . x = r
let x0 be Real; :: thesis: ( x0 in Z implies (f `| Z) . x0 = r )
assume A16: x0 in Z ; :: thesis: (f `| Z) . x0 = r
then consider N being Neighbourhood of x0 such that
A17: N c= Z by RCOMP_1:18;
A18: for x being Real st x in N holds
(f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))

proof

let x be Real; :: thesis: ( x in N implies (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0)) )
assume x in N ; :: thesis: (f . x) - (f . x0) = (L . (x - x0)) + (R . (x - x0))
hence (f . x) - (f . x0) = ((r * x) + p) - (f . x0) by A7, A17
.= ((r * x) + p) - ((r * x0) + p) by A7, A16
.= (r * (x - x0)) + 0
.= (L . (x - x0)) + 0 by A10
.= (L . (x - x0)) + (R . (x - x0)) by FUNCOP_1:7 ;
:: thesis: verum

end;

A19: N c= dom f by A6, A17, XBOOLE_1:1;
A20: f is_differentiable_in x0 by A11, A16;
thus (f `| Z) . x0 = diff (f,x0) by A15, A16, Def8
.= L . 1 by A20, A19, A18, Def6
.= r * 1 by A10
.= r ; :: thesis: verum