let X be non empty set ; :: thesis: for f being PartFunc of X,ExtREAL
for S being SigmaField of X
for A being Element of S st f is_measurable_on A holds
max+ f is_measurable_on A
let f be PartFunc of X,ExtREAL; :: thesis: for S being SigmaField of X
for A being Element of S st f is_measurable_on A holds
max+ f is_measurable_on A
let S be SigmaField of X; :: thesis: for A being Element of S st f is_measurable_on A holds
max+ f is_measurable_on A
let A be Element of S; :: thesis: ( f is_measurable_on A implies max+ f is_measurable_on A )
assume A1: f is_measurable_on A ; :: thesis: max+ f is_measurable_on A
for r being real number holds A /\ (less_dom ((max+ f),(R_EAL r))) in S

proof

let r be real number ; :: thesis: A /\ (less_dom ((max+ f),(R_EAL r))) in S
reconsider r = r as Real by XREAL_0:def 1;

now

per cases ( 0 < r or r <= 0 ) ;

suppose A4: 0 < r ; :: thesis: A /\ (less_dom ((max+ f),(R_EAL r))) in S

for x being set st x in less_dom ((max+ f),(R_EAL r)) holds
x in less_dom (f,(R_EAL r))

proof

let x be set ; :: thesis: ( x in less_dom ((max+ f),(R_EAL r)) implies x in less_dom (f,(R_EAL r)) )
assume A6: x in less_dom ((max+ f),(R_EAL r)) ; :: thesis: x in less_dom (f,(R_EAL r))
then A7: x in dom (max+ f) by MESFUNC1:def 12;
A8: (max+ f) . x < R_EAL r by A6, MESFUNC1:def 12;
reconsider x = x as Element of X by A6;
A9: max ((f . x),0.) < R_EAL r by A7, A8, Def2;
then A10: f . x <= R_EAL r by XXREAL_0:30;
f . x <> R_EAL r

proof

assume A12: f . x = R_EAL r ; :: thesis: contradiction
then max ((f . x),0.) = 0. by A9, XXREAL_0:16;
hence contradiction by A9, A12, XXREAL_0:def 10; :: thesis: verum

end;

then A14: f . x < R_EAL r by A10, XXREAL_0:1;
x in dom f by A7, Def2;
hence x in less_dom (f,(R_EAL r)) by A14, MESFUNC1:def 12; :: thesis: verum

end;

then A16: less_dom ((max+ f),(R_EAL r)) c= less_dom (f,(R_EAL r)) by TARSKI:def 3;
for x being set st x in less_dom (f,(R_EAL r)) holds
x in less_dom ((max+ f),(R_EAL r))

proof

let x be set ; :: thesis: ( x in less_dom (f,(R_EAL r)) implies x in less_dom ((max+ f),(R_EAL r)) )
assume A18: x in less_dom (f,(R_EAL r)) ; :: thesis: x in less_dom ((max+ f),(R_EAL r))
then A19: x in dom f by MESFUNC1:def 12;
A20: f . x < R_EAL r by A18, MESFUNC1:def 12;
reconsider x = x as Element of X by A18;
A21: x in dom (max+ f) by A19, Def2;

now

per cases ( 0. <= f . x or not 0. <= f . x ) ;

suppose 0. <= f . x ; :: thesis: x in less_dom ((max+ f),(R_EAL r))

then max ((f . x),0.) = f . x by XXREAL_0:def 10;
then (max+ f) . x = f . x by A21, Def2;
hence x in less_dom ((max+ f),(R_EAL r)) by A20, A21, MESFUNC1:def 12; :: thesis: verum

end;

suppose not 0. <= f . x ; :: thesis: x in less_dom ((max+ f),(R_EAL r))

then max ((f . x),0.) = 0. by XXREAL_0:def 10;
then (max+ f) . x = 0. by A21, Def2;
hence x in less_dom ((max+ f),(R_EAL r)) by A4, A21, MESFUNC1:def 12; :: thesis: verum

end;

end;

end;

hence x in less_dom ((max+ f),(R_EAL r)) ; :: thesis: verum

end;

then less_dom (f,(R_EAL r)) c= less_dom ((max+ f),(R_EAL r)) by TARSKI:def 3;
then less_dom ((max+ f),(R_EAL r)) = less_dom (f,(R_EAL r)) by A16, XBOOLE_0:def 10;
hence A /\ (less_dom ((max+ f),(R_EAL r))) in S by A1, MESFUNC1:def 17; :: thesis: verum

end;

suppose A31: r <= 0 ; :: thesis: A /\ (less_dom ((max+ f),(R_EAL r))) in S

for x being Element of X holds not x in less_dom ((max+ f),(R_EAL r))

proof

let x be Element of X; :: thesis: not x in less_dom ((max+ f),(R_EAL r))
assume A33: x in less_dom ((max+ f),(R_EAL r)) ; :: thesis: contradiction
then A34: x in dom (max+ f) by MESFUNC1:def 12;
A35: (max+ f) . x < R_EAL r by A33, MESFUNC1:def 12;
(max+ f) . x = max ((f . x),0.) by A34, Def2;
hence contradiction by A31, A35, XXREAL_0:25; :: thesis: verum

end;

then less_dom ((max+ f),(R_EAL r)) = {} by SUBSET_1:10;
hence A /\ (less_dom ((max+ f),(R_EAL r))) in S by PROB_1:10; :: thesis: verum

end;

end;

end;

hence A /\ (less_dom ((max+ f),(R_EAL r))) in S ; :: thesis: verum

end;

hence max+ f is_measurable_on A by MESFUNC1:def 17; :: thesis: verum