let p be the Instructions of SCM+FSA -valued ManySortedSet of NAT ; :: thesis: for s being State of SCM+FSA
for I, J being Program of SCM+FSA st I is_closed_on s,p & Initialize I c= s & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
let s be State of SCM+FSA; :: thesis: for I, J being Program of SCM+FSA st I is_closed_on s,p & Initialize I c= s & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
let I, J be Program of SCM+FSA; :: thesis: ( I is_closed_on s,p & Initialize I c= s & I c= p & p halts_on s implies for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT )
assume that
A1: I is_closed_on s,p and
A2: Initialize I c= s and
A3: I c= p and
A4: p halts_on s ; :: thesis: for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
A5: p +* I = p by A3, FUNCT_4:79;
A6: ProgramPart I = I by RELAT_1:209;
defpred S₁[ Element of NAT ] means ( $1 <= LifeSpan (p,s) implies Comput (p,s,$1), Comput ((p +* (I ';' J)),(s +* (I ';' J)),$1) equal_outside NAT );
A7: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

dom (I ';' J) = (dom (Directed I)) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:def 1
.= (dom I) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:105 ;
then A8: dom I c= dom (I ';' J) by XBOOLE_1:7;
set sIJ = s +* (I ';' J);
set pIJ = p +* (I ';' J);
A9: I ';' J c= p +* (I ';' J) by FUNCT_4:26;
let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A10: ( m <= LifeSpan (p,s) implies Comput (p,s,m), Comput ((p +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT ) ; :: thesis: S₁[m + 1]
A11: Comput ((p +* (I ';' J)),(s +* (I ';' J)),(m + 1)) = Following ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),(s +* (I ';' J)),m))) by EXTPRO_1:4
.= Exec ((CurInstr ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),(s +* (I ';' J)),m)))),(Comput ((p +* (I ';' J)),(s +* (I ';' J)),m))) ;
A12: Comput (p,s,(m + 1)) = Following (p,(Comput (p,s,m))) by EXTPRO_1:4
.= Exec ((CurInstr (p,(Comput (p,s,m)))),(Comput (p,s,m))) ;
A13: p /. (IC (Comput (p,s,m))) = p . (IC (Comput (p,s,m))) by PBOOLE:158;
assume A14: m + 1 <= LifeSpan (p,s) ; :: thesis: Comput (p,s,(m + 1)), Comput ((p +* (I ';' J)),(s +* (I ';' J)),(m + 1)) equal_outside NAT
then A15: IC (Comput (p,s,m)) = IC (Comput ((p +* (I ';' J)),(s +* (I ';' J)),m)) by A10, COMPOS_1:24, NAT_1:13;
s = s +* (Initialize I) by A2, FUNCT_4:79;
then A16: IC (Comput (p,s,m)) in dom I by A1, SCMFSA7B:def 7, A6, A5;
A17: CurInstr (p,(Comput (p,s,m))) = I . (IC (Comput (p,s,m))) by A16, A13, GRFUNC_1:8, A3;
A18: (p +* (I ';' J)) /. (IC (Comput ((p +* (I ';' J)),(s +* (I ';' J)),m))) = (p +* (I ';' J)) . (IC (Comput ((p +* (I ';' J)),(s +* (I ';' J)),m))) by PBOOLE:158;
m < LifeSpan (p,s) by A14, NAT_1:13;
then I . (IC (Comput (p,s,m))) <> halt SCM+FSA by A4, A17, EXTPRO_1:def 14;
then CurInstr (p,(Comput (p,s,m))) = (I ';' J) . (IC (Comput (p,s,m))) by A16, A17, SCMFSA6A:54
.= CurInstr ((p +* (I ';' J)),(Comput ((p +* (I ';' J)),(s +* (I ';' J)),m))) by A15, A16, A8, A18, GRFUNC_1:8, A9 ;
hence Comput (p,s,(m + 1)), Comput ((p +* (I ';' J)),(s +* (I ';' J)),(m + 1)) equal_outside NAT by A10, A14, A12, A11, NAT_1:13, AMISTD_2:def 20; :: thesis: verum

end;

A19: Comput ((p +* (I ';' J)),(s +* (I ';' J)),0) = s +* (I ';' J) by EXTPRO_1:3;
Comput (p,s,0) = s by EXTPRO_1:3;
then A20: S₁[ 0 ] by A19, FUNCT_7:132;
thus for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A20, A7); :: thesis: verum