set E = the carrier of R^1;
let T be non empty interval SubSpace of R^1 ; :: thesis: for P, Q being continuous Function of I[01],T holds R1Homotopy (P,Q) is continuous
let P, Q be continuous Function of I[01],T; :: thesis: R1Homotopy (P,Q) is continuous
set F = R1Homotopy (P,Q);
set PI = [:P,(id I[01]):];
set QI = [:Q,(id I[01]):];
defpred S₁[ Element of the carrier of R^1, Element of the carrier of I[01], set ] means $3 = (1 - $2) * $1;
defpred S₂[ Element of the carrier of R^1, Element of the carrier of I[01], set ] means $3 = $2 * $1;
A1: the carrier of T is Subset of R^1 by TSEP_1:1;
then reconsider G = R1Homotopy (P,Q) as Function of [:I[01],I[01]:],R^1 by FUNCT_2:9;
reconsider P1 = P, Q1 = Q as Function of I[01],R^1 by A1, FUNCT_2:9;
reconsider P1 = P1, Q1 = Q1 as continuous Function of I[01],R^1 by PRE_TOPC:56;
set P1I = [:P1,(id I[01]):];
set Q1I = [:Q1,(id I[01]):];
A2: ( [:P1,(id I[01]):] is continuous & [:Q1,(id I[01]):] is continuous ) ;
A3: for x being Element of the carrier of R^1
for y being Element of the carrier of I[01] ex z being Element of the carrier of R^1 st S₁[x,y,z] by TOPMETR:24;
consider Pa being Function of [: the carrier of R^1, the carrier of I[01]:], the carrier of R^1 such that
A4: for x being Element of the carrier of R^1
for i being Element of the carrier of I[01] holds S₁[x,i,Pa . (x,i)] from BINOP_1:sch 3(A3);
A5: for x being Element of the carrier of R^1
for y being Element of the carrier of I[01] ex z being Element of the carrier of R^1 st S₂[x,y,z]

proof

let x be Element of the carrier of R^1; :: thesis: for y being Element of the carrier of I[01] ex z being Element of the carrier of R^1 st S₂[x,y,z]
let y be Element of the carrier of I[01]; :: thesis: ex z being Element of the carrier of R^1 st S₂[x,y,z]
y * x in REAL by XREAL_0:def 1;
hence ex z being Element of the carrier of R^1 st S₂[x,y,z] by TOPMETR:24; :: thesis: verum

end;

consider Pb being Function of [: the carrier of R^1, the carrier of I[01]:], the carrier of R^1 such that
A6: for x being Element of the carrier of R^1
for i being Element of the carrier of I[01] holds S₂[x,i,Pb . (x,i)] from BINOP_1:sch 3(A5);
reconsider Pa = Pa, Pb = Pb as Function of [:R^1,I[01]:],R^1 by Lm3;
A7: Pb is continuous by A6, Th7;
Pa is continuous by A4, Th6;
then consider g being Function of [:I[01],I[01]:],R^1 such that
A8: for p being Point of [:I[01],I[01]:]
for r1, r2 being real number st (Pa * [:P1,(id I[01]):]) . p = r1 & (Pb * [:Q1,(id I[01]):]) . p = r2 holds
g . p = r1 + r2 and
A9: g is continuous by A7, JGRAPH_2:29;
A10: for p being Point of [:I[01],I[01]:] holds G . p = ((Pa * [:P1,(id I[01]):]) . p) + ((Pb * [:Q1,(id I[01]):]) . p)

proof

A11: dom Q = the carrier of I[01] by FUNCT_2:def 1;
A12: dom P = the carrier of I[01] by FUNCT_2:def 1;
let p be Point of [:I[01],I[01]:]; :: thesis: G . p = ((Pa * [:P1,(id I[01]):]) . p) + ((Pb * [:Q1,(id I[01]):]) . p)
consider s, t being Point of I[01] such that
A13: p = [s,t] by BORSUK_1:50;
reconsider a1 = P . s, b1 = Q . s as Point of R^1 by PRE_TOPC:55;
A14: P . s in the carrier of T ;
A15: (R1Homotopy (P,Q)) . (s,t) = ((1 - t) * a1) + (t * b1) by Def5;
A16: Q . s in the carrier of T ;
A17: (id I[01]) . t = t by FUNCT_1:35;
A18: (Pb * [:Q,(id I[01]):]) . p = Pb . ([:Q,(id I[01]):] . (s,t)) by A13, FUNCT_2:21
.= Pb . ((Q . s),t) by A11, A17, Lm4, FUNCT_3:def 9
.= t * (Q . s) by A1, A6, A16 ;
(Pa * [:P,(id I[01]):]) . p = Pa . ([:P,(id I[01]):] . (s,t)) by A13, FUNCT_2:21
.= Pa . ((P . s),t) by A12, A17, Lm4, FUNCT_3:def 9
.= (1 - t) * (P . s) by A1, A4, A14 ;
hence G . p = ((Pa * [:P1,(id I[01]):]) . p) + ((Pb * [:Q1,(id I[01]):]) . p) by A13, A18, A15; :: thesis: verum

end;

for p being Point of [:I[01],I[01]:] holds G . p = g . p

proof

let p be Point of [:I[01],I[01]:]; :: thesis: G . p = g . p
thus G . p = ((Pa * [:P1,(id I[01]):]) . p) + ((Pb * [:Q1,(id I[01]):]) . p) by A10
.= g . p by A8 ; :: thesis: verum

end;

hence R1Homotopy (P,Q) is continuous by A9, FUNCT_2:113, PRE_TOPC:57; :: thesis: verum