let X be set ; :: thesis: for f1, f2 being PartFunc of COMPLEX,COMPLEX st f1 is_continuous_on X & f2 is_continuous_on X holds
( f1 + f2 is_continuous_on X & f1 - f2 is_continuous_on X & f1 (#) f2 is_continuous_on X )
let f1, f2 be PartFunc of COMPLEX,COMPLEX; :: thesis: ( f1 is_continuous_on X & f2 is_continuous_on X implies ( f1 + f2 is_continuous_on X & f1 - f2 is_continuous_on X & f1 (#) f2 is_continuous_on X ) )
assume A1: ( f1 is_continuous_on X & f2 is_continuous_on X ) ; :: thesis: ( f1 + f2 is_continuous_on X & f1 - f2 is_continuous_on X & f1 (#) f2 is_continuous_on X )
then ( X c= dom f1 & X c= dom f2 ) by Th60;
then A2: X c= (dom f1) /\ (dom f2) by XBOOLE_1:19;
then A3: X c= dom (f1 + f2) by CFUNCT_1:1;

now

let s1 be Complex_Sequence; :: thesis: ( rng s1 c= X & s1 is convergent & lim s1 in X implies ( (f1 + f2) /* s1 is convergent & (f1 + f2) /. (lim s1) = lim ((f1 + f2) /* s1) ) )
assume that
A4: rng s1 c= X and
A5: s1 is convergent and
A6: lim s1 in X ; :: thesis: ( (f1 + f2) /* s1 is convergent & (f1 + f2) /. (lim s1) = lim ((f1 + f2) /* s1) )
A7: ( f1 /* s1 is convergent & f2 /* s1 is convergent ) by A1, A4, A5, A6, Th60;
then A8: (f1 /* s1) + (f2 /* s1) is convergent by COMSEQ_2:13;
A9: rng s1 c= (dom f1) /\ (dom f2) by A2, A4, XBOOLE_1:1;
( f1 /. (lim s1) = lim (f1 /* s1) & f2 /. (lim s1) = lim (f2 /* s1) ) by A1, A4, A5, A6, Th60;
then (f1 + f2) /. (lim s1) = (lim (f1 /* s1)) + (lim (f2 /* s1)) by A3, A6, CFUNCT_1:1
.= lim ((f1 /* s1) + (f2 /* s1)) by A7, COMSEQ_2:14
.= lim ((f1 + f2) /* s1) by A9, Th18 ;
hence ( (f1 + f2) /* s1 is convergent & (f1 + f2) /. (lim s1) = lim ((f1 + f2) /* s1) ) by A9, A8, Th18; :: thesis: verum

end;

hence f1 + f2 is_continuous_on X by A3, Th60; :: thesis: ( f1 - f2 is_continuous_on X & f1 (#) f2 is_continuous_on X )
A10: X c= dom (f1 - f2) by A2, CFUNCT_1:2;

now

let s1 be Complex_Sequence; :: thesis: ( rng s1 c= X & s1 is convergent & lim s1 in X implies ( (f1 - f2) /* s1 is convergent & (f1 - f2) /. (lim s1) = lim ((f1 - f2) /* s1) ) )
assume that
A11: rng s1 c= X and
A12: s1 is convergent and
A13: lim s1 in X ; :: thesis: ( (f1 - f2) /* s1 is convergent & (f1 - f2) /. (lim s1) = lim ((f1 - f2) /* s1) )
A14: ( f1 /* s1 is convergent & f2 /* s1 is convergent ) by A1, A11, A12, A13, Th60;
then A15: (f1 /* s1) - (f2 /* s1) is convergent by COMSEQ_2:25;
A16: rng s1 c= (dom f1) /\ (dom f2) by A2, A11, XBOOLE_1:1;
( f1 /. (lim s1) = lim (f1 /* s1) & f2 /. (lim s1) = lim (f2 /* s1) ) by A1, A11, A12, A13, Th60;
then (f1 - f2) /. (lim s1) = (lim (f1 /* s1)) - (lim (f2 /* s1)) by A10, A13, CFUNCT_1:2
.= lim ((f1 /* s1) - (f2 /* s1)) by A14, COMSEQ_2:26
.= lim ((f1 - f2) /* s1) by A16, Th18 ;
hence ( (f1 - f2) /* s1 is convergent & (f1 - f2) /. (lim s1) = lim ((f1 - f2) /* s1) ) by A16, A15, Th18; :: thesis: verum

end;

hence f1 - f2 is_continuous_on X by A10, Th60; :: thesis: f1 (#) f2 is_continuous_on X
A17: X c= dom (f1 (#) f2) by A2, CFUNCT_1:3;

now

let s1 be Complex_Sequence; :: thesis: ( rng s1 c= X & s1 is convergent & lim s1 in X implies ( (f1 (#) f2) /* s1 is convergent & (f1 (#) f2) /. (lim s1) = lim ((f1 (#) f2) /* s1) ) )
assume that
A18: rng s1 c= X and
A19: s1 is convergent and
A20: lim s1 in X ; :: thesis: ( (f1 (#) f2) /* s1 is convergent & (f1 (#) f2) /. (lim s1) = lim ((f1 (#) f2) /* s1) )
A21: ( f1 /* s1 is convergent & f2 /* s1 is convergent ) by A1, A18, A19, A20, Th60;
then A22: (f1 /* s1) (#) (f2 /* s1) is convergent by COMSEQ_2:29;
A23: rng s1 c= (dom f1) /\ (dom f2) by A2, A18, XBOOLE_1:1;
( f1 /. (lim s1) = lim (f1 /* s1) & f2 /. (lim s1) = lim (f2 /* s1) ) by A1, A18, A19, A20, Th60;
then (f1 (#) f2) /. (lim s1) = (lim (f1 /* s1)) * (lim (f2 /* s1)) by A17, A20, CFUNCT_1:3
.= lim ((f1 /* s1) (#) (f2 /* s1)) by A21, COMSEQ_2:30
.= lim ((f1 (#) f2) /* s1) by A23, Th18 ;
hence ( (f1 (#) f2) /* s1 is convergent & (f1 (#) f2) /. (lim s1) = lim ((f1 (#) f2) /* s1) ) by A23, A22, Th18; :: thesis: verum

end;

hence f1 (#) f2 is_continuous_on X by A17, Th60; :: thesis: verum