let Omega, I be non empty set ; :: thesis: for Sigma being SigmaField of Omega
for P being Probability of Sigma
for a being Element of Sigma
for F being ManySortedSigmaField of I,Sigma st F is_independent_wrt P & a in tailSigmaField (F,I) & not P . a = 0 holds
P . a = 1
let Sigma be SigmaField of Omega; :: thesis: for P being Probability of Sigma
for a being Element of Sigma
for F being ManySortedSigmaField of I,Sigma st F is_independent_wrt P & a in tailSigmaField (F,I) & not P . a = 0 holds
P . a = 1
let P be Probability of Sigma; :: thesis: for a being Element of Sigma
for F being ManySortedSigmaField of I,Sigma st F is_independent_wrt P & a in tailSigmaField (F,I) & not P . a = 0 holds
P . a = 1
let a be Element of Sigma; :: thesis: for F being ManySortedSigmaField of I,Sigma st F is_independent_wrt P & a in tailSigmaField (F,I) & not P . a = 0 holds
P . a = 1
let F be ManySortedSigmaField of I,Sigma; :: thesis: ( F is_independent_wrt P & a in tailSigmaField (F,I) & not P . a = 0 implies P . a = 1 )
reconsider T = tailSigmaField (F,I) as SigmaField of Omega by Th15;
set Ie = I \ ({} I);
A1: ( a in tailSigmaField (F,I) implies a in sigUn (F,(I \ ({} I))) )

proof

assume A2: a in tailSigmaField (F,I) ; :: thesis: a in sigUn (F,(I \ ({} I)))
sigUn (F,(I \ ({} I))) in futSigmaFields (F,I) by Def7;
hence a in sigUn (F,(I \ ({} I))) by A2, SETFAM_1:def 1; :: thesis: verum

end;

assume A3: F is_independent_wrt P ; :: thesis: ( not a in tailSigmaField (F,I) or P . a = 0 or P . a = 1 )
A4: for E being finite Subset of I
for p, q being Event of Sigma st p in sigUn (F,E) & q in tailSigmaField (F,I) holds
p,q are_independent_respect_to P

proof

let E be finite Subset of I; :: thesis: for p, q being Event of Sigma st p in sigUn (F,E) & q in tailSigmaField (F,I) holds
p,q are_independent_respect_to P
let p, q be Event of Sigma; :: thesis: ( p in sigUn (F,E) & q in tailSigmaField (F,I) implies p,q are_independent_respect_to P )
assume that
A5: p in sigUn (F,E) and
A6: q in tailSigmaField (F,I) ; :: thesis: p,q are_independent_respect_to P
for E being finite Subset of I holds q in sigUn (F,(I \ E))

proof

let E be finite Subset of I; :: thesis: q in sigUn (F,(I \ E))
sigUn (F,(I \ E)) in futSigmaFields (F,I) by Def7;
hence q in sigUn (F,(I \ E)) by A6, SETFAM_1:def 1; :: thesis: verum

end;

then A7: q in sigUn (F,(I \ E)) ;

per cases ( ( E <> {} & I \ E <> {} ) or not E <> {} or not I \ E <> {} ) ;

suppose A8: ( E <> {} & I \ E <> {} ) ; :: thesis: p,q are_independent_respect_to P

then reconsider E = E as non empty Subset of I ;
reconsider IE = I \ E as non empty Subset of I by A8;
E misses IE by XBOOLE_1:79;
then P . (p /\ q) = (P . p) * (P . q) by A3, A5, A7, Th14;
hence p,q are_independent_respect_to P by PROB_2:def 5; :: thesis: verum

end;

suppose A9: ( not E <> {} or not I \ E <> {} ) ; :: thesis: p,q are_independent_respect_to P

reconsider e = {} as Subset of I by XBOOLE_1:2;
A10: for u, v being Event of Sigma st u in {{},Omega} holds
u,v are_independent_respect_to P

proof

let u, v be Event of Sigma; :: thesis: ( u in {{},Omega} implies u,v are_independent_respect_to P )
assume A11: u in {{},Omega} ; :: thesis: u,v are_independent_respect_to P

per cases ( u = {} or u <> {} ) ;

suppose u = {} ; :: thesis: u,v are_independent_respect_to P

hence u,v are_independent_respect_to P by PROB_2:31, PROB_2:35; :: thesis: verum

end;

suppose u <> {} ; :: thesis: u,v are_independent_respect_to P

then u = [#] Sigma by A11, TARSKI:def 2;
hence u,v are_independent_respect_to P by PROB_2:31, PROB_2:36; :: thesis: verum

end;

end;

end;

Union (F | {}) = {} by ZFMISC_1:2;
then A12: sigUn (F,e) = {{},Omega} by Th3;
p,q are_independent_respect_to P

proof

per cases ( E = {} or E <> {} ) ;

suppose E = {} ; :: thesis: p,q are_independent_respect_to P

hence p,q are_independent_respect_to P by A5, A12, A10; :: thesis: verum

end;

suppose E <> {} ; :: thesis: p,q are_independent_respect_to P

hence p,q are_independent_respect_to P by A7, A9, A12, A10, PROB_2:31; :: thesis: verum

end;

end;

end;

hence p,q are_independent_respect_to P ; :: thesis: verum

end;

end;

end;

A13: for p, q being Event of Sigma st p in finSigmaFields (F,I) & q in tailSigmaField (F,I) holds
p,q are_independent_respect_to P

proof

let p, q be Event of Sigma; :: thesis: ( p in finSigmaFields (F,I) & q in tailSigmaField (F,I) implies p,q are_independent_respect_to P )
assume that
A14: p in finSigmaFields (F,I) and
A15: q in tailSigmaField (F,I) ; :: thesis: p,q are_independent_respect_to P
ex E being finite Subset of I st p in sigUn (F,E) by A14, Def10;
hence p,q are_independent_respect_to P by A4, A15; :: thesis: verum

end;

Union (F | (I \ ({} I))) c= sigma (finSigmaFields (F,I))

proof

consider X being set ;
let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Union (F | (I \ ({} I))) or x in sigma (finSigmaFields (F,I)) )
A16: dom F c= I \ ({} I) ;
assume x in Union (F | (I \ ({} I))) ; :: thesis: x in sigma (finSigmaFields (F,I))
then x in union (rng F) by A16, RELAT_1:97;
then consider y being set such that
A17: x in y and
A18: y in rng F by TARSKI:def 4;
consider i being set such that
A19: i in dom F and
A20: y = F . i by A18, FUNCT_1:def 5;
A21: x in finSigmaFields (F,I)

proof

reconsider Fi = F . i as SigmaField of Omega by A19, Def2;
A22: ( sigma Fi c= Fi & Fi c= sigma Fi ) by PROB_1:def 14;
i in I by A19;
then for z being set st z in {i} holds
z in I by TARSKI:def 1;
then reconsider E = {i} as finite Subset of I by TARSKI:def 3;
A23: dom (F | {i}) = (dom F) /\ {i} by RELAT_1:90
.= {i} by A19, ZFMISC_1:52 ;
then rng (F | {i}) = {((F | {i}) . i)} by FUNCT_1:14;
then A24: union (rng (F | {i})) = (F | {i}) . i by ZFMISC_1:31;
i in dom (F | {i}) by A23, TARSKI:def 1;
then Union (F | {i}) = F . i by A24, FUNCT_1:70;
then sigUn (F,E) = F . i by A22, XBOOLE_0:def 10;
hence x in finSigmaFields (F,I) by A17, A20, Def10; :: thesis: verum

end;

finSigmaFields (F,I) c= sigma (finSigmaFields (F,I)) by PROB_1:def 14;
hence x in sigma (finSigmaFields (F,I)) by A21; :: thesis: verum

end;

then A25: ( T c= sigma T & sigUn (F,(I \ ({} I))) c= sigma (finSigmaFields (F,I)) ) by PROB_1:def 14;
A26: for u, v being Event of Sigma st u in sigUn (F,(I \ ({} I))) & v in tailSigmaField (F,I) holds
u,v are_independent_respect_to P

proof

for x, y being set st x in finSigmaFields (F,I) & y in finSigmaFields (F,I) holds
x /\ y in finSigmaFields (F,I)

proof

let x, y be set ; :: thesis: ( x in finSigmaFields (F,I) & y in finSigmaFields (F,I) implies x /\ y in finSigmaFields (F,I) )
assume that
A27: x in finSigmaFields (F,I) and
A28: y in finSigmaFields (F,I) ; :: thesis: x /\ y in finSigmaFields (F,I)
consider E1 being finite Subset of I such that
A29: x in sigUn (F,E1) by A27, Def10;
consider E2 being finite Subset of I such that
A30: y in sigUn (F,E2) by A28, Def10;
A31: for z being set
for E1, E2 being finite Subset of I st z in sigUn (F,E1) holds
z in sigUn (F,(E1 \/ E2))

proof

let z be set ; :: thesis: for E1, E2 being finite Subset of I st z in sigUn (F,E1) holds
z in sigUn (F,(E1 \/ E2))
let E1, E2 be finite Subset of I; :: thesis: ( z in sigUn (F,E1) implies z in sigUn (F,(E1 \/ E2)) )
reconsider E3 = E1 \/ E2 as finite Subset of I ;
A32: Union (F | E1) c= Union (F | E3)

proof

let X be set ; :: according to TARSKI:def 3 :: thesis: ( not X in Union (F | E1) or X in Union (F | E3) )
assume X in Union (F | E1) ; :: thesis: X in Union (F | E3)
then consider S being set such that
A33: X in S and
A34: S in rng (F | E1) by TARSKI:def 4;
F | E3 = (F | E1) \/ (F | E2) by RELAT_1:107;
then rng (F | E3) = (rng (F | E1)) \/ (rng (F | E2)) by RELAT_1:26;
then S in rng (F | E3) by A34, XBOOLE_0:def 3;
hence X in Union (F | E3) by A33, TARSKI:def 4; :: thesis: verum

end;

Union (F | E3) c= sigma (Union (F | E3)) by PROB_1:def 14;
then Union (F | E1) c= sigma (Union (F | E3)) by A32, XBOOLE_1:1;
then A35: sigma (Union (F | E1)) c= sigma (Union (F | E3)) by PROB_1:def 14;
assume z in sigUn (F,E1) ; :: thesis: z in sigUn (F,(E1 \/ E2))
hence z in sigUn (F,(E1 \/ E2)) by A35; :: thesis: verum

end;

then A36: y in sigUn (F,(E2 \/ E1)) by A30;
x in sigUn (F,(E1 \/ E2)) by A29, A31;
then x /\ y in sigUn (F,(E1 \/ E2)) by A36, FINSUB_1:def 2;
hence x /\ y in finSigmaFields (F,I) by Def10; :: thesis: verum

end;

then A37: finSigmaFields (F,I) is intersection_stable by FINSUB_1:def 2;
let u, v be Event of Sigma; :: thesis: ( u in sigUn (F,(I \ ({} I))) & v in tailSigmaField (F,I) implies u,v are_independent_respect_to P )
A38: not finSigmaFields (F,I) is empty

proof

consider E being finite Subset of I;
{} in sigUn (F,E) by PROB_1:10;
hence not finSigmaFields (F,I) is empty by Def10; :: thesis: verum

end;

A39: tailSigmaField (F,I) c= Sigma

proof

set Ie = I \ ({} I);
let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in tailSigmaField (F,I) or x in Sigma )
assume A40: x in tailSigmaField (F,I) ; :: thesis: x in Sigma
Union (F | (I \ ({} I))) c= Sigma

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in Union (F | (I \ ({} I))) or y in Sigma )
assume y in Union (F | (I \ ({} I))) ; :: thesis: y in Sigma
then ex S being set st
( y in S & S in rng (F | (I \ ({} I))) ) by TARSKI:def 4;
hence y in Sigma ; :: thesis: verum

end;

then A41: sigma (Union (F | (I \ ({} I)))) c= Sigma by PROB_1:def 14;
sigUn (F,(I \ ({} I))) in futSigmaFields (F,I) by Def7;
then x in sigma (Union (F | (I \ ({} I)))) by A40, SETFAM_1:def 1;
hence x in Sigma by A41; :: thesis: verum

end;

A42: finSigmaFields (F,I) c= Sigma

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in finSigmaFields (F,I) or x in Sigma )
assume x in finSigmaFields (F,I) ; :: thesis: x in Sigma
then consider E being finite Subset of I such that
A43: x in sigUn (F,E) by Def10;
Union (F | E) c= Sigma

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in Union (F | E) or y in Sigma )
assume y in Union (F | E) ; :: thesis: y in Sigma
then ex S being set st
( y in S & S in rng (F | E) ) by TARSKI:def 4;
hence y in Sigma ; :: thesis: verum

end;

then sigma (Union (F | E)) c= Sigma by PROB_1:def 14;
hence x in Sigma by A43; :: thesis: verum

end;

assume ( u in sigUn (F,(I \ ({} I))) & v in tailSigmaField (F,I) ) ; :: thesis: u,v are_independent_respect_to P
hence u,v are_independent_respect_to P by A13, A25, A38, A42, A37, A39, Th10; :: thesis: verum

end;

assume a in tailSigmaField (F,I) ; :: thesis: ( P . a = 0 or P . a = 1 )
then a,a are_independent_respect_to P by A1, A26;
then P . (a /\ a) = (P . a) * (P . a) by PROB_2:def 5;
hence ( P . a = 0 or P . a = 1 ) by Th2; :: thesis: verum