let U be non empty set ; :: thesis: for A1, A2, B1, B2 being Subset of U st A1 c= A2 & B1 c= B2 holds
UNION ((Inter (A1,A2)),(Inter (B1,B2))) = { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) }
let A1, A2, B1, B2 be Subset of U; :: thesis: ( A1 c= A2 & B1 c= B2 implies UNION ((Inter (A1,A2)),(Inter (B1,B2))) = { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } )
assume that
A1: A1 c= A2 and
A2: B1 c= B2 ; :: thesis: UNION ((Inter (A1,A2)),(Inter (B1,B2))) = { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) }
set A = Inter (A1,A2);
set B = Inter (B1,B2);
set LAB = A1 \/ B1;
set UAB = A2 \/ B2;
set IT = UNION ((Inter (A1,A2)),(Inter (B1,B2)));
thus UNION ((Inter (A1,A2)),(Inter (B1,B2))) c= { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } :: according to XBOOLE_0:def 10 :: thesis: { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } c= UNION ((Inter (A1,A2)),(Inter (B1,B2)))

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in UNION ((Inter (A1,A2)),(Inter (B1,B2))) or x in { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } )
assume x in UNION ((Inter (A1,A2)),(Inter (B1,B2))) ; :: thesis: x in { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) }
then consider X, Y being set such that
B1: ( X in Inter (A1,A2) & Y in Inter (B1,B2) & x = X \/ Y ) by SETFAM_1:def 4;
B2: x is Subset of U by B1, XBOOLE_1:8;
B4: A1 c= X by Lemacik, B1;
B1 c= Y by Lemacik, B1;
then B3: A1 \/ B1 c= x by B4, B1, XBOOLE_1:13;
B5: X c= A2 by Lemacik, B1;
Y c= B2 by Lemacik, B1;
then x c= A2 \/ B2 by B5, XBOOLE_1:13, B1;
hence x in { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } by B2, B3; :: thesis: verum

end;

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } or x in UNION ((Inter (A1,A2)),(Inter (B1,B2))) )
assume x in { C where C is Subset of U : ( A1 \/ B1 c= C & C c= A2 \/ B2 ) } ; :: thesis: x in UNION ((Inter (A1,A2)),(Inter (B1,B2)))
then consider C9 being Subset of U such that
B1: ( C9 = x & A1 \/ B1 c= C9 & C9 c= A2 \/ B2 ) ;
set x1 = (x \/ A1) /\ A2;
set x2 = (x \/ B1) /\ B2;
T1: (A1 \/ B1) \/ x = x by B1, XBOOLE_1:12;
T2: (A2 \/ B2) /\ x = x by B1, XBOOLE_1:28;
H1: A1 /\ A2 = A1 by A1, XBOOLE_1:28;
H2: B1 /\ B2 = B1 by A2, XBOOLE_1:28;
T4: ((x \/ A1) /\ A2) \/ ((x \/ B1) /\ B2) = ((x /\ A2) \/ (A1 /\ A2)) \/ ((x \/ B1) /\ B2) by XBOOLE_1:23
.= ((x /\ A2) \/ A1) \/ ((x /\ B2) \/ (B1 /\ B2)) by H1, XBOOLE_1:23
.= (x /\ A2) \/ (A1 \/ ((x /\ B2) \/ B1)) by H2, XBOOLE_1:4
.= (x /\ A2) \/ ((x /\ B2) \/ (A1 \/ B1)) by XBOOLE_1:4
.= ((x /\ A2) \/ (x /\ B2)) \/ (A1 \/ B1) by XBOOLE_1:4
.= x by T1, T2, XBOOLE_1:23 ;
A1 /\ A2 = A1 by A1, XBOOLE_1:28;
then (x \/ A1) /\ A2 = (x /\ A2) \/ A1 by XBOOLE_1:23;
then H1: A1 c= (x \/ A1) /\ A2 by XBOOLE_1:7;
(x \/ A1) /\ A2 c= A2 by XBOOLE_1:17;
then Y2: (x \/ A1) /\ A2 in Inter (A1,A2) by H1;
B1 /\ B2 = B1 by A2, XBOOLE_1:28;
then (x \/ B1) /\ B2 = (x /\ B2) \/ B1 by XBOOLE_1:23;
then H2: B1 c= (x \/ B1) /\ B2 by XBOOLE_1:7;
(x \/ B1) /\ B2 c= B2 by XBOOLE_1:17;
then (x \/ B1) /\ B2 in Inter (B1,B2) by H2;
hence x in UNION ((Inter (A1,A2)),(Inter (B1,B2))) by T4, Y2, SETFAM_1:def 4; :: thesis: verum