let seq, seq9, seq1 be Real_Sequence; :: thesis: ( seq is convergent & seq9 is convergent & ( for n being Element of NAT holds
( seq . n <= seq1 . n & seq1 . n <= seq9 . n ) ) & lim seq = lim seq9 implies lim seq1 = lim seq )
assume that
A1: seq is convergent and
A2: seq9 is convergent and
A3: for n being Element of NAT holds
( seq . n <= seq1 . n & seq1 . n <= seq9 . n ) and
A4: lim seq = lim seq9 ; :: thesis: lim seq1 = lim seq
A5: seq1 is convergent by A1, A2, A3, A4, Th33;

now

let p be real number ; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((seq1 . m) - (lim seq)) < p )
assume A6: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((seq1 . m) - (lim seq)) < p
then consider n1 being Element of NAT such that
A7: for m being Element of NAT st n1 <= m holds
abs ((seq . m) - (lim seq)) < p by A1, Def7;
consider n2 being Element of NAT such that
A8: for m being Element of NAT st n2 <= m holds
abs ((seq9 . m) - (lim seq)) < p by A2, A4, A6, Def7;
take n = n1 + n2; :: thesis: for m being Element of NAT st n <= m holds
abs ((seq1 . m) - (lim seq)) < p
let m be Element of NAT ; :: thesis: ( n <= m implies abs ((seq1 . m) - (lim seq)) < p )
assume A9: n <= m ; :: thesis: abs ((seq1 . m) - (lim seq)) < p
n2 <= n by NAT_1:12;
then n2 <= m by A9, XXREAL_0:2;
then abs ((seq9 . m) - (lim seq)) < p by A8;
then A10: (seq9 . m) - (lim seq) < p by Th9;
n1 <= n1 + n2 by NAT_1:12;
then n1 <= m by A9, XXREAL_0:2;
then abs ((seq . m) - (lim seq)) < p by A7;
then A11: - p < (seq . m) - (lim seq) by Th9;
seq . m <= seq1 . m by A3;
then (seq . m) - (lim seq) <= (seq1 . m) - (lim seq) by XREAL_1:11;
then A12: - p < (seq1 . m) - (lim seq) by A11, XXREAL_0:2;
seq1 . m <= seq9 . m by A3;
then (seq1 . m) - (lim seq) <= (seq9 . m) - (lim seq) by XREAL_1:11;
then (seq1 . m) - (lim seq) < p by A10, XXREAL_0:2;
hence abs ((seq1 . m) - (lim seq)) < p by A12, Th9; :: thesis: verum

end;

hence lim seq1 = lim seq by A5, Def7; :: thesis: verum