set R = cf;
reconsider L = id COMPLEX as PartFunc of COMPLEX,COMPLEX ;
A1: COMPLEX c= COMPLEX ;
then for b being Complex holds L /. b = 1r * b by PARTFUN2:6;
then reconsider L = L as C_LINEAR by Def4;
A2: dom cf = COMPLEX by FUNCOP_1:13;

now

let h be convergent_to_0 Complex_Sequence; :: thesis: ( (h ") (#) (cf /* h) is convergent & lim ((h ") (#) (cf /* h)) = 0c )

now

let n be Nat; :: thesis: ((h ") (#) (cf /* h)) . n = 0c
A3: ( n in NAT & rng h c= dom cf ) by A2, ORDINAL1:def 12;
thus ((h ") (#) (cf /* h)) . n = ((h ") . n) * ((cf /* h) . n) by VALUED_1:5
.= ((h ") . n) * (cf /. (h . n)) by A3, FUNCT_2:109
.= ((h ") . n) * 0c by FUNCOP_1:7
.= 0c ; :: thesis: verum

end;

then ( (h ") (#) (cf /* h) is constant & ((h ") (#) (cf /* h)) . 0 = 0c ) by VALUED_0:def 18;
hence ( (h ") (#) (cf /* h) is convergent & lim ((h ") (#) (cf /* h)) = 0c ) by CFCONT_1:26, CFCONT_1:27; :: thesis: verum

end;

then reconsider R = cf as C_REST by Def3;
let f be PartFunc of COMPLEX,COMPLEX; :: thesis: for Z being open Subset of COMPLEX st Z c= dom f & f | Z = id Z holds
( f is_differentiable_on Z & ( for x being Complex st x in Z holds
(f `| Z) /. x = 1r ) )
let Z be open Subset of COMPLEX; :: thesis: ( Z c= dom f & f | Z = id Z implies ( f is_differentiable_on Z & ( for x being Complex st x in Z holds
(f `| Z) /. x = 1r ) ) )
assume that
A4: Z c= dom f and
A5: f | Z = id Z ; :: thesis: ( f is_differentiable_on Z & ( for x being Complex st x in Z holds
(f `| Z) /. x = 1r ) )

A6: now

let x be Complex; :: thesis: ( x in Z implies f /. x = x )
assume A7: x in Z ; :: thesis: f /. x = x
then (f | Z) . x = x by A5, FUNCT_1:18;
then f . x = x by A7, FUNCT_1:49;
hence f /. x = x by A4, A7, PARTFUN1:def 6; :: thesis: verum

end;

A8: now

let x0 be Complex; :: thesis: ( x0 in Z implies f is_differentiable_in x0 )
assume A9: x0 in Z ; :: thesis: f is_differentiable_in x0
then consider N being Neighbourhood of x0 such that
A10: N c= Z by Th9;
A11: for x being Complex st x in N holds
(f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0))

proof

let x be Complex; :: thesis: ( x in N implies (f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0)) )
assume x in N ; :: thesis: (f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0))
hence (f /. x) - (f /. x0) = x - (f /. x0) by A6, A10
.= x - x0 by A6, A9
.= (L /. (x - x0)) + 0c by A1, PARTFUN2:6
.= (L /. (x - x0)) + (R /. (x - x0)) by FUNCOP_1:7 ;
:: thesis: verum

end;

N c= dom f by A4, A10, XBOOLE_1:1;
hence f is_differentiable_in x0 by A11, Def6; :: thesis: verum

end;

hence A12: f is_differentiable_on Z by A4, Th15; :: thesis: for x being Complex st x in Z holds
(f `| Z) /. x = 1r
let x0 be Complex; :: thesis: ( x0 in Z implies (f `| Z) /. x0 = 1r )
assume A13: x0 in Z ; :: thesis: (f `| Z) /. x0 = 1r
then consider N1 being Neighbourhood of x0 such that
A14: N1 c= Z by Th9;
A15: f is_differentiable_in x0 by A8, A13;
then ex N being Neighbourhood of x0 st
( N c= dom f & ex L being C_LINEAR ex R being C_REST st
for x being Complex st x in N holds
(f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0)) ) by Def6;
then consider N being Neighbourhood of x0 such that
A16: N c= dom f ;
consider N2 being Neighbourhood of x0 such that
A17: N2 c= N1 and
A18: N2 c= N by Lm1;
A19: N2 c= dom f by A16, A18, XBOOLE_1:1;
A20: for x being Complex st x in N2 holds
(f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0))

proof

let x be Complex; :: thesis: ( x in N2 implies (f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0)) )
assume x in N2 ; :: thesis: (f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0))
then x in N1 by A17;
hence (f /. x) - (f /. x0) = x - (f /. x0) by A6, A14
.= x - x0 by A6, A13
.= (L /. (x - x0)) + 0c by A1, PARTFUN2:6
.= (L /. (x - x0)) + (R /. (x - x0)) by FUNCOP_1:7 ;
:: thesis: verum

end;

thus (f `| Z) /. x0 = diff (f,x0) by A12, A13, Def12
.= L /. 1r by A15, A19, A20, Def7
.= 1r by A1, PARTFUN2:6 ; :: thesis: verum