let X be non empty set ; :: thesis: for a being Complex
for F, G being Point of (C_Normed_Algebra_of_BoundedFunctions X) holds
( ( ||.F.|| = 0 implies F = 0. (C_Normed_Algebra_of_BoundedFunctions X) ) & ( F = 0. (C_Normed_Algebra_of_BoundedFunctions X) implies ||.F.|| = 0 ) & ||.(a * F).|| = |.a.| * ||.F.|| & ||.(F + G).|| <= ||.F.|| + ||.G.|| )
let a be Complex; :: thesis: for F, G being Point of (C_Normed_Algebra_of_BoundedFunctions X) holds
( ( ||.F.|| = 0 implies F = 0. (C_Normed_Algebra_of_BoundedFunctions X) ) & ( F = 0. (C_Normed_Algebra_of_BoundedFunctions X) implies ||.F.|| = 0 ) & ||.(a * F).|| = |.a.| * ||.F.|| & ||.(F + G).|| <= ||.F.|| + ||.G.|| )
let F, G be Point of (C_Normed_Algebra_of_BoundedFunctions X); :: thesis: ( ( ||.F.|| = 0 implies F = 0. (C_Normed_Algebra_of_BoundedFunctions X) ) & ( F = 0. (C_Normed_Algebra_of_BoundedFunctions X) implies ||.F.|| = 0 ) & ||.(a * F).|| = |.a.| * ||.F.|| & ||.(F + G).|| <= ||.F.|| + ||.G.|| )

A1: now

set z = X --> 0c;
reconsider z = X --> 0c as Function of X,COMPLEX ;
F in ComplexBoundedFunctions X ;
then consider g being Function of X,COMPLEX such that
A2: F = g and
A3: g | X is bounded ;
A4: ( not PreNorms g is empty & PreNorms g is bounded_above ) by A3, Th14;
consider r0 being set such that
A5: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A5;
A6: ( ( for s being real number st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
assume F = 0. (C_Normed_Algebra_of_BoundedFunctions X) ; :: thesis: ||.F.|| = 0
then A7: z = g by A2, Th22;

A8: now

let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being Element of X such that
A9: r = |.(g . t).| ;
|.(g . t).| = |.0.| by A7, FUNCOP_1:7
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A9; :: thesis: verum

end;

then 0 <= r0 by A5;
then upper_bound (PreNorms g) = 0 by A8, A4, A6, A5, SEQ_4:def 1;
hence ||.F.|| = 0 by A2, A3, Th17; :: thesis: verum

end;

A10: ||.(F + G).|| <= ||.F.|| + ||.G.||

proof

F + G in ComplexBoundedFunctions X ;
then consider h1 being Function of X,COMPLEX such that
A11: h1 = F + G and
A12: h1 | X is bounded ;
G in ComplexBoundedFunctions X ;
then consider g1 being Function of X,COMPLEX such that
A13: g1 = G and
A14: g1 | X is bounded ;
F in ComplexBoundedFunctions X ;
then consider f1 being Function of X,COMPLEX such that
A15: f1 = F and
A16: f1 | X is bounded ;

A17: now

let t be Element of X; :: thesis: |.(h1 . t).| <= ||.F.|| + ||.G.||
( |.(f1 . t).| <= ||.F.|| & |.(g1 . t).| <= ||.G.|| ) by A15, A16, A13, A14, Th23;
then A18: |.(f1 . t).| + |.(g1 . t).| <= ||.F.|| + ||.G.|| by XREAL_1:7;
( |.(h1 . t).| = |.((f1 . t) + (g1 . t)).| & |.((f1 . t) + (g1 . t)).| <= |.(f1 . t).| + |.(g1 . t).| ) by A15, A13, A11, Th26, COMPLEX1:56;
hence |.(h1 . t).| <= ||.F.|| + ||.G.|| by A18, XXREAL_0:2; :: thesis: verum

end;

A19: now

let r be real number ; :: thesis: ( r in PreNorms h1 implies r <= ||.F.|| + ||.G.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.F.|| + ||.G.||
then ex t being Element of X st r = |.(h1 . t).| ;
hence r <= ||.F.|| + ||.G.|| by A17; :: thesis: verum

end;

( ( for s being real number st s in PreNorms h1 holds
s <= ||.F.|| + ||.G.|| ) implies upper_bound (PreNorms h1) <= ||.F.|| + ||.G.|| ) by SEQ_4:45;
hence ||.(F + G).|| <= ||.F.|| + ||.G.|| by A11, A12, A19, Th17; :: thesis: verum

end;

A20: ||.(a * F).|| = |.a.| * ||.F.||

proof

F in ComplexBoundedFunctions X ;
then consider f1 being Function of X,COMPLEX such that
A21: f1 = F and
A22: f1 | X is bounded ;
a * F in ComplexBoundedFunctions X ;
then consider h1 being Function of X,COMPLEX such that
A23: h1 = a * F and
A24: h1 | X is bounded ;

A25: now

let t be Element of X; :: thesis: |.(h1 . t).| <= |.a.| * ||.F.||
|.(h1 . t).| = |.(a * (f1 . t)).| by A21, A23, Th27;
then |.(h1 . t).| = |.a.| * |.(f1 . t).| by COMPLEX1:65;
hence |.(h1 . t).| <= |.a.| * ||.F.|| by A21, A22, Th23, XREAL_1:64; :: thesis: verum

end;

A27: now

let r be real number ; :: thesis: ( r in PreNorms h1 implies r <= |.a.| * ||.F.|| )
assume r in PreNorms h1 ; :: thesis: r <= |.a.| * ||.F.||
then ex t being Element of X st r = |.(h1 . t).| ;
hence r <= |.a.| * ||.F.|| by A25; :: thesis: verum

end;

( ( for s being real number st s in PreNorms h1 holds
s <= |.a.| * ||.F.|| ) implies upper_bound (PreNorms h1) <= |.a.| * ||.F.|| ) by SEQ_4:45;
then A28: ||.(a * F).|| <= |.a.| * ||.F.|| by A23, A24, A27, Th17;

per cases ( a <> 0 or a = 0 ) ;

suppose A29: a <> 0 ; :: thesis: ||.(a * F).|| = |.a.| * ||.F.||

A30: now

let t be Element of X; :: thesis: |.(f1 . t).| <= (|.a.| ") * ||.(a * F).||
|.(a ").| = |.(1 / a).| ;
then A31: |.(a ").| = 1 / |.a.| by COMPLEX1:80;
h1 . t = a * (f1 . t) by A21, A23, Th27;
then (a ") * (h1 . t) = ((a ") * a) * (f1 . t) ;
then A32: (a ") * (h1 . t) = 1 * (f1 . t) by A29, XCMPLX_0:def 7;
( |.((a ") * (h1 . t)).| = |.(a ").| * |.(h1 . t).| & 0 <= |.(a ").| ) by COMPLEX1:65;
hence |.(f1 . t).| <= (|.a.| ") * ||.(a * F).|| by A23, A24, A32, A31, Th23, XREAL_1:64; :: thesis: verum

end;

A33: now

let r be Real; :: thesis: ( r in PreNorms f1 implies r <= (|.a.| ") * ||.(a * F).|| )
assume r in PreNorms f1 ; :: thesis: r <= (|.a.| ") * ||.(a * F).||
then ex t being Element of X st r = |.(f1 . t).| ;
hence r <= (|.a.| ") * ||.(a * F).|| by A30; :: thesis: verum

end;

( ( for s being real number st s in PreNorms f1 holds
s <= (|.a.| ") * ||.(a * F).|| ) implies upper_bound (PreNorms f1) <= (|.a.| ") * ||.(a * F).|| ) by SEQ_4:45;
then ||.F.|| <= (|.a.| ") * ||.(a * F).|| by A21, A22, A33, Th17;
then |.a.| * ||.F.|| <= |.a.| * ((|.a.| ") * ||.(a * F).||) by XREAL_1:64;
then |.a.| * ||.F.|| <= (|.a.| * (|.a.| ")) * ||.(a * F).|| ;
then |.a.| * ||.F.|| <= 1 * ||.(a * F).|| by A29, XCMPLX_0:def 7;
hence ||.(a * F).|| = |.a.| * ||.F.|| by A28, XXREAL_0:1; :: thesis: verum

end;

suppose A35: a = 0 ; :: thesis: ||.(a * F).|| = |.a.| * ||.F.||

reconsider fz = F as VECTOR of (C_Algebra_of_BoundedFunctions X) ;
a * fz = (a + a) * fz by A35
.= (a * fz) + (a * fz) by CLVECT_1:def 3 ;
then 0. (C_Algebra_of_BoundedFunctions X) = (- (a * fz)) + ((a * fz) + (a * fz)) by VECTSP_1:16;
then 0. (C_Algebra_of_BoundedFunctions X) = ((- (a * fz)) + (a * fz)) + (a * fz) by RLVECT_1:def 3;
then 0. (C_Algebra_of_BoundedFunctions X) = (0. (C_Algebra_of_BoundedFunctions X)) + (a * fz) by VECTSP_1:16;
then A36: a * F = 0. (C_Normed_Algebra_of_BoundedFunctions X) by RLVECT_1:4;
|.a.| * ||.F.|| = 0 * ||.F.|| by A35;
hence ||.(a * F).|| = |.a.| * ||.F.|| by A36, Th25; :: thesis: verum

end;

end;

end;

now

set z = X --> 0c;
reconsider z = X --> 0c as Function of X,COMPLEX ;
F in ComplexBoundedFunctions X ;
then consider g being Function of X,COMPLEX such that
A37: F = g and
A38: g | X is bounded ;
assume A39: ||.F.|| = 0 ; :: thesis: F = 0. (C_Normed_Algebra_of_BoundedFunctions X)

now

let t be Element of X; :: thesis: g . t = z . t
|.(g . t).| = 0 by A37, A38, A39, Th23;
hence g . t = 0
.= z . t by FUNCOP_1:7 ;
:: thesis: verum

end;

then g = z by FUNCT_2:63;
hence F = 0. (C_Normed_Algebra_of_BoundedFunctions X) by A37, Th22; :: thesis: verum

end;

hence ( ( ||.F.|| = 0 implies F = 0. (C_Normed_Algebra_of_BoundedFunctions X) ) & ( F = 0. (C_Normed_Algebra_of_BoundedFunctions X) implies ||.F.|| = 0 ) & ||.(a * F).|| = |.a.| * ||.F.|| & ||.(F + G).|| <= ||.F.|| + ||.G.|| ) by A1, A20, A10; :: thesis: verum