let s be State of SCM+FSA; :: thesis: for I being paraclosed Program of SCM+FSA
for J being Program of SCM+FSA
for P being the Instructions of SCM+FSA -valued ManySortedSet of NAT st I c= P & Initialize I c= s & P halts_on s holds
for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
let I be paraclosed Program of SCM+FSA; :: thesis: for J being Program of SCM+FSA
for P being the Instructions of SCM+FSA -valued ManySortedSet of NAT st I c= P & Initialize I c= s & P halts_on s holds
for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
let J be Program of SCM+FSA; :: thesis: for P being the Instructions of SCM+FSA -valued ManySortedSet of NAT st I c= P & Initialize I c= s & P halts_on s holds
for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
let P be the Instructions of SCM+FSA -valued ManySortedSet of NAT ; :: thesis: ( I c= P & Initialize I c= s & P halts_on s implies for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT )
assume A1: I c= P ; :: thesis: ( not Initialize I c= s or not P halts_on s or for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT )
assume that
A2: Initialize I c= s and
A3: P halts_on s ; :: thesis: for m being Element of NAT st m <= LifeSpan (P,s) holds
Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT
A4: ProgramPart (Initialize I) = I by COMPOS_1:144;
A5: ProgramPart (Initialize I) c= P by A1, COMPOS_1:144;
defpred S₁[ Nat] means ( $1 <= LifeSpan (P,s) implies Comput (P,s,$1), Comput ((P +* (I ';' J)),(s +* (I ';' J)),$1) equal_outside NAT );
A6: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A7: ( m <= LifeSpan (P,s) implies Comput (P,s,m), Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) equal_outside NAT ) ; :: thesis: S₁[m + 1]
dom (I ';' J) = (dom (Directed I)) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:def 1
.= (dom I) \/ (dom (Reloc (J,(card I)))) by FUNCT_4:105 ;
then A8: ( I ';' J c= Comput ((P +* (I ';' J)),(s +* (I ';' J)),m) & dom I c= dom (I ';' J) ) by AMI_1:81, FUNCT_4:26, XBOOLE_1:7;
A9: Comput (P,s,(m + 1)) = Following (P,(Comput (P,s,m))) by EXTPRO_1:4
.= Exec ((CurInstr (P,(Comput (P,s,m)))),(Comput (P,s,m))) ;
A10: Comput ((P +* (I ';' J)),(s +* (I ';' J)),(m + 1)) = Following ((P +* (I ';' J)),(Comput ((P +* (I ';' J)),(s +* (I ';' J)),m))) by EXTPRO_1:4
.= Exec ((CurInstr ((P +* (I ';' J)),(Comput ((P +* (I ';' J)),(s +* (I ';' J)),m)))),(Comput ((P +* (I ';' J)),(s +* (I ';' J)),m))) ;
A11: IC (Comput (P,s,m)) in dom I by A2, Def2, A4, A5;
dom P = NAT by PARTFUN1:def 4;
then A12: CurInstr (P,(Comput (P,s,m))) = P . (IC (Comput (P,s,m))) by PARTFUN1:def 8
.= I . (IC (Comput (P,s,m))) by A11, GRFUNC_1:8, A1 ;
assume A13: m + 1 <= LifeSpan (P,s) ; :: thesis: Comput (P,s,(m + 1)), Comput ((P +* (I ';' J)),(s +* (I ';' J)),(m + 1)) equal_outside NAT
A14: I ';' J c= P +* (I ';' J) by FUNCT_4:26;
A15: dom (P +* (I ';' J)) = NAT by PARTFUN1:def 4;
m < LifeSpan (P,s) by A13, NAT_1:13;
then I . (IC (Comput (P,s,m))) <> halt SCM+FSA by A3, A12, EXTPRO_1:def 14;
then CurInstr (P,(Comput (P,s,m))) = (I ';' J) . (IC (Comput (P,s,m))) by A11, A12, SCMFSA6A:54
.= (P +* (I ';' J)) . (IC (Comput (P,s,m))) by A11, A8, GRFUNC_1:8, A14
.= (P +* (I ';' J)) . (IC (Comput ((P +* (I ';' J)),(s +* (I ';' J)),m))) by A13, A7, COMPOS_1:24, NAT_1:13
.= CurInstr ((P +* (I ';' J)),(Comput ((P +* (I ';' J)),(s +* (I ';' J)),m))) by A15, PARTFUN1:def 8 ;
hence Comput (P,s,(m + 1)), Comput ((P +* (I ';' J)),(s +* (I ';' J)),(m + 1)) equal_outside NAT by A9, A10, AMISTD_2:def 20, A7, A13, NAT_1:13; :: thesis: verum

end;

( Comput (P,s,0) = s & Comput ((P +* (I ';' J)),(s +* (I ';' J)),0) = s +* (I ';' J) ) by EXTPRO_1:3;
then A16: S₁[ 0 ] by FUNCT_7:132;
thus for m being Element of NAT holds S₁[m] from NAT_1:sch 1(A16, A6); :: thesis: verum