let S be RealNormSpace; :: thesis: for f being PartFunc of REAL, the carrier of S st f is total & ( for x1, x2 being real number holds f /. (x1 + x2) = (f /. x1) + (f /. x2) ) & ex x0 being real number st f is_continuous_in x0 holds
f | REAL is continuous
let f be PartFunc of REAL, the carrier of S; :: thesis: ( f is total & ( for x1, x2 being real number holds f /. (x1 + x2) = (f /. x1) + (f /. x2) ) & ex x0 being real number st f is_continuous_in x0 implies f | REAL is continuous )
assume that
A1: f is total and
A2: for x1, x2 being real number holds f /. (x1 + x2) = (f /. x1) + (f /. x2) ; :: thesis: ( for x0 being real number holds not f is_continuous_in x0 or f | REAL is continuous )
A3: dom f = REAL by A1, PARTFUN1:def 4;
given x0 being real number such that A4: f is_continuous_in x0 ; :: thesis: f | REAL is continuous
reconsider z0 = 0 as real number ;
(f /. z0) + (f /. z0) = f /. (z0 + z0) by A2;
then (f /. z0) + ((f /. z0) - (f /. z0)) = (f /. z0) - (f /. z0) by RLVECT_1:42;
then (f /. z0) + (0. S) = (f /. z0) - (f /. z0) by RLVECT_1:28;
then A5: (f /. z0) + (0. S) = 0. S by RLVECT_1:28;

A6: now

let x1 be real number ; :: thesis: - (f /. x1) = f /. (- x1)
0. S = f /. (x1 + (- x1)) by A5, RLVECT_1:10;
then 0. S = (f /. x1) + (f /. (- x1)) by A2;
hence - (f /. x1) = f /. (- x1) by RLVECT_1:def 13; :: thesis: verum

end;

A7: now

let x1, x2 be real number ; :: thesis: f /. (x1 - x2) = (f /. x1) - (f /. x2)
f /. (x1 - x2) = f /. (x1 + (- x2)) ;
then f /. (x1 - x2) = (f /. x1) + (f /. (- x2)) by A2;
hence f /. (x1 - x2) = (f /. x1) - (f /. x2) by A6; :: thesis: verum

end;

now

let x1 be real number ; :: thesis: for r being Real st x1 in REAL & r > 0 holds
ex s being real number st
( s > 0 & ( for x2 being real number st x2 in REAL & abs (x2 - x1) < s holds
||.((f /. x2) - (f /. x1)).|| < r ) )
let r be Real; :: thesis: ( x1 in REAL & r > 0 implies ex s being real number st
( s > 0 & ( for x2 being real number st x2 in REAL & abs (x2 - x1) < s holds
||.((f /. x2) - (f /. x1)).|| < r ) ) )
assume that
x1 in REAL and
A8: r > 0 ; :: thesis: ex s being real number st
( s > 0 & ( for x2 being real number st x2 in REAL & abs (x2 - x1) < s holds
||.((f /. x2) - (f /. x1)).|| < r ) )
set y = x1 - x0;
consider s being real number such that
A9: 0 < s and
A10: for x1 being real number st x1 in dom f & abs (x1 - x0) < s holds
||.((f /. x1) - (f /. x0)).|| < r by A4, A8, Th3;
take s = s; :: thesis: ( s > 0 & ( for x2 being real number st x2 in REAL & abs (x2 - x1) < s holds
||.((f /. x2) - (f /. x1)).|| < r ) )
thus s > 0 by A9; :: thesis: for x2 being real number st x2 in REAL & abs (x2 - x1) < s holds
||.((f /. x2) - (f /. x1)).|| < r
let x2 be real number ; :: thesis: ( x2 in REAL & abs (x2 - x1) < s implies ||.((f /. x2) - (f /. x1)).|| < r )
assume that
x2 in REAL and
A11: abs (x2 - x1) < s ; :: thesis: ||.((f /. x2) - (f /. x1)).|| < r
A12: ( x2 - (x1 - x0) is Real & abs ((x2 - (x1 - x0)) - x0) = abs (x2 - x1) ) by XREAL_0:def 1;
(x1 - x0) + x0 = x1 ;
then ||.((f /. x2) - (f /. x1)).|| = ||.((f /. x2) - ((f /. (x1 - x0)) + (f /. x0))).|| by A2
.= ||.(((f /. x2) - (f /. (x1 - x0))) - (f /. x0)).|| by RLVECT_1:41
.= ||.((f /. (x2 - (x1 - x0))) - (f /. x0)).|| by A7 ;
hence ||.((f /. x2) - (f /. x1)).|| < r by A3, A10, A11, A12; :: thesis: verum

end;

hence f | REAL is continuous by A3, Th15; :: thesis: verum