let A be closed-interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R) holds
integral (f,A) = ((- (cos * exp_R)) . (upper_bound A)) - ((- (cos * exp_R)) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R) holds
integral (f,A) = ((- (cos * exp_R)) . (upper_bound A)) - ((- (cos * exp_R)) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R) implies integral (f,A) = ((- (cos * exp_R)) . (upper_bound A)) - ((- (cos * exp_R)) . (lower_bound A)) )
assume A1: ( A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R) ) ; :: thesis: integral (f,A) = ((- (cos * exp_R)) . (upper_bound A)) - ((- (cos * exp_R)) . (lower_bound A))
then Z = (dom exp_R) /\ (dom (sin * exp_R)) by VALUED_1:def 4;
then A2: ( Z c= dom exp_R & Z c= dom (sin * exp_R) ) by XBOOLE_1:18;
for y being set st y in Z holds
y in dom (cos * exp_R)

proof

let y be set ; :: thesis: ( y in Z implies y in dom (cos * exp_R) )
assume y in Z ; :: thesis: y in dom (cos * exp_R)
then ( y in dom exp_R & exp_R . y in dom cos ) by A2, SIN_COS:27;
hence y in dom (cos * exp_R) by FUNCT_1:21; :: thesis: verum

end;

then A3: Z c= dom (cos * exp_R) by TARSKI:def 3;
A4: sin * exp_R is_differentiable_on Z by A2, FDIFF_7:34;
exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
then f | Z is continuous by A1, A4, FDIFF_1:29, FDIFF_1:33;
then f | A is continuous by A1, FCONT_1:17;
then A5: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A6: cos * exp_R is_differentiable_on Z by A3, FDIFF_7:35;
A7: Z c= dom (- (cos * exp_R)) by A3, VALUED_1:8;
then A8: (- 1) (#) (cos * exp_R) is_differentiable_on Z by A6, Lm1, FDIFF_1:28;
A9: for x being Real st x in Z holds
((- (cos * exp_R)) `| Z) . x = (exp_R . x) * (sin . (exp_R . x))

proof

let x be Real; :: thesis: ( x in Z implies ((- (cos * exp_R)) `| Z) . x = (exp_R . x) * (sin . (exp_R . x)) )
assume A10: x in Z ; :: thesis: ((- (cos * exp_R)) `| Z) . x = (exp_R . x) * (sin . (exp_R . x))
A11: exp_R is_differentiable_in x by SIN_COS:70;
A12: cos is_differentiable_in exp_R . x by SIN_COS:68;
A13: cos * exp_R is_differentiable_in x by A6, A10, FDIFF_1:16;
((- (cos * exp_R)) `| Z) . x = diff ((- (cos * exp_R)),x) by A8, A10, FDIFF_1:def 8
.= (- 1) * (diff ((cos * exp_R),x)) by A13, Lm1, FDIFF_1:23
.= (- 1) * ((diff (cos,(exp_R . x))) * (diff (exp_R,x))) by A11, A12, FDIFF_2:13
.= (- 1) * ((- (sin . (exp_R . x))) * (diff (exp_R,x))) by SIN_COS:68
.= (- 1) * ((- (sin . (exp_R . x))) * (exp_R . x)) by SIN_COS:70
.= (exp_R . x) * (sin . (exp_R . x)) ;
hence ((- (cos * exp_R)) `| Z) . x = (exp_R . x) * (sin . (exp_R . x)) ; :: thesis: verum

end;

A14: for x being Real st x in Z holds
f . x = (exp_R . x) * (sin . (exp_R . x))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . x) * (sin . (exp_R . x)) )
assume A15: x in Z ; :: thesis: f . x = (exp_R . x) * (sin . (exp_R . x))
then (exp_R (#) (sin * exp_R)) . x = (exp_R . x) * ((sin * exp_R) . x) by A1, VALUED_1:def 4
.= (exp_R . x) * (sin . (exp_R . x)) by A2, A15, FUNCT_1:22 ;
hence f . x = (exp_R . x) * (sin . (exp_R . x)) by A1; :: thesis: verum

end;

A16: for x being Real st x in dom ((- (cos * exp_R)) `| Z) holds
((- (cos * exp_R)) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((- (cos * exp_R)) `| Z) implies ((- (cos * exp_R)) `| Z) . x = f . x )
assume x in dom ((- (cos * exp_R)) `| Z) ; :: thesis: ((- (cos * exp_R)) `| Z) . x = f . x
then A17: x in Z by A8, FDIFF_1:def 8;
then ((- (cos * exp_R)) `| Z) . x = (exp_R . x) * (sin . (exp_R . x)) by A9
.= f . x by A17, A14 ;
hence ((- (cos * exp_R)) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((- (cos * exp_R)) `| Z) = dom f by A1, A8, FDIFF_1:def 8;
then (- (cos * exp_R)) `| Z = f by A16, PARTFUN1:34;
hence integral (f,A) = ((- (cos * exp_R)) . (upper_bound A)) - ((- (cos * exp_R)) . (lower_bound A)) by A1, A5, A6, A7, Lm1, FDIFF_1:28, INTEGRA5:13; :: thesis: verum