let X be set ; :: thesis: for S being SigmaField of X
for F being Function of NAT,S
for f being PartFunc of X,ExtREAL
for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom (f,(R_EAL n))) ) holds
A /\ (eq_dom (f,+infty)) = meet (rng F)
let S be SigmaField of X; :: thesis: for F being Function of NAT,S
for f being PartFunc of X,ExtREAL
for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom (f,(R_EAL n))) ) holds
A /\ (eq_dom (f,+infty)) = meet (rng F)
let F be Function of NAT,S; :: thesis: for f being PartFunc of X,ExtREAL
for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom (f,(R_EAL n))) ) holds
A /\ (eq_dom (f,+infty)) = meet (rng F)
let f be PartFunc of X,ExtREAL; :: thesis: for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom (f,(R_EAL n))) ) holds
A /\ (eq_dom (f,+infty)) = meet (rng F)
let A be set ; :: thesis: ( ( for n being Element of NAT holds F . n = A /\ (great_dom (f,(R_EAL n))) ) implies A /\ (eq_dom (f,+infty)) = meet (rng F) )
assume A1: for n being Element of NAT holds F . n = A /\ (great_dom (f,(R_EAL n))) ; :: thesis: A /\ (eq_dom (f,+infty)) = meet (rng F)
for x being set st x in A /\ (eq_dom (f,+infty)) holds
x in meet (rng F)

proof

let x be set ; :: thesis: ( x in A /\ (eq_dom (f,+infty)) implies x in meet (rng F) )
assume A3: x in A /\ (eq_dom (f,+infty)) ; :: thesis: x in meet (rng F)
then A4: x in A by XBOOLE_0:def 4;
A5: x in eq_dom (f,+infty) by A3, XBOOLE_0:def 4;
for Y being set st Y in rng F holds
x in Y

proof

let Y be set ; :: thesis: ( Y in rng F implies x in Y )
( Y in rng F implies x in Y )

proof

assume Y in rng F ; :: thesis: x in Y
then consider m being Element of NAT such that
m in dom F and
A9: Y = F . m by PARTFUN1:26;
A10: Y = A /\ (great_dom (f,(R_EAL m))) by A1, A9;
reconsider x = x as Element of X by A3;
A11: f . x = +infty by A5, Def16;
( x in dom f & not +infty <= R_EAL m ) by A5, Def16, XXREAL_0:9;
then x in great_dom (f,(R_EAL m)) by A11, Def14;
hence x in Y by A4, A10, XBOOLE_0:def 4; :: thesis: verum

end;

hence ( Y in rng F implies x in Y ) ; :: thesis: verum

end;

hence x in meet (rng F) by SETFAM_1:def 1; :: thesis: verum

end;

then A14: A /\ (eq_dom (f,+infty)) c= meet (rng F) by TARSKI:def 3;
for x being set st x in meet (rng F) holds
x in A /\ (eq_dom (f,+infty))

proof

let x be set ; :: thesis: ( x in meet (rng F) implies x in A /\ (eq_dom (f,+infty)) )
assume A16: x in meet (rng F) ; :: thesis: x in A /\ (eq_dom (f,+infty))
A17: for m being Element of NAT holds
( x in A & x in dom f & ex y being R_eal st
( y = f . x & y = +infty ) )

proof

let m be Element of NAT ; :: thesis: ( x in A & x in dom f & ex y being R_eal st
( y = f . x & y = +infty ) )
m in NAT ;
then m in dom F by FUNCT_2:def 1;
then F . m in rng F by FUNCT_1:def 5;
then x in F . m by A16, SETFAM_1:def 1;
then A22: x in A /\ (great_dom (f,(R_EAL m))) by A1;
then A23: x in great_dom (f,(R_EAL m)) by XBOOLE_0:def 4;
for r being Real holds R_EAL r < f . x

proof

let r be Real; :: thesis: R_EAL r < f . x
consider n being Element of NAT such that
A25: r <= n by Th11;
n in NAT ;
then n in dom F by FUNCT_2:def 1;
then F . n in rng F by FUNCT_1:def 5;
then x in F . n by A16, SETFAM_1:def 1;
then x in A /\ (great_dom (f,(R_EAL n))) by A1;
then x in great_dom (f,(R_EAL n)) by XBOOLE_0:def 4;
then R_EAL n < f . x by Def14;
hence R_EAL r < f . x by A25, XXREAL_0:2; :: thesis: verum

end;

then f . x = +infty by Th15;
hence ( x in A & x in dom f & ex y being R_eal st
( y = f . x & y = +infty ) ) by A22, A23, Def14, XBOOLE_0:def 4; :: thesis: verum

end;

1 in NAT ;
then 1 in dom F by FUNCT_2:def 1;
then F . 1 in rng F by FUNCT_1:def 5;
then x in F . 1 by A16, SETFAM_1:def 1;
then x in A /\ (great_dom (f,(R_EAL 1))) by A1;
then reconsider x = x as Element of X ;
x in eq_dom (f,+infty) by A17, Def16;
hence x in A /\ (eq_dom (f,+infty)) by A17, XBOOLE_0:def 4; :: thesis: verum

end;

then meet (rng F) c= A /\ (eq_dom (f,+infty)) by TARSKI:def 3;
hence A /\ (eq_dom (f,+infty)) = meet (rng F) by A14, XBOOLE_0:def 10; :: thesis: verum