let p be the Instructions of SCM+FSA -valued ManySortedSet of NAT ; :: thesis: for s being State of SCM+FSA
for I being InitClosed Program of SCM+FSA st Initialized I c= s & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (loop I)),(s +* (loop I)),m) equal_outside NAT
let s be State of SCM+FSA; :: thesis: for I being InitClosed Program of SCM+FSA st Initialized I c= s & I c= p & p halts_on s holds
for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (loop I)),(s +* (loop I)),m) equal_outside NAT
let I be InitClosed Program of SCM+FSA; :: thesis: ( Initialized I c= s & I c= p & p halts_on s implies for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (loop I)),(s +* (loop I)),m) equal_outside NAT )
assume that
A1: Initialized I c= s and
A2: I c= p ; :: thesis: ( not p halts_on s or for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (loop I)),(s +* (loop I)),m) equal_outside NAT )
defpred S₁[ Nat] means ( $1 <= LifeSpan (p,s) implies Comput (p,s,$1), Comput ((p +* (loop I)),(s +* (loop I)),$1) equal_outside NAT );
assume A3: p halts_on s ; :: thesis: for m being Element of NAT st m <= LifeSpan (p,s) holds
Comput (p,s,m), Comput ((p +* (loop I)),(s +* (loop I)),m) equal_outside NAT
A4: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

set sx = s +* (loop I);
set px = p +* (loop I);
A5: loop I c= p +* (loop I) by FUNCT_4:26;
let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A6: ( m <= LifeSpan (p,s) implies Comput (p,s,m), Comput ((p +* (loop I)),(s +* (loop I)),m) equal_outside NAT ) ; :: thesis: S₁[m + 1]
A7: Comput ((p +* (loop I)),(s +* (loop I)),(m + 1)) = Following ((p +* (loop I)),(Comput ((p +* (loop I)),(s +* (loop I)),m))) by EXTPRO_1:4
.= Exec ((CurInstr ((p +* (loop I)),(Comput ((p +* (loop I)),(s +* (loop I)),m)))),(Comput ((p +* (loop I)),(s +* (loop I)),m))) ;
A8: Comput (p,s,(m + 1)) = Following (p,(Comput (p,s,m))) by EXTPRO_1:4
.= Exec ((CurInstr (p,(Comput (p,s,m)))),(Comput (p,s,m))) ;
A9: IC (Comput (p,s,m)) in dom I by A1, Def1, A2;
then A10: ( loop I c= Comput ((p +* (loop I)),(s +* (loop I)),m) & IC (Comput (p,s,m)) in dom (loop I) ) by AMI_1:81, FUNCT_4:26, FUNCT_4:105;
A11: p /. (IC (Comput (p,s,m))) = p . (IC (Comput (p,s,m))) by PBOOLE:158;
A12: CurInstr (p,(Comput (p,s,m))) = I . (IC (Comput (p,s,m))) by A9, A11, GRFUNC_1:8, A2;
assume A13: m + 1 <= LifeSpan (p,s) ; :: thesis: Comput (p,s,(m + 1)), Comput ((p +* (loop I)),(s +* (loop I)),(m + 1)) equal_outside NAT
then A14: IC (Comput (p,s,m)) = IC (Comput ((p +* (loop I)),(s +* (loop I)),m)) by A6, COMPOS_1:24, NAT_1:13;
A15: (p +* (loop I)) /. (IC (Comput ((p +* (loop I)),(s +* (loop I)),m))) = (p +* (loop I)) . (IC (Comput ((p +* (loop I)),(s +* (loop I)),m))) by PBOOLE:158;
m < LifeSpan (p,s) by A13, NAT_1:13;
then I . (IC (Comput (p,s,m))) <> halt SCM+FSA by A3, A12, EXTPRO_1:def 14;
then CurInstr (p,(Comput (p,s,m))) = (loop I) . (IC (Comput (p,s,m))) by A12, FUNCT_4:111
.= CurInstr ((p +* (loop I)),(Comput ((p +* (loop I)),(s +* (loop I)),m))) by A14, A10, A15, GRFUNC_1:8, A5 ;
hence Comput (p,s,(m + 1)), Comput ((p +* (loop I)),(s +* (loop I)),(m + 1)) equal_outside NAT by A6, A13, A8, A7, NAT_1:13, AMISTD_2:def 20; :: thesis: verum

end;

( Comput (p,s,0) = s & Comput ((p +* (loop I)),(s +* (loop I)),0) = s +* (loop I) ) by EXTPRO_1:3;
then A16: S₁[ 0 ] by FUNCT_7:132;
thus for m being Element of NAT holds S₁[m] from NAT_1:sch 1(A16, A4); :: thesis: verum