let x0 be Element of COMPLEX ; :: thesis: for f being PartFunc of COMPLEX,COMPLEX holds
( f is_continuous_in x0 iff ( x0 in dom f & ( for s1 being Complex_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) holds
( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) ) ) )
let f be PartFunc of COMPLEX,COMPLEX; :: thesis: ( f is_continuous_in x0 iff ( x0 in dom f & ( for s1 being Complex_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) holds
( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) ) ) )
thus ( f is_continuous_in x0 implies ( x0 in dom f & ( for s1 being Complex_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) holds
( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) ) ) ) by Def2; :: thesis: ( x0 in dom f & ( for s1 being Complex_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) holds
( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) ) implies f is_continuous_in x0 )
assume that
A1: x0 in dom f and
A2: for s1 being Complex_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) holds
( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) ; :: thesis: f is_continuous_in x0
thus x0 in dom f by A1; :: according to CFCONT_1:def 1 :: thesis: for s1 being Complex_Sequence st rng s1 c= dom f & s1 is convergent & lim s1 = x0 holds
( f /* s1 is convergent & f /. x0 = lim (f /* s1) )
let s2 be Complex_Sequence; :: thesis: ( rng s2 c= dom f & s2 is convergent & lim s2 = x0 implies ( f /* s2 is convergent & f /. x0 = lim (f /* s2) ) )
assume that
A3: rng s2 c= dom f and
A4: ( s2 is convergent & lim s2 = x0 ) ; :: thesis: ( f /* s2 is convergent & f /. x0 = lim (f /* s2) )

now

per cases ( ex n being Element of NAT st
for m being Element of NAT st n <= m holds
s2 . m = x0 or for n being Element of NAT ex m being Element of NAT st
( n <= m & s2 . m <> x0 ) ) ;

suppose ex n being Element of NAT st
for m being Element of NAT st n <= m holds
s2 . m = x0 ; :: thesis: ( f /* s2 is convergent & f /. x0 = lim (f /* s2) )

then consider N being Element of NAT such that
A5: for m being Element of NAT st N <= m holds
s2 . m = x0 ;
A6: for n being Element of NAT holds (s2 ^\ N) . n = x0

proof

let n be Element of NAT ; :: thesis: (s2 ^\ N) . n = x0
s2 . (n + N) = x0 by A5, NAT_1:12;
hence (s2 ^\ N) . n = x0 by NAT_1:def 3; :: thesis: verum

end;

A7: f /* (s2 ^\ N) = (f /* s2) ^\ N by A3, VALUED_0:27;
A8: rng (s2 ^\ N) c= rng s2 by VALUED_0:21;

A9: now

let p be Real; :: thesis: ( p > 0 implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| < p )
assume A10: p > 0 ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| < p
take n = 0 ; :: thesis: for m being Element of NAT st n <= m holds
|.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| < p
let m be Element of NAT ; :: thesis: ( n <= m implies |.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| < p )
assume n <= m ; :: thesis: |.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| < p
|.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| = |.((f /. ((s2 ^\ N) . m)) - (f /. x0)).| by A3, A8, FUNCT_2:109, XBOOLE_1:1
.= |.((f /. x0) - (f /. x0)).| by A6
.= 0 by COMPLEX1:44 ;
hence |.(((f /* (s2 ^\ N)) . m) - (f /. x0)).| < p by A10; :: thesis: verum

end;

then A11: f /* (s2 ^\ N) is convergent by COMSEQ_2:def 4;
then f /. x0 = lim ((f /* s2) ^\ N) by A9, A7, COMSEQ_2:def 5;
hence ( f /* s2 is convergent & f /. x0 = lim (f /* s2) ) by A11, A7, Th40, Th44; :: thesis: verum

end;

suppose A12: for n being Element of NAT ex m being Element of NAT st
( n <= m & s2 . m <> x0 ) ; :: thesis: ( f /* s2 is convergent & f /. x0 = lim (f /* s2) )

defpred S₁[ set , set ] means for n, m being Element of NAT st $1 = n & $2 = m holds
( n < m & s2 . m <> x0 & ( for k being Element of NAT st n < k & s2 . k <> x0 holds
m <= k ) );
defpred S₂[ set , set , set ] means S₁[$2,$3];
defpred S₃[ set ] means s2 . $1 <> x0;
ex m1 being Element of NAT st
( 0 <= m1 & s2 . m1 <> x0 ) by A12;
then A13: ex m being Nat st S₃[m] ;
consider M being Nat such that
A14: ( S₃[M] & ( for n being Nat st S₃[n] holds
M <= n ) ) from NAT_1:sch 5(A13);
reconsider M9 = M as Element of NAT by ORDINAL1:def 12;

A15: now

let n be Element of NAT ; :: thesis: ex m being Element of NAT st
( n < m & s2 . m <> x0 )
consider m being Element of NAT such that
A16: ( n + 1 <= m & s2 . m <> x0 ) by A12;
take m = m; :: thesis: ( n < m & s2 . m <> x0 )
thus ( n < m & s2 . m <> x0 ) by A16, NAT_1:13; :: thesis: verum

end;

A17: for n, x being Element of NAT ex y being Element of NAT st S₂[n,x,y]

proof

let n, x be Element of NAT ; :: thesis: ex y being Element of NAT st S₂[n,x,y]
defpred S₄[ Nat] means ( x < $1 & s2 . $1 <> x0 );
ex m being Element of NAT st S₄[m] by A15;
then A18: ex m being Nat st S₄[m] ;
consider l being Nat such that
A19: ( S₄[l] & ( for k being Nat st S₄[k] holds
l <= k ) ) from NAT_1:sch 5(A18);
take l ; :: thesis: ( l is Element of REAL & l is Element of NAT & S₂[n,x,l] )
l in NAT by ORDINAL1:def 12;
hence ( l is Element of REAL & l is Element of NAT & S₂[n,x,l] ) by A19; :: thesis: verum

end;

consider F being Function of NAT,NAT such that
A20: ( F . 0 = M9 & ( for n being Element of NAT holds S₂[n,F . n,F . (n + 1)] ) ) from RECDEF_1:sch 2(A17);
A21: for n being Element of NAT holds F . n is real ;
A22: rng F c= NAT ;
A23: dom F = NAT by FUNCT_2:def 1;
then reconsider F = F as Real_Sequence by A21, SEQ_1:2;

A24: now

let n be Element of NAT ; :: thesis: F . n is Element of NAT
F . n in rng F by A23, FUNCT_1:def 3;
hence F . n is Element of NAT by A22; :: thesis: verum

end;

now

let n be Element of NAT ; :: thesis: F . n < F . (n + 1)
( F . n is Element of NAT & F . (n + 1) is Element of NAT ) by A24;
hence F . n < F . (n + 1) by A20; :: thesis: verum

end;

then reconsider F = F as V36() sequence of NAT by SEQM_3:def 6;
A25: s2 * F is subsequence of s2 by VALUED_0:def 17;
then A26: ( s2 * F is convergent & lim (s2 * F) = x0 ) by A4, Th39, Th40;
A27: for n being Element of NAT st s2 . n <> x0 holds
ex m being Element of NAT st F . m = n

proof

defpred S₄[ set ] means ( s2 . $1 <> x0 & ( for m being Element of NAT holds F . m <> $1 ) );
assume ex n being Element of NAT st S₄[n] ; :: thesis: contradiction
then A28: ex n being Nat st S₄[n] ;
consider M1 being Nat such that
A29: ( S₄[M1] & ( for n being Nat st S₄[n] holds
M1 <= n ) ) from NAT_1:sch 5(A28);
defpred S₅[ Nat] means ( $1 < M1 & s2 . $1 <> x0 & ex m being Element of NAT st F . m = $1 );
A30: ex n being Nat st S₅[n]

proof

take M ; :: thesis: S₅[M]
( M <= M1 & M <> M1 ) by A14, A20, A29;
hence M < M1 by XXREAL_0:1; :: thesis: ( s2 . M <> x0 & ex m being Element of NAT st F . m = M )
thus s2 . M <> x0 by A14; :: thesis: ex m being Element of NAT st F . m = M
take 0 ; :: thesis: F . 0 = M
thus F . 0 = M by A20; :: thesis: verum

end;

A31: for n being Nat st S₅[n] holds
n <= M1 ;
consider MX being Nat such that
A32: ( S₅[MX] & ( for n being Nat st S₅[n] holds
n <= MX ) ) from NAT_1:sch 6(A31, A30);
A33: for k being Element of NAT st MX < k & k < M1 holds
s2 . k = x0

proof

given k being Element of NAT such that A34: MX < k and
A35: ( k < M1 & s2 . k <> x0 ) ; :: thesis: contradiction

now

per cases ( ex m being Element of NAT st F . m = k or for m being Element of NAT holds F . m <> k ) ;

suppose ex m being Element of NAT st F . m = k ; :: thesis: contradiction

hence contradiction by A32, A34, A35; :: thesis: verum

end;

suppose for m being Element of NAT holds F . m <> k ; :: thesis: contradiction

hence contradiction by A29, A35; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum

end;

consider m being Element of NAT such that
A36: F . m = MX by A32;
A37: ( MX < F . (m + 1) & s2 . (F . (m + 1)) <> x0 ) by A20, A36;
M1 in NAT by ORDINAL1:def 12;
then A38: F . (m + 1) <= M1 by A20, A29, A32, A36;

now

assume F . (m + 1) <> M1 ; :: thesis: contradiction
then F . (m + 1) < M1 by A38, XXREAL_0:1;
hence contradiction by A33, A37; :: thesis: verum

end;

hence contradiction by A29; :: thesis: verum

end;

defpred S₄[ Element of NAT ] means (s2 * F) . $1 <> x0;
A39: for k being Element of NAT st S₄[k] holds
S₄[k + 1]

proof

let k be Element of NAT ; :: thesis: ( S₄[k] implies S₄[k + 1] )
assume (s2 * F) . k <> x0 ; :: thesis: S₄[k + 1]
S₁[F . k,F . (k + 1)] by A20;
then s2 . (F . (k + 1)) <> x0 ;
hence S₄[k + 1] by FUNCT_2:15; :: thesis: verum

end;

A40: S₄[ 0 ] by A14, A20, FUNCT_2:15;
A41: for n being Element of NAT holds S₄[n] from NAT_1:sch 1(A40, A39);
A42: rng (s2 * F) c= rng s2 by A25, VALUED_0:21;
then rng (s2 * F) c= dom f by A3, XBOOLE_1:1;
then A43: ( f /* (s2 * F) is convergent & f /. x0 = lim (f /* (s2 * F)) ) by A2, A41, A26;

A44: now

let p be Real; :: thesis: ( 0 < p implies ex k being Element of NAT st
for m being Element of NAT st k <= m holds
|.(((f /* s2) . m) - (f /. x0)).| < p )
assume A45: 0 < p ; :: thesis: ex k being Element of NAT st
for m being Element of NAT st k <= m holds
|.(((f /* s2) . m) - (f /. x0)).| < p
then consider n being Element of NAT such that
A46: for m being Element of NAT st n <= m holds
|.(((f /* (s2 * F)) . m) - (f /. x0)).| < p by A43, COMSEQ_2:def 5;
take k = F . n; :: thesis: for m being Element of NAT st k <= m holds
|.(((f /* s2) . m) - (f /. x0)).| < p
let m be Element of NAT ; :: thesis: ( k <= m implies |.(((f /* s2) . m) - (f /. x0)).| < p )
assume A47: k <= m ; :: thesis: |.(((f /* s2) . m) - (f /. x0)).| < p

now

per cases ( s2 . m = x0 or s2 . m <> x0 ) ;

suppose s2 . m = x0 ; :: thesis: |.(((f /* s2) . m) - (f /. x0)).| < p

then |.(((f /* s2) . m) - (f /. x0)).| = |.((f /. x0) - (f /. x0)).| by A3, FUNCT_2:109
.= 0 by COMPLEX1:44 ;
hence |.(((f /* s2) . m) - (f /. x0)).| < p by A45; :: thesis: verum

end;

suppose s2 . m <> x0 ; :: thesis: |.(((f /* s2) . m) - (f /. x0)).| < p

then consider l being Element of NAT such that
A48: m = F . l by A27;
n <= l by A47, A48, SEQM_3:1;
then |.(((f /* (s2 * F)) . l) - (f /. x0)).| < p by A46;
then |.((f /. ((s2 * F) . l)) - (f /. x0)).| < p by A3, A42, FUNCT_2:109, XBOOLE_1:1;
then |.((f /. (s2 . m)) - (f /. x0)).| < p by A48, FUNCT_2:15;
hence |.(((f /* s2) . m) - (f /. x0)).| < p by A3, FUNCT_2:109; :: thesis: verum

end;

end;

end;

hence |.(((f /* s2) . m) - (f /. x0)).| < p ; :: thesis: verum

end;

hence f /* s2 is convergent by COMSEQ_2:def 4; :: thesis: f /. x0 = lim (f /* s2)
hence f /. x0 = lim (f /* s2) by A44, COMSEQ_2:def 5; :: thesis: verum

end;

end;

end;

hence ( f /* s2 is convergent & f /. x0 = lim (f /* s2) ) ; :: thesis: verum