let m, n be Nat; :: thesis: for f being Function of (TOP-REAL m),(TOP-REAL n) holds
( f is continuous iff for p being Point of (TOP-REAL m)
for r being real positive number ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r) )
let f be Function of (TOP-REAL m),(TOP-REAL n); :: thesis: ( f is continuous iff for p being Point of (TOP-REAL m)
for r being real positive number ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r) )
A1: ( TopStruct(# the U1 of (TOP-REAL m), the topology of (TOP-REAL m) #) = TopSpaceMetr (Euclid m) & TopStruct(# the U1 of (TOP-REAL n), the topology of (TOP-REAL n) #) = TopSpaceMetr (Euclid n) ) by EUCLID:def 8;
then reconsider f1 = f as Function of (TopSpaceMetr (Euclid m)),(TopSpaceMetr (Euclid n)) ;
A2: ( m in NAT & n in NAT ) by ORDINAL1:def 13;

hereby :: thesis: ( ( for p being Point of (TOP-REAL m)
for r being real positive number ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r) ) implies f is continuous )

assume A3: f is continuous ; :: thesis: for p being Point of (TOP-REAL m)
for r being real positive number ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r)
let p be Point of (TOP-REAL m); :: thesis: for r being real positive number ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r)
let r be real positive number ; :: thesis: ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r)
reconsider p1 = p as Point of (Euclid m) by EUCLID:71;
reconsider q1 = f . p as Point of (Euclid n) by EUCLID:71;
f1 is continuous by A1, A3, YELLOW12:36;
then consider s being real positive number such that
A4: f1 .: (Ball (p1,s)) c= Ball (q1,r) by Th17;
take s = s; :: thesis: f .: (Ball (p,s)) c= Ball ((f . p),r)
( Ball (p1,s) = Ball (p,s) & Ball (q1,r) = Ball ((f . p),r) ) by A2, TOPREAL9:13;
hence f .: (Ball (p,s)) c= Ball ((f . p),r) by A4; :: thesis: verum

end;

assume A5: for p being Point of (TOP-REAL m)
for r being real positive number ex s being real positive number st f .: (Ball (p,s)) c= Ball ((f . p),r) ; :: thesis: f is continuous
for p being Point of (Euclid m)
for q being Point of (Euclid n)
for r being real positive number st q = f1 . p holds
ex s being real positive number st f1 .: (Ball (p,s)) c= Ball (q,r)

proof

let p be Point of (Euclid m); :: thesis: for q being Point of (Euclid n)
for r being real positive number st q = f1 . p holds
ex s being real positive number st f1 .: (Ball (p,s)) c= Ball (q,r)
let q be Point of (Euclid n); :: thesis: for r being real positive number st q = f1 . p holds
ex s being real positive number st f1 .: (Ball (p,s)) c= Ball (q,r)
let r be real positive number ; :: thesis: ( q = f1 . p implies ex s being real positive number st f1 .: (Ball (p,s)) c= Ball (q,r) )
assume A6: q = f1 . p ; :: thesis: ex s being real positive number st f1 .: (Ball (p,s)) c= Ball (q,r)
reconsider p1 = p as Point of (TOP-REAL m) by EUCLID:71;
consider s being real positive number such that
A7: f .: (Ball (p1,s)) c= Ball ((f . p1),r) by A5;
take s ; :: thesis: f1 .: (Ball (p,s)) c= Ball (q,r)
( Ball (p1,s) = Ball (p,s) & Ball ((f . p1),r) = Ball (q,r) ) by A2, A6, TOPREAL9:13;
hence f1 .: (Ball (p,s)) c= Ball (q,r) by A7; :: thesis: verum

end;

then f1 is continuous by Th17;
hence f is continuous by A1, YELLOW12:36; :: thesis: verum