let X be non empty set ; :: thesis: for f being PartFunc of X,ExtREAL
for S being SigmaField of X
for A being Element of S st f is_measurable_on A & A c= dom f holds
max- f is_measurable_on A
let f be PartFunc of X,ExtREAL; :: thesis: for S being SigmaField of X
for A being Element of S st f is_measurable_on A & A c= dom f holds
max- f is_measurable_on A
let S be SigmaField of X; :: thesis: for A being Element of S st f is_measurable_on A & A c= dom f holds
max- f is_measurable_on A
let A be Element of S; :: thesis: ( f is_measurable_on A & A c= dom f implies max- f is_measurable_on A )
assume A1: ( f is_measurable_on A & A c= dom f ) ; :: thesis: max- f is_measurable_on A
for r being real number holds A /\ (less_dom ((max- f),(R_EAL r))) in S

proof

let r be real number ; :: thesis: A /\ (less_dom ((max- f),(R_EAL r))) in S
reconsider r = r as Real by XREAL_0:def 1;

now

per cases ( 0 < r or r <= 0 ) ;

suppose A4: 0 < r ; :: thesis: A /\ (less_dom ((max- f),(R_EAL r))) in S

(- 1) (#) f is_measurable_on A by A1, MESFUNC1:41;
then A6: - f is_measurable_on A by Th11;
for x being set st x in less_dom ((max- f),(R_EAL r)) holds
x in less_dom ((- f),(R_EAL r))

proof

let x be set ; :: thesis: ( x in less_dom ((max- f),(R_EAL r)) implies x in less_dom ((- f),(R_EAL r)) )
assume A8: x in less_dom ((max- f),(R_EAL r)) ; :: thesis: x in less_dom ((- f),(R_EAL r))
then A9: x in dom (max- f) by MESFUNC1:def 12;
A10: (max- f) . x < R_EAL r by A8, MESFUNC1:def 12;
reconsider x = x as Element of X by A8;
A11: max ((- (f . x)),0.) < R_EAL r by A9, A10, Def3;
then A12: - (f . x) <= R_EAL r by XXREAL_0:30;
- (f . x) <> R_EAL r

proof

assume A14: - (f . x) = R_EAL r ; :: thesis: contradiction
then max ((- (f . x)),0.) = 0. by A11, XXREAL_0:16;
hence contradiction by A11, A14, XXREAL_0:def 10; :: thesis: verum

end;

then A16: - (f . x) < R_EAL r by A12, XXREAL_0:1;
x in dom f by A9, Def3;
then A18: x in dom (- f) by MESFUNC1:def 7;
then (- f) . x = - (f . x) by MESFUNC1:def 7;
hence x in less_dom ((- f),(R_EAL r)) by A16, A18, MESFUNC1:def 12; :: thesis: verum

end;

then A20: less_dom ((max- f),(R_EAL r)) c= less_dom ((- f),(R_EAL r)) by TARSKI:def 3;
for x being set st x in less_dom ((- f),(R_EAL r)) holds
x in less_dom ((max- f),(R_EAL r))

proof

let x be set ; :: thesis: ( x in less_dom ((- f),(R_EAL r)) implies x in less_dom ((max- f),(R_EAL r)) )
assume A22: x in less_dom ((- f),(R_EAL r)) ; :: thesis: x in less_dom ((max- f),(R_EAL r))
then A23: x in dom (- f) by MESFUNC1:def 12;
A24: (- f) . x < R_EAL r by A22, MESFUNC1:def 12;
reconsider x = x as Element of X by A22;
x in dom f by A23, MESFUNC1:def 7;
then A26: x in dom (max- f) by Def3;

now

per cases ( 0. <= - (f . x) or not 0. <= - (f . x) ) ;

suppose 0. <= - (f . x) ; :: thesis: x in less_dom ((max- f),(R_EAL r))

then max ((- (f . x)),0.) = - (f . x) by XXREAL_0:def 10;
then (max- f) . x = - (f . x) by A26, Def3
.= (- f) . x by A23, MESFUNC1:def 7 ;
hence x in less_dom ((max- f),(R_EAL r)) by A24, A26, MESFUNC1:def 12; :: thesis: verum

end;

suppose not 0. <= - (f . x) ; :: thesis: x in less_dom ((max- f),(R_EAL r))

then max ((- (f . x)),0.) = 0. by XXREAL_0:def 10;
then (max- f) . x = 0. by A26, Def3;
hence x in less_dom ((max- f),(R_EAL r)) by A4, A26, MESFUNC1:def 12; :: thesis: verum

end;

end;

end;

hence x in less_dom ((max- f),(R_EAL r)) ; :: thesis: verum

end;

then less_dom ((- f),(R_EAL r)) c= less_dom ((max- f),(R_EAL r)) by TARSKI:def 3;
then less_dom ((max- f),(R_EAL r)) = less_dom ((- f),(R_EAL r)) by A20, XBOOLE_0:def 10;
hence A /\ (less_dom ((max- f),(R_EAL r))) in S by A6, MESFUNC1:def 17; :: thesis: verum

end;

suppose A36: r <= 0 ; :: thesis: A /\ (less_dom ((max- f),(R_EAL r))) in S

for x being Element of X holds not x in less_dom ((max- f),(R_EAL r))

proof

let x be Element of X; :: thesis: not x in less_dom ((max- f),(R_EAL r))
assume A38: x in less_dom ((max- f),(R_EAL r)) ; :: thesis: contradiction
then A39: x in dom (max- f) by MESFUNC1:def 12;
A40: (max- f) . x < R_EAL r by A38, MESFUNC1:def 12;
(max- f) . x = max ((- (f . x)),0.) by A39, Def3;
hence contradiction by A36, A40, XXREAL_0:25; :: thesis: verum

end;

then less_dom ((max- f),(R_EAL r)) = {} by SUBSET_1:10;
hence A /\ (less_dom ((max- f),(R_EAL r))) in S by PROB_1:10; :: thesis: verum

end;

end;

end;

hence A /\ (less_dom ((max- f),(R_EAL r))) in S ; :: thesis: verum

end;

hence max- f is_measurable_on A by MESFUNC1:def 17; :: thesis: verum