let X be RealUnitarySpace; :: thesis: for a being Real
for seq being sequence of X st seq is convergent holds
lim (a * seq) = a * (lim seq)
let a be Real; :: thesis: for seq being sequence of X st seq is convergent holds
lim (a * seq) = a * (lim seq)
let seq be sequence of X; :: thesis: ( seq is convergent implies lim (a * seq) = a * (lim seq) )
set g = lim seq;
set h = a * (lim seq);
assume A1: seq is convergent ; :: thesis: lim (a * seq) = a * (lim seq)

A2: now

assume A3: a = 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r
then consider m1 being Element of NAT such that
A4: for n being Element of NAT st n >= m1 holds
dist ((seq . n),(lim seq)) < r by A1, Def2;
take k = m1; :: thesis: for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r
let n be Element of NAT ; :: thesis: ( n >= k implies dist (((a * seq) . n),(a * (lim seq))) < r )
assume n >= k ; :: thesis: dist (((a * seq) . n),(a * (lim seq))) < r
then A5: dist ((seq . n),(lim seq)) < r by A4;
dist ((a * (seq . n)),(a * (lim seq))) = dist ((0 * (seq . n)),H₁(X)) by A3, RLVECT_1:10
.= dist (H₁(X),H₁(X)) by RLVECT_1:10
.= 0 by BHSP_1:34 ;
then dist ((a * (seq . n)),(a * (lim seq))) < r by A5, BHSP_1:37;
hence dist (((a * seq) . n),(a * (lim seq))) < r by NORMSP_1:def 5; :: thesis: verum

end;

A6: now

A7: 0 / (abs a) = 0 ;
assume A8: a <> 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r
then A9: abs a > 0 by COMPLEX1:47;
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r
then r / (abs a) > 0 by A9, A7, XREAL_1:74;
then consider m1 being Element of NAT such that
A10: for n being Element of NAT st n >= m1 holds
dist ((seq . n),(lim seq)) < r / (abs a) by A1, Def2;
take k = m1; :: thesis: for n being Element of NAT st n >= k holds
dist (((a * seq) . n),(a * (lim seq))) < r
let n be Element of NAT ; :: thesis: ( n >= k implies dist (((a * seq) . n),(a * (lim seq))) < r )
assume n >= k ; :: thesis: dist (((a * seq) . n),(a * (lim seq))) < r
then A11: dist ((seq . n),(lim seq)) < r / (abs a) by A10;
A12: abs a <> 0 by A8, COMPLEX1:47;
A13: (abs a) * (r / (abs a)) = (abs a) * (((abs a) ") * r) by XCMPLX_0:def 9
.= ((abs a) * ((abs a) ")) * r
.= 1 * r by A12, XCMPLX_0:def 7
.= r ;
dist ((a * (seq . n)),(a * (lim seq))) = ||.((a * (seq . n)) - (a * (lim seq))).|| by BHSP_1:def 5
.= ||.(a * ((seq . n) - (lim seq))).|| by RLVECT_1:34
.= (abs a) * ||.((seq . n) - (lim seq)).|| by BHSP_1:27
.= (abs a) * (dist ((seq . n),(lim seq))) by BHSP_1:def 5 ;
then dist ((a * (seq . n)),(a * (lim seq))) < r by A9, A11, A13, XREAL_1:68;
hence dist (((a * seq) . n),(a * (lim seq))) < r by NORMSP_1:def 5; :: thesis: verum

end;

a * seq is convergent by A1, Th5;
hence lim (a * seq) = a * (lim seq) by A2, A6, Def2; :: thesis: verum