let X be Complex_Banach_Algebra; :: thesis: ( (0. X) ExpSeq is norm_summable & Sum ((0. X) ExpSeq) = 1. X )
defpred S1[ set ] means (Partial_Sums ||.((0. X) ExpSeq).||) . $1 = 1;
A1: for n being Nat st S1[n] holds
S1[n + 1]
proof
let n be Nat; :: thesis: ( S1[n] implies S1[n + 1] )
assume A2: (Partial_Sums ||.((0. X) ExpSeq).||) . n = 1 ; :: thesis: S1[n + 1]
A3: n in NAT by ORDINAL1:def 12;
hence (Partial_Sums ||.((0. X) ExpSeq).||) . (n + 1) = 1 + (||.((0. X) ExpSeq).|| . (n + 1)) by A2, SERIES_1:def 1
.= 1 + ||.(((0. X) ExpSeq) . (n + 1)).|| by NORMSP_0:def 4
.= 1 + ||.(((1r / (n + 1)) * (0. X)) * (((0. X) ExpSeq) . n)).|| by A3, Th13
.= 1 + ||.((0. X) * (((0. X) ExpSeq) . n)).|| by CLOPBAN3:38
.= 1 + ||.(0. X).|| by CLOPBAN3:38
.= 1 + 0 by CLOPBAN3:38
.= 1 ;
:: thesis: verum
end;
(Partial_Sums ||.((0. X) ExpSeq).||) . 0 = ||.((0. X) ExpSeq).|| . 0 by SERIES_1:def 1
.= ||.(((0. X) ExpSeq) . 0).|| by NORMSP_0:def 4
.= ||.(1. X).|| by Th13
.= 1 by CLOPBAN3:38 ;
then A4: S1[ 0 ] ;
for n being Nat holds S1[n] from NAT_1:sch 2(A4, A1);
 then Partial_Sums ||.((0. X) ExpSeq).|| is constant by VALUED_0:def 18;
then A5: ||.((0. X) ExpSeq).|| is summable by SERIES_1:def 2;
defpred S2[ set ] means (Partial_Sums ((0. X) ExpSeq)) . $1 = 1. X;
A6: for n being Element of NAT st S2[n] holds
S2[n + 1]
proof
let n be Element of NAT ; :: thesis: ( S2[n] implies S2[n + 1] )
assume (Partial_Sums ((0. X) ExpSeq)) . n = 1. X ; :: thesis: S2[n + 1]
hence (Partial_Sums ((0. X) ExpSeq)) . (n + 1) = (1. X) + (((0. X) ExpSeq) . (n + 1)) by BHSP_4:def 1
.= (1. X) + (((1r / (n + 1)) * (0. X)) * (((0. X) ExpSeq) . n)) by Th13
.= (1. X) + ((0. X) * (((0. X) ExpSeq) . n)) by CLOPBAN3:38
.= (1. X) + (0. X) by CLOPBAN3:38
.= 1. X by CLOPBAN3:38 ;
:: thesis: verum
end;
(Partial_Sums ((0. X) ExpSeq)) . 0 = ((0. X) ExpSeq) . 0 by BHSP_4:def 1
.= 1. X by Th13 ;
then A7: S2[ 0 ] ;
for n being Element of NAT holds S2[n] from NAT_1:sch 1(A7, A6);
 then lim (Partial_Sums ((0. X) ExpSeq)) = 1. X by Th2;
hence ( (0. X) ExpSeq is norm_summable & Sum ((0. X) ExpSeq) = 1. X ) by A5, CLOPBAN3:def 2, CLOPBAN3:def 3; :: thesis: verum