let Y be non empty set ; :: thesis: for a, b being Element of Funcs (Y,BOOLEAN) holds (a 'imp' b) '&' (a 'imp' ('not' b)) = 'not' a
let a, b be Element of Funcs (Y,BOOLEAN); :: thesis: (a 'imp' b) '&' (a 'imp' ('not' b)) = 'not' a
consider k3 being Function such that
A1: (a 'imp' b) '&' (a 'imp' ('not' b)) = k3 and
A2: dom k3 = Y and
rng k3 c= BOOLEAN by FUNCT_2:def 2;
consider k4 being Function such that
A3: 'not' a = k4 and
A4: dom k4 = Y and
rng k4 c= BOOLEAN by FUNCT_2:def 2;
for x being Element of Y holds ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x

proof

let x be Element of Y; :: thesis: ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x
A5: ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ((a 'imp' b) . x) '&' ((a 'imp' ('not' b)) . x) by MARGREL1:def 20
.= (('not' (a . x)) 'or' (b . x)) '&' ((a 'imp' ('not' b)) . x) by BVFUNC_1:def 8
.= (('not' (a . x)) 'or' (b . x)) '&' (('not' (a . x)) 'or' (('not' b) . x)) by BVFUNC_1:def 8
.= (('not' (a . x)) 'or' (b . x)) '&' (('not' (a . x)) 'or' ('not' (b . x))) by MARGREL1:def 19 ;

now

per cases ( b . x = TRUE or b . x = FALSE ) by XBOOLEAN:def 3;

case b . x = TRUE ; :: thesis: ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x

then ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = (('not' (a . x)) 'or' TRUE) '&' (('not' (a . x)) 'or' FALSE) by A5, MARGREL1:11
.= (('not' (a . x)) 'or' TRUE) '&' ('not' (a . x)) by BINARITH:3
.= TRUE '&' ('not' (a . x)) by BINARITH:10
.= 'not' (a . x) by MARGREL1:14
.= ('not' a) . x by MARGREL1:def 19 ;
hence ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x ; :: thesis: verum

end;

case b . x = FALSE ; :: thesis: ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x

then ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = (('not' (a . x)) 'or' FALSE) '&' (('not' (a . x)) 'or' TRUE) by A5, MARGREL1:11
.= ('not' (a . x)) '&' (('not' (a . x)) 'or' TRUE) by BINARITH:3
.= TRUE '&' ('not' (a . x)) by BINARITH:10
.= 'not' (a . x) by MARGREL1:14
.= ('not' a) . x by MARGREL1:def 19 ;
hence ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x ; :: thesis: verum

end;

end;

end;

hence ((a 'imp' b) '&' (a 'imp' ('not' b))) . x = ('not' a) . x ; :: thesis: verum

end;

then for u being set st u in Y holds
k3 . u = k4 . u by A1, A3;
hence (a 'imp' b) '&' (a 'imp' ('not' b)) = 'not' a by A1, A2, A3, A4, FUNCT_1:2; :: thesis: verum